Anti Hack For GM Account Password.

[Hatake Kakashi]

hello, who can give anti hack for gm acc? put an another password ingame when you login for gm acc. only. thanks

[Arcenciel]

You've already requested this before.

http://rathena.org/b...urity-password/

[Hatake Kakashi]

sorry, i already have this thanks. by the way.

is this posible?

when you make gm acc. it has automatically password for security? bcoz someone bypass my database. i mean he make gm acc lvl 99 but i dont know who is that. so my concern is, is that posible? if you make gmlvl 99 and if he make char. on that acc. and if he/she in game it will automatically prompt needs GM Password that i will put in script.? thanks

[Arcenciel]

If you're being hacked, instead of using password. It's better to just auto-kick them. Log-in scripts with input can be bypassed by using alt + shorcuts to just teleport during the prompts.

- script Login_Events -1,{
OnPCLoginEvent:

if ( getgmlevel() > 0 ) {
if ( strcharinfo(0) != "Name here" || strcharinfo(0) != "Name here" || strcharinfo(0) != "Name here" ) {
atcommand "@kick "+strcharinfo(0);
}
}
}

This script will kick people who doesn't have their name listed provided that their GM level is greater than 0. Untested by the way.

[Hatake Kakashi]

i will use this scripts? can you explain further on how it works and what do i need to put? thank you.

[Arcenciel]

It's self-explanatory.....just put the names of your GM where it says Name Here.

EDIT:

- script Login_Events -1,{
OnPCLoginEvent:

if ( getgmlevel() > 0 ) {
if ( strcharinfo(0) == "Name here" || strcharinfo(0) == "Name here" || strcharinfo(0) == "Name here" ) { end; }
atcommand "@kick "+strcharinfo(0);
}
}

[Hatake Kakashi]

sorry my bad. its working................. thank you.

Edited January 23, 2012 by Hatake Kakashi

[Peopleperson49]

You can also go another route with it. Leave your accounts as non-gm accounts. Then use a login event script to make them GM's that allows you to have several characters on the same account without having them all as GM's. Basically, GM's don't have to login several accounts to swtich between there GM and non-gm characters.

- script GMAccess -1,{
OnPCLoginEvent:
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
//atcommand "@adjgmlvl 99 NameHere;
atcommand "@refresh";
end;
}
//Any character you want to be a GM place here and that specific character will be made a GM.
//This allows a person to have a non-GM account, but with GM access for a specific character.
//There GM level is also specificed in the script.

[Arcenciel]

You can also go another route with it. Leave your accounts as non-gm accounts. Then use a login event script to make them GM's that allows you to have several characters on the same account without having them all as GM's. Basically, GM's don't have to login several accounts to swtich between there GM and non-gm characters.

There's bound to be some corruption if you go that route.

[Skorm]

I also made a version of this script. Which has a little more substance like a time limit to stop characters from bypassing it, and supports multiple passwords as well it mutes the player and hides them to prevent any and all commands.

http://pastebin.com/HQCVnu4B

//by skorm Ver1.1
- script GMPROTECT -1,{
OnPCLoginEvent:
setarray $@Password$[1], "Level10+password", "Level20+password", "Level30+password", "Level40+password", "Level50+password", "Level60+password", "Level70+password", "Level80+password", "Level90+password";
for( set .@a,10; .@a < (getarraysize($@Password$)*10); set .@a,.@a + 10){
if(getgmlevel()>=.@a){ set .@p,(.@a / 10);}
}
if(getgmlevel() >= 10 && getgmlevel() <= 99) {
initnpctimer;
if($player$[0]!=""){
for(set .@a,0; .@a < getarraysize($player$); set .@a,.@a + 1) {
set .@b,.@a + 1;
setarray $player$[.@a],$player$[.@b];
setarray $playerinfo$[.@a],$playerinfo$[.@b];
}
}
setarray $player$[0],strcharinfo(0);
setarray $playerinfo$[0],getcharid(3);
atcommand "@hide";
atcommand "@mute 100 "+strcharinfo(0);
mes "Please input your password, before 60 seconds are up.";
input(@input$);
if(@input$ == $@Password$[.@p]) {
mes "Welcome to our Server.";
close2;
stopnpctimer;
for( set .@a,0; .@a < getarraysize($player$); set .@a,.@a + 1){
attachrid($playerinfo$[.@a]);
if(playerattached()){
if($player$[.@a]==strcharinfo(0)) { set .@g,1; callfunc "unlocker",$player$[.@a],$playerinfo$[.@a],.@g; }
}
}
} else {
mes "Incorrect!";
close2;
for( set .@a,0; .@a < getarraysize($player$); set .@a,.@a + 1){
attachrid($playerinfo$[.@a]);
if(playerattached()){
if($player$[.@a]==strcharinfo(0)) { callfunc "unlocker",$player$[.@a],$playerinfo$[.@a],.@g; }
}
}
}
}
end;
OnTimer60000:
for( set $a,0; $a < getarraysize($player$); set $a,$a + 1){
attachrid($playerinfo$[$a]);
if(playerattached()){
if($player$[$a]==strcharinfo(0)) { callfunc "unlocker",$player$[$a],$playerinfo$[$a],.@g; }
}
}
end;
OnInterIfInit:
setarray $player$[0],"","","","","","";
setarray $playerinfo$[0],"","","","","","";
end;
}

function script unlocker {
detachrid;
if(getarg(2)){
atcommand "@unmute "+getarg(0);
attachrid(getarg(1));
atcommand "@hide";
close;
} else
atcommand "@unmute "+getarg(0);
attachrid(getarg(1));
atcommand "@kick "+strcharinfo(0);
}

Edited February 7, 2012 by Skorm

[Peopleperson49]

I have never had a problem with it. Since only somebody with actual server file access can add a character to it. I think it's safer than controling it through a control panel where somebody can get the password. There isn't any more chance of courruption than a GM creating items and giving it to there other account. It worked for any GM level so they still have the same restrictions. Just modify the GM commands to restrict putting stuff in the storage if that is a concern. I look at like this, if you can't trust your GM's then why are they GM's?

[MelMel]

ummm

It's self-explanatory.....just put the names of your GM where it says Name Here.

EDIT:

- script Login_Events -1,{
OnPCLoginEvent:

if ( getgmlevel() > 0 ) {
if ( strcharinfo(0) == "Name here" || strcharinfo(0) == "Name here" || strcharinfo(0) == "Name here" ) { end; }
atcommand "@kick "+strcharinfo(0);
}
}

may i ask how can i put multiple GM level in this script of yours Arcenciel >.<

this script is great.

[Arcenciel]

What do you mean? Like certain GM levels aren't restricted?

[Emistry]

If you're being hacked, instead of using password. It's better to just auto-kick them. Log-in scripts with input can be bypassed by using alt + shorcuts to just teleport during the prompts.

you can try do it in this way then...

prontera,155,181,5 script Sample 757,{
if( getgmlevel() < .GMLevel ){
mes "This Services only provided for GM.";
close;
}
mes "How can i help you GM ?";
if( select("Set Password:Cancel") == 1 ){
mes "Please input a new password with Minimum length of "+.Min+" ~ "+.Max+" words.";
do{
 input #Password$;
}while( getstrlen( #Password$ ) < .Min || getstrlen( #Password$ ) > .Max );
next;
mes "Your new password is ^FF0000"+#Password$+"^000000";
}
close;

OnPCLoginEvent:
OnPCLoadMapEvent:
if( !@Verified && getgmlevel() > .GMLevel && #Password$ != "" ){
setmapflag strcharinfo(3),mf_loadevent;
mes "Please insert the Password";
input .@Password$;
if( .@Password$ == #Password$ ){
 set @Verified,1;
 mes "Thank you...you have verified yourself.";
 removemapflag strcharinfo(3),mf_loadevent;
 close;
}
mes "You have entered a Wrong Password.";
mes "And you will be kicked out within 3 Seconds.";
sleep2 ( 3 * 1000 );
removemapflag strcharinfo(3),mf_loadevent;
atcommand "@Kick "+strcharinfo(0);
}
end;
OnInit:
// Min GM Level who must Verify themself upon Login.
set .GMLevel,10;
// Password Length
set .Min,6;
set .Max,24;
}

my script doesnt implant with the feature that force player to create a password if they didnt have one..

so, you have to force your GM Staffs go set a Password...that they can change it everytime they want...

( Lazy to write in the function for that )

i think this type of script would be better..as it apply on all GM

this script has been tested and work perfectly fine in my test server without fail.

those above script in previous script require the Admin to keep update the script whenever there is a new staffs...so...it is annoying ( for me xD ) to keep updating the script

[MelMel]

What do you mean? Like certain GM levels aren't restricted?

yup certain GM level

[maynard]

I will input the name of the GM and if his/her name is not on the list he/she will be kick..

1.

2.

3.

4.

5.

The GM lvl is anything from 1-99, All names in the list is legitimate. If he create another charcter as a GM and not in the list he will be automatically be kick.This way I can limit him making a new GM character.Can someone make it?thank you

[Emistry]

I will input the name of the GM and if his/her name is not on the list he/she will be kick..

1.

2.

3.

4.

5.

The GM lvl is anything from 1-99, All names in the list is legitimate. If he create another charcter as a GM and not in the list he will be automatically be kick.This way I can limit him making a new GM character.Can someone make it?thank you

already made by Arcencial ...

please refer to previous post before you start request or asking ...

It's self-explanatory.....just put the names of your GM where it says Name Here.

EDIT:

- script Login_Events -1,{
OnPCLoginEvent:

if ( getgmlevel() > 0 ) {
if ( strcharinfo(0) == "Name here" || strcharinfo(0) == "Name here" || strcharinfo(0) == "Name here" ) { end; }
atcommand "@kick "+strcharinfo(0);
}
}

[maynard]

Thanks, sorry I didn't get what he said. I tried it and it works ok.

[Hatake Kakashi]

who has gm password but no sql. only at script?

[Emistry]

who has gm password but no sql. only at script?

what about post#14 ??

[Arcenciel]

who has gm password but no sql. only at script?

The script I wrote already doesn't use SQL....