Jump to content
  • 0

Woe countdown timer

Reborn

Asked by Reborn,

 Share

Question

Reborn Poring

Reborn

Posted
  • Group:  Members
  • Topic Count:  104
  • Topics Per Day:  0.03
  • Content Count:  290
  • Reputation:   3
  • Joined:  09/29/13
  • Last Seen:  
Posted

Hi everyone does anyone knows how to make a waiting room that has a countdown for woe?

Example woe will start in 10mins and the cound down will be

00:10:00

00:09:59

00:09:58

Etc

Until the countdown ends the woe will start automatically.

Link to comment
Share on other sites

24 answers to this question

Recommended Posts

  • 0
Skorm Metaling

Skorm

Posted
  • Group:  Forum Moderator
  • Topic Count:  33
  • Topics Per Day:  0.01
  • Content Count:  1268
  • Reputation:   382
  • Joined:  02/03/12
  • Last Seen:  
Posted (edited)
4 hours ago, neXus said:

@sikiro

this one is working fine with me

 

There were a few problems when trying to use it with Euphy's WOE controller also I hadn't thought about the fact that 0 actually means something in this script. So getarraysize didn't work correctly when sunday was the last day in your list. To fix that I had to change the days from 1 ~ 7 instead of 0 ~ 6... That on its own was pretty easy but Euphy's script still uses 0 ~ 6 so I had to do a bunch of arbitrary junk to still keep it a standalone npc yet compatible with Euphy's script.

 

2 hours ago, sikiro said:

npc on its own works fine but i would like to combine them.

Firstly don't remove credits. ( Seriously I can't stress that enough. ) Uhh... So I didn't have a lot of time tonight. I will make an integrated version with Euphy's WOE controller but there are a few things with his script that I wanted to change/add. Alternatively you could just put this npc on the same location as his npc but make it invisible with sprite number 139.

Anyways here is a working standalone version that is compatible with Euphy's WOE Controller. ( Sorry @neXus it's the version with Days, Minutes, Seconds. I'll make it easier to change that or something.  )
  

//Skormie's WOE Waitingroom Timer v1.03
//Should natively work with Euphy's WOE Controller.
prontera,151,193,5	script	Woe Time	100,{
end;
OnInit:
	function s;
	function woe_update;
	
	// CONFIG //                  ...If you're not using Euphy's Woe Controller.
	setarray .@start_day,   5, 1; //Day of the week WOE Starts on. (1 for Sunday, 7 is Saturday)
	setarray .@start_hour, 20, 0; //rAthena works on a 24 hour clock.
	.auto_update = 60;            //Auto update timer in seconds.
	
	.woe_len = getarraysize( .@start_day );
	for( .@i = 0; .@i < .woe_len; .@i++ ) {
		.woe_day[ .@i * 4 ] = .@start_day[ .@i ] -1;
		.woe_day[ (.@i * 4) + 1 ] = .@start_hour[ .@i ];
	}
	.woe_len = ( ( .woe_len ) * 4 );
	
	woe_update();

	while ( 1 ) {
		if( !( gettimetick(2) % .auto_update ) )
			woe_update();
		.@woe_tick = .woe_time[.current] - gettimetick(2);
		.@day  = .@woe_tick / 86400;
		.@hour = .@woe_tick % 86400 / 3600;
		.@min  = .@woe_tick % 3600 / 60;
		.@sec  = .@woe_tick % 60;
		.@mes$ = ( .@day  ? .@day  +" day"+    s( .@day )    : "" ) +
		         ( .@hour ? .@hour +" hour"+   s( .@hour )   : "" ) +
		         ( .@min  ? .@min  +" minute"+ s( .@min )    : "" ) +
		         ( .@sec  ? .@sec  +" second"+ s( .@sec, 1 ) : "" );
		delwaitingroom strnpcinfo(0);
		waitingroom ( .woe_len ? ( agitcheck() ? "WOE is Active!" : .@mes$ ) : "WOE is Disabled!" ), 0;
		sleep 1000;
	}
	end;
	
	OnAgitEnd:
		woe_update();
		end;
	
	function s {
		return ( getarg(0) > 1 ? "s" : "" ) + ( getarg(1,0) ? "" : " " );
	}
	function woe_update {
		if( getnpcid( 0, "WOE_CONTROL" ) ) {
			.@Euphy_Len = getarraysize( $WOE_CONTROL );
			copyarray .woe_day, $WOE_CONTROL, .@Euphy_Len;
			.woe_len = .@Euphy_Len;
		}
		
		for( .@a = 0; .@a < .woe_len; .@a += 4 ) {
			.@woe_day[.@a] = ( .woe_day[.@a] - gettime(4) + 7 ) % 7 * 86400;
			.@woe_hour[.@a] = ( .woe_day[.@a+1] * 3600 ) - gettimetick(1);
			.woe_time[.@a] = gettimetick(2) + .@woe_day[.@a] + .@woe_hour[.@a];
			if(gettimetick(2) > .woe_time[.@a])
				.woe_time[.@a] = .woe_time[.@a] + 7 * 86400;
			if( .woe_time[.@a] <= .woe_time[.current] )
				.current = .@a;
		}
	}
}

 

Edited by Skorm
Link to comment
Share on other sites
  • 0
Cyro Poring

Cyro

Posted
  • Group:  Members
  • Topic Count:  8
  • Topics Per Day:  0.00
  • Content Count:  1137
  • Reputation:   290
  • Joined:  04/29/13
  • Last Seen:  
Posted 
-	script	woe_countdown_main	-1,{
	
	OnAgitStart:
		.woe_countdown = 120;
		initnpctimer;
		end;
	
	OnTimer60000:
		.woe_countdown--;
		if ( .woe_countdown < 10 || ( .woe_countdown % 10 ) == 0 ) {
			announce "[WOE] Left "+.woe_countdown+" minute(s)",bc_all;
		}
		if ( .woe_countdown == 1 ) {
			stopnpctimer;
			sleep 30000;
			for ( .@i = 30; .@i > 0; .@i-- ) {
				announce "[WOE] Left "+.woe_countdown+" second(s)",bc_all;
			}
		}
		else setnpctimer 0;
		end;
}

 

Link to comment
Share on other sites
  • 0
Technoken Santa Poring

Technoken

Posted
  • Group:  Members
  • Topic Count:  27
  • Topics Per Day:  0.01
  • Content Count:  505
  • Reputation:   126
  • Joined:  04/04/16
  • Last Seen:  
Posted

@Cyro I think he was referring to a waitingroom that displays the woe countdown. I saw something like that from Toasty's WoE Controller. But I doubt it will work on the latest hash.

Link to comment
Share on other sites
  • 0
Cyro Poring

Cyro

Posted
  • Group:  Members
  • Topic Count:  8
  • Topics Per Day:  0.00
  • Content Count:  1137
  • Reputation:   290
  • Joined:  04/29/13
  • Last Seen:  
Posted

oh i think Toasty's WoE setter have it, i dont know how to make count down timer with npc waiting room

this one shows server time 
  

prontera,155,171,5	script	Sample	757,{
end;

OnInit:
while( 1 ){
	delwaitingroom;
	waitingroom ""+gettimestr( "%H:%M:%S %p",21 ),0;
	sleep 1000;
}
end;
}

 

Link to comment
Share on other sites
  • 0
Reborn Poring

Reborn

Posted
  • Group:  Members
  • Topic Count:  104
  • Topics Per Day:  0.03
  • Content Count:  290
  • Reputation:   3
  • Joined:  09/29/13
  • Last Seen:  
  • Author
Posted

thanks for the infos guys I appreciate it however @Technoken is right I am looking for a count down timer for WOE in a waitingroom form.

Please help me out guys on how to do this.

Link to comment
Share on other sites
  • 0
Technoken Santa Poring

Technoken

Posted
  • Group:  Members
  • Topic Count:  27
  • Topics Per Day:  0.01
  • Content Count:  505
  • Reputation:   126
  • Joined:  04/04/16
  • Last Seen:  
Posted
3 hours ago, neXus said:

thanks for the infos guys I appreciate it however @Technoken is right I am looking for a count down timer for WOE in a waitingroom form.

Please help me out guys on how to do this.

I'm working on an NPC that is something like this. I'll share it once I get it done.

Link to comment
Share on other sites
  • 0
Reborn Poring

Reborn

Posted
  • Group:  Members
  • Topic Count:  104
  • Topics Per Day:  0.03
  • Content Count:  290
  • Reputation:   3
  • Joined:  09/29/13
  • Last Seen:  
  • Author
Posted

Thank you @Technoken Ill wait for it..

Link to comment
Share on other sites
  • 0
Skorm Metaling

Skorm

Posted
  • Group:  Forum Moderator
  • Topic Count:  33
  • Topics Per Day:  0.01
  • Content Count:  1268
  • Reputation:   382
  • Joined:  02/03/12
  • Last Seen:  
Posted (edited)
On 4/19/2017 at 3:16 AM, neXus said:

Thank you @Technoken Ill wait for it..

Something I botched together pretty quick it should natively work with Euphy's WOE Controller. (lightly tested) Let me know if you have any problems. 

//Skormie's WOE Waitingroom Timer v1.02
//Should natively work with Euphy's WOE Controller.
prontera,150,150,5	script	Woe Time	100,{
end;
OnInit:
	function s;
	function woe_update;
	
	.@Euphy_Len = getarraysize( $WOE_CONTROL );
	
	if( .@Euphy_Len ) {
		for( .@i = 0; .@i < .@Euphy_Len; .@i += 4 ) {
			.woe_day[ getarraysize( .woe_day ) ] = $WOE_CONTROL[.@i];
			.woe_hour[ getarraysize( .woe_hour ) ] = $WOE_CONTROL[.@i+1];
		}
	} else {
		setarray .woe_day, 5, 4; //Day of the week WOE Starts on. (0 for Sunday, 6 is Saturday)
		setarray .woe_hour, 16, 20; //rAthena works on a 24 hour clock.
	}
	
	woe_update();

	while ( 1 ) {
		.@woe_tick = .woe_time[.current] - gettimetick(2);
		.@day  = .@woe_tick / 86400;
		.@hour = .@woe_tick % 86400 / 3600;
		.@min  = .@woe_tick % 3600 / 60;
		.@sec  = .@woe_tick % 60;
		.@mes$ = ( .@day  ? .@day  +" day"+    s( .@day )    : "" ) +
				 ( .@hour ? .@hour +" hour"+   s( .@hour )   : "" ) +
				 ( .@min  ? .@min  +" minute"+ s( .@min )    : "" ) +
				 ( .@sec  ? .@sec  +" second"+ s( .@sec, 1 ) : "" );
		delwaitingroom strnpcinfo(0);
		waitingroom agitcheck() ? "WOE is Active!" : .@mes$, 0;
		sleep 1000;
	}
	end;
	
	OnAgitEnd:
		woe_update();
		end;
	
	function s {
		return ( getarg(0) > 1 ? "s" : "" ) + ( getarg(1,0) ? "" : " " );
	}
	function woe_update {
		.@woe_len = getarraysize( .woe_day );
		for( .@a = 0; .@a < .@woe_len; .@a++ ) {
			.@woe_day[.@a] = ( .woe_day[.@a] - gettime(4) + 7 ) % 7 * 86400;
			.@woe_hour[.@a] = ( .woe_hour[.@a] * 3600 ) - gettimetick(1);
			.woe_time[.@a] = gettimetick(2) + .@woe_day[.@a] + .@woe_hour[.@a];
			if(gettimetick(2) > .woe_time[.@a])
				.woe_time[.@a] = .woe_time[.@a] + 7 * 86400;
			if( .woe_time[.@a] <= .woe_time[.current] )
				.current = .@a;
		}
	}
}

(External Link)

Edited by Skorm
  • Upvote 1
Link to comment
Share on other sites
  • 0
Reborn Poring

Reborn

Posted
  • Group:  Members
  • Topic Count:  104
  • Topics Per Day:  0.03
  • Content Count:  290
  • Reputation:   3
  • Joined:  09/29/13
  • Last Seen:  
  • Author
Posted

@Skorm

thanks its working fine.

however I have another request if its okay with you.

Instead of saying " 2 hours 15 minutes 43 seconds " can it be just " 02:15:43 " ?

Link to comment
Share on other sites
  • 0
Skorm Metaling

Skorm

Posted
  • Group:  Forum Moderator
  • Topic Count:  33
  • Topics Per Day:  0.01
  • Content Count:  1268
  • Reputation:   382
  • Joined:  02/03/12
  • Last Seen:  
Posted
6 minutes ago, neXus said:

@Skorm

thanks its working fine.

however I have another request if its okay with you.

Instead of saying " 2 hours 15 minutes 43 seconds " can it be just " 02:15:43 " ?

Sure thing. 

//Skormie's WOE Waitingroom Timer v1.02.1
//Should natively work with Euphy's WOE Controller.
prontera,150,150,5	script	Woe Time	100,{
end;
OnInit:
	function add_zero;
	function woe_update;
	
	.@Euphy_Len = getarraysize( $WOE_CONTROL );
	
	if( .@Euphy_Len ) {
		for( .@i = 0; .@i < .@Euphy_Len; .@i += 4 ) {
			.woe_day[ getarraysize( .woe_day ) ] = $WOE_CONTROL[.@i];
			.woe_hour[ getarraysize( .woe_hour ) ] = $WOE_CONTROL[.@i+1];
		}
	} else {
		setarray .woe_day, 5, 4; //Day of the week WOE Starts on. (0 for Sunday, 6 is Saturday)
		setarray .woe_hour, 16, 20; //rAthena works on a 24 hour clock.
	}
	
	woe_update();

	while ( 1 ) {
		.@woe_tick = .woe_time[.current] - gettimetick(2);
		.@day  = .@woe_tick / 86400;
		.@hour = .@woe_tick % 86400 / 3600;
		.@min  = .@woe_tick % 3600 / 60;
		.@sec  = .@woe_tick % 60;
		.@mes$ = add_zero( .@day ) +
				 add_zero( .@hour ) +
				 add_zero( .@min ) +
				 add_zero( .@sec, 1 );
		delwaitingroom strnpcinfo(0);
		waitingroom agitcheck() ? "WOE is Active!" : .@mes$, 0;
		sleep 1000;
	}
	end;
	
	OnAgitEnd:
		woe_update();
		end;
	function add_zero {
		return ( ( getarg(0) < 10 ) ? "0" : "" )+ getarg(0) +( getarg(1,0) ? "" : ":" );
	}
	function woe_update {
		.@woe_len = getarraysize( .woe_day );
		for( .@a = 0; .@a < .@woe_len; .@a++ ) {
			.@woe_day[.@a] = ( .woe_day[.@a] - gettime(4) + 7 ) % 7 * 86400;
			.@woe_hour[.@a] = ( .woe_hour[.@a] * 3600 ) - gettimetick(1);
			.woe_time[.@a] = gettimetick(2) + .@woe_day[.@a] + .@woe_hour[.@a];
			if(gettimetick(2) > .woe_time[.@a])
				.woe_time[.@a] = .woe_time[.@a] + 7 * 86400;
			if( .woe_time[.@a] <= .woe_time[.current] )
				.current = .@a;
		}
	}
}

 

  • Upvote 2
Link to comment
Share on other sites
  • 0
Technoken Santa Poring

Technoken

Posted
  • Group:  Members
  • Topic Count:  27
  • Topics Per Day:  0.01
  • Content Count:  505
  • Reputation:   126
  • Joined:  04/04/16
  • Last Seen:  
Posted

Dang @Skorm! You just saved us. I already started my script but haven't finished it yet. Guess i'll just use yours. Thanks man! /no1 

  • Upvote 1
Link to comment
Share on other sites
  • 0
Skorm Metaling

Skorm

Posted
  • Group:  Forum Moderator
  • Topic Count:  33
  • Topics Per Day:  0.01
  • Content Count:  1268
  • Reputation:   382
  • Joined:  02/03/12
  • Last Seen:  
Posted
Just now, Technoken said:

Dang @Skorm! You just saved us. I already started my script but haven't finished it yet. Guess i'll just use yours. Thanks man! /no1 

Yeah, sorry about that. Some requests just really catch my attention. I felt like a standalone woe countdown timer has been missing for awhile or if it's here I haven't seen it. Anyways thanks for helping and keep scripting/sharing!

Link to comment
Share on other sites
  • 0
Technoken Santa Poring

Technoken

Posted
  • Group:  Members
  • Topic Count:  27
  • Topics Per Day:  0.01
  • Content Count:  505
  • Reputation:   126
  • Joined:  04/04/16
  • Last Seen:  
Posted
19 minutes ago, Skorm said:

Yeah, sorry about that. Some requests just really catch my attention. I felt like a standalone woe countdown timer has been missing for awhile or if it's here I haven't seen it. Anyways thanks for helping and keep scripting/sharing!

That's better, providing your script. I'm amazed how fast you did the script. lol I was confused doing trial and errors to make the script work. And you just popped up showing a working script. 

Link to comment
Share on other sites
  • 0
Reborn Poring

Reborn

Posted
  • Group:  Members
  • Topic Count:  104
  • Topics Per Day:  0.03
  • Content Count:  290
  • Reputation:   3
  • Joined:  09/29/13
  • Last Seen:  
  • Author
Posted

@Skorm and @Technoken thank you for both of you. Its working fine.

Link to comment
Share on other sites
  • 0
sikiro Poring

sikiro

Posted
  • Group:  Members
  • Topic Count:  16
  • Topics Per Day:  0.00
  • Content Count:  171
  • Reputation:   15
  • Joined:  01/26/12
  • Last Seen:  
Posted (edited)

errorguild.png.408c46543b2877df246e22d2203d6600.png@Skorm hey skorm can this be added to the npc? i add it at the begining on the script but it counts forwards and it shows weird characters. 

Edited by sikiro
Link to comment
Share on other sites
  • 0
Skorm Metaling

Skorm

Posted
  • Group:  Forum Moderator
  • Topic Count:  33
  • Topics Per Day:  0.01
  • Content Count:  1268
  • Reputation:   382
  • Joined:  02/03/12
  • Last Seen:  
Posted
3 hours ago, sikiro said:

errorguild.png.408c46543b2877df246e22d2203d6600.png@Skorm hey skorm can this be added to the npc? i add it at the begining on the script but it counts forwards and it shows weird characters. 

I'm not sure what you've added. Xd

Link to comment
Share on other sites
  • 0
sikiro Poring

sikiro

Posted
  • Group:  Members
  • Topic Count:  16
  • Topics Per Day:  0.00
  • Content Count:  171
  • Reputation:   15
  • Joined:  01/26/12
  • Last Seen:  
Posted

I did this the npc does not error but when I set a castle to active the message shows up like that however if no castles are active it still has like a 4 hour countdown idk why lol.

  

//===== rAthena Script =======================================
//= Euphy's WOE Controller
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.5
//===== Compatible With: =====================================
//= rAthena SVN r16958+
//===== Description: =========================================
//= A controller for War of Emperium designed for
//= simplicity and ease of use.
//= Many concepts taken from ToastOfDoom's script,
//= and "rewards" function originally by Goddameit.
//===== Additional Comments: =================================
//= Be sure to disable the default agit controllers!
//== npc\guild\agit_controller.txt
//== npc\guild2\agit_start_se.txt
//============================================================

// Information NPC
//============================================================
prontera,149,193,4	script	WOE Information	835,{
	doevent "WOE_CONTROL::OnMenu";
	end;
OnAgitStart:
	while(agitcheck()) {
		misceffect EF_BEGINSPELL6;
		sleep 425;
	}
	end;
OnInit:
	function add_zero;
	function woe_update;
	
	.@Euphy_Len = getarraysize( $WOE_CONTROL );
	
	if( .@Euphy_Len ) {
		for( .@i = 0; .@i < .@Euphy_Len; .@i += 4 ) {
			.woe_day[ getarraysize( .woe_day ) ] = $WOE_CONTROL[.@i];
			.woe_hour[ getarraysize( .woe_hour ) ] = $WOE_CONTROL[.@i+1];
		}
	} else {
		setarray .woe_day, 5, 4; //Day of the week WOE Starts on. (0 for Sunday, 6 is Saturday)
		setarray .woe_hour, 16, 20; //rAthena works on a 24 hour clock.
	}
	
	woe_update();

	while ( 1 ) {
		.@woe_tick = .woe_time[.current] - gettimetick(2);
		.@day  = .@woe_tick / 86400;
		.@hour = .@woe_tick % 86400 / 3600;
		.@min  = .@woe_tick % 3600 / 60;
		.@sec  = .@woe_tick % 60;
		.@mes$ = add_zero( .@day ) +
				 add_zero( .@hour ) +
				 add_zero( .@min ) +
				 add_zero( .@sec, 1 );
		delwaitingroom strnpcinfo(0);
		waitingroom agitcheck() ? "WOE is Active!" : .@mes$, 0;
		sleep 1000;
	}
	end;
	
	OnAgitEnd:
		woe_update();
		end;
	function add_zero {
		return ( ( getarg(0) < 10 ) ? "0" : "" )+ getarg(0) +( getarg(1,0) ? "" : ":" );
	}
	function woe_update {
		.@woe_len = getarraysize( .woe_day );
		for( .@a = 0; .@a < .@woe_len; .@a++ ) {
			.@woe_day[.@a] = ( .woe_day[.@a] - gettime(4) + 7 ) % 7 * 86400;
			.@woe_hour[.@a] = ( .woe_hour[.@a] * 3600 ) - gettimetick(1);
			.woe_time[.@a] = gettimetick(2) + .@woe_day[.@a] + .@woe_hour[.@a];
			if(gettimetick(2) > .woe_time[.@a])
				.woe_time[.@a] = .woe_time[.@a] + 7 * 86400;
			if( .woe_time[.@a] <= .woe_time[.current] )
				.current = .@a;
		}
	}
}

// Script Core
//============================================================
-	script	WOE_CONTROL	-1,{
function Disp_Owner; function Add_Zero;

OnInit:

// -----------------------------------------------------------
//  Configuration settings.
// -----------------------------------------------------------

	set .CastleWarp,0;		// 1: Always enable all castle warps. | 0: Warp only to active castles.
	set .AutoKick,1;		// Automatically kick players from inactive castles during WOE? (1:yes / 0:no)
	set .NoOwner,0; 		// Automatically kick players from unconquered castles outside of WOE? (1:yes / 0:no)
	set .ExitWarp,0;		// Warp all players from castles when WOE ends? (1:yes / 0:no)
	set .GMAccess,99;		// GM level required to access Session Manager.

// -----------------------------------------------------------
//  Reward options.
// -----------------------------------------------------------
//  [1] Enable rewards.
//  [2] Mail all rewards.
//      - If not set, players receive items in their inventory.
//      - Only ONE item can be sent via mail, plus Zeny.
//      - Note that offline players do NOT receive rewards.
//  [4] Only reward Guild Masters.
//      - If not set, all guild members are rewarded.
//      - If mailing is enabled (option 2), offline Guild Masters WILL receive rewards.
//  [8] Duplicate IP check.
//      - Members in a guild with the same IP address are not rewarded.
//      - If Guild Masters is enabled (option 4), this feature is not used.
// -----------------------------------------------------------

	// Combine values as needed (e.g. 1|8 = 1+8 = 9).
	set .Options, 1|8;

	// Rewards per castle.
	// -- when given directly: <itemID>,<amount>{,<itemID>,<amount>,...}
	// -- via mail (option 2): <itemID>,<amount>,<Zeny>
	setarray .Reward[0],14001,1;

// -----------------------------------------------------------
//  Constants (leave this section alone).
// -----------------------------------------------------------

	setarray .Castles$[0],
		"prtg_cas01","prtg_cas02","prtg_cas03","prtg_cas04","prtg_cas05",
		"payg_cas01","payg_cas02","payg_cas03","payg_cas04","payg_cas05",
		"gefg_cas01","gefg_cas02","gefg_cas03","gefg_cas04","gefg_cas05",
		"aldeg_cas01","aldeg_cas02","aldeg_cas03","aldeg_cas04","aldeg_cas05",
		"arug_cas01","arug_cas02","arug_cas03","arug_cas04","arug_cas05",
		"schg_cas01","schg_cas02","schg_cas03","schg_cas04","schg_cas05";
	setarray .EndLabel$[0],"ar01","ar02","ar03","ar04","ar05","sc01","sc02","sc03","sc04","sc05";
	setarray .Days$[0],"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday";
	setarray .Regions$[0],"Prontera","Payon","Geffen","Aldebaran","Arunafeltz","Schwaltzvalt";
	setarray .Map$[0],"prt_gld","pay_gld","gef_fild13","alde_gld","aru_gld","sch_gld";
	setarray .MapX[0],134,240,153,111,208,121,295,317,140,204,214,308,143,193,305,48, 95,142,239,264,158,83, 68,299,292,293,288, 97,137, 71;
	setarray .MapY[0], 65,128,137,240,240,233,116,293,160,266, 75,240,240,278, 87,83,249, 85,242, 90,272,47,155,345,107,100,252,196, 90,315;

// -----------------------------------------------------------

	set .Size, getarraysize($WOE_CONTROL);
	if (.AutoKick || .NoOwner)
		for(set .@i,0; .@i<30; set .@i,.@i+1) {
			setmapflag .Castles$[.@i], mf_loadevent;
			setd "."+.Castles$[.@i], .@i;
		}
	if (!agitcheck() && !agitcheck2()) sleep 4000;
	set .Init,1;

OnMinute00:
	freeloop(1);
	if (agitcheck() || agitcheck2()) {
		for(set .@i,0; .@i<.Size; set .@i,.@i+4)
			if (gettime(4) == $WOE_CONTROL[.@i] && gettime(3) == $WOE_CONTROL[.@i+2]) {
			OnWOEEnd:
				announce "The War Of Emperium is over!",bc_all|bc_woe;
				AgitEnd; AgitEnd2;
				sleep 1000;
				for(set .@j,0; .@j<30; set .@j,.@j+1) {
					if (.Active[0]&(1<<.@j)) Disp_Owner(.Castles$[.@j],1);
					if (.ExitWarp) maprespawnguildid .Castles$[.@j],0,3;
				}
				if (.Options&1 && .Active[0] && .ForceEnd != 2) callsub OnReward, .Active[0];
				deletearray .Active[0],2;
				if (.ForceEnd) { set .ForceEnd,0; end; }
				break;
			}
	}
	if ((!agitcheck() && !agitcheck2()) || .Init) {
		if (!agitcheck() && !agitcheck2()) set .Init,0;
		for(set .@i,0; .@i<.Size; set .@i,.@i+4)
			if (gettime(4) == $WOE_CONTROL[.@i] && gettime(3) >= $WOE_CONTROL[.@i+1] && gettime(3) < $WOE_CONTROL[.@i+2]) {
				deletearray .Active[0],2;
				set .Active[0], $WOE_CONTROL[.@i+3];
				if (.Init) { AgitEnd; AgitEnd2; }
				else announce "The War Of Emperium has begun!",bc_all|bc_woe;
				sleep 1000;
				AgitStart; AgitStart2;
				for(set .@j,0; .@j<30; set .@j,.@j+1) {
					if (.Active[0]&(1<<.@j)) {
						if (!.Init) Disp_Owner(.Castles$[.@j],0);
						set .Active[1], .Active[1] | (1<<((.@j/5)+1));
					} else {
						if (.@j<20) {
							donpcevent "Agit#"+.Castles$[.@j]+"::OnAgitEnd";
							killmonster .Castles$[.@j], "Agit#"+.Castles$[.@j]+"::OnAgitBreak";
						} else {
							donpcevent "Manager#"+.Castles$[.@j]+"::OnAgitEnd2";
							killmonster .Castles$[.@j], "Steward#"+.EndLabel$[.@j-20]+"::OnStartArena";
						}
					}
				}
				break;
			}
	}
	set .Init,0;
	end;

function Disp_Owner {
	set .@o, getcastledata(getarg(0),1);
	if (.@o) announce "The ["+getcastlename(getarg(0))+"] castle "+((getarg(1))?"has been conquered":"is currently held")+" by the ["+getguildname(.@o)+"] guild.",bc_all|bc_woe;
	else announce "The ["+getcastlename(getarg(0))+"] castle is currently unoccupied.",bc_all|bc_woe;
	return;
}
function Add_Zero {
	return ((getarg(0)<10)?"0":"")+getarg(0)+(getarg(1,0)?".":":")+"00";
}

OnReward:
	set .@sql$, ((.Options&4)?"position = 0":"online = 1");
	if (.Options&2) set .@str$,gettimestr("%B %d, %Y",21);
	freeloop(1);
	for(set .@i,0; .@i<30; set .@i,.@i+1)
		if (getarg(0)&(1<<.@i)) {
			set .@gid, getcastledata(.Castles$[.@i],1);
			if (!.@gid) continue;
			set .@size, query_sql("SELECT account_id,char_id FROM `guild_member` WHERE guild_id = '"+.@gid+"' AND "+.@sql$,.@aid,.@cid);
			for(set .@j,0; .@j<.@size; set .@j,.@j+1) {
				if (.Options&8 && !(.Options&4)) {
					set .@ip$, replacestr(getcharip(.@aid[.@j]),".","a");
					if (getd(".@ip_"+.@i+"_"+.@ip$)) continue;
					setd ".@ip_"+.@i+"_"+.@ip$,1;
				}
				if (.Options&2) {
					query_sql("INSERT INTO `mail` (send_name,dest_id,title,message,nameid,amount,identify,zeny,time) VALUES ("+
					          "'no-reply',"+.@cid[.@j]+",'** Siege Reward: "+getcastlename(.Castles$[.@i])+" **',"+
					          "'Brave one,% % Congratulations!% Your guild has successfully occupied% territory in the War of Emperium on% "+.@str$+".% % % % % [ Your reward is attached. ]',"+
					          .Reward[0]+","+.Reward[1]+",0,"+.Reward[2]+",UNIX_TIMESTAMP(NOW()))");
					if (!getd(".@str_"+.@cid[.@j]) && isloggedin(.@aid[.@j],.@cid[.@j])) {
						setd ".@str_"+.@cid[.@j],1;
						message rid2name(.@aid[.@j]),"You've got mail! Please re-login to update your mailing list.";
					}
				} else if (isloggedin(.@aid[.@j])) {
					for(set .@k,0; .@k<getarraysize(.Reward); set .@k,.@k+2)
						getitem .Reward[.@k], .Reward[.@k+1], .@aid[.@j];
					message rid2name(.@aid[.@j]),"You have been rewarded for conquering "+getcastlename(.Castles$[.@i])+".";
				}
			}
		}
	if (.Options&2) query_sql("UPDATE `mail` SET message = REPLACE(message,'%',CHAR(13)) WHERE send_name = 'no-reply'");
	return;

OnPCLoadMapEvent:
	if (!compare(strcharinfo(3),"g_cas")) end;
	if (((.AutoKick && .Active[0]) || (.NoOwner && !getcastledata(strcharinfo(3),1))) && !(.Active[0]&(1<<getd("."+strcharinfo(3))))) {
		if (getcharid(2) && getcastledata(strcharinfo(3),1) == getcharid(2)) end;
		sleep2 1000;
		message strcharinfo(0), getcastlename(strcharinfo(3))+" is currently inactive.";
		sleep2 5000;
		if (compare(strcharinfo(3),"g_cas")) warp "SavePoint",0,0;
	}
	end;

OnMenu:
while(1) {
	mes "[WOE Information]";
	if (agitcheck() || agitcheck2()) {
		if (.Active[0]) {
			for(set .@i,0; .@i<.Size; set .@i,.@i+4)
				if (gettime(4) == $WOE_CONTROL[.@i] && gettime(3) >= $WOE_CONTROL[.@i+1] && gettime(3) < $WOE_CONTROL[.@i+2]) {
					set .@i, $WOE_CONTROL[.@i+2];
					break;
				}
			mes "The War of Emperium is ^0055FFactive^000000 until ^FF0000"+Add_Zero(.@i)+"^000000 in the following regions:";
			mes " ";
			for(set .@i,0; .@i<6; set .@i,.@i+1)
				if (.Active[1]&(1<<(.@i+1))) mes " > ^777777"+.Regions$[.@i]+"^000000";
		} else
			mes "The War of Emperium is ^0055FFactive^000000.";
	} else {
		for(set .@i,0; .@i<.Size; set .@i,.@i+4)
			if ((gettime(4) == $WOE_CONTROL[.@i] && gettime(3) <= $WOE_CONTROL[.@i+1]) || gettime(4) < $WOE_CONTROL[.@i]) {
				setarray .@time[0],$WOE_CONTROL[.@i],$WOE_CONTROL[.@i+1];
				break;
			}
		if (!getarraysize(.@time))
			setarray .@time[0],$WOE_CONTROL[0],$WOE_CONTROL[1];
		mes "The War of Emperium is ^777777inactive^000000.";
		if (.Size) {
			mes " ";
			mes "The next session will begin";
			mes "on ^0055FF"+.Days$[.@time[0]]+"^000000 at "+Add_Zero(.@time[1])+"^000000.";
		}
	}
	next;
	switch(select(""+((.CastleWarp || .Active[1])?" ~ Warp to castles...":"")+": ~ Check schedule...: ~ View castle owners...:"+((getgmlevel()<.GMAccess || !getgmlevel())?"":" ~ Manage sessions...")+": ~ ^777777Cancel^000000")) {
	case 1:
		if (.CastleWarp) set .@clr$,"^0055FF";
		set .@menu$,"";
		for(set .@i,0; .@i<6; set .@i,.@i+1) {
			if (.CastleWarp || .Active[1]&(1<<(.@i+1)))
				set .@menu$, .@menu$+" ~ "+((.Active[1]&(1<<(.@i+1)))?.@clr$:"^777777")+.Regions$[.@i]+" Castles^000000";
			set .@menu$, .@menu$+":";
		}
		set .@i, select(.@menu$)-1;
		set .@menu$,"";
		for(set .@j,.@i*5; .@j<(.@i*5)+5; set .@j,.@j+1) {
			if (.CastleWarp || .Active[0]&(1<<.@j))
				set .@menu$, .@menu$+" ~ "+((.Active[0]&(1<<.@j))?.@clr$:"^777777")+getcastlename(.Castles$[.@j])+"^000000";
			set .@menu$, .@menu$+":";
		}
		set .@j, select(.@menu$)-1;
		warp .Map$[.@i],.MapX[(.@i*5)+.@j],.MapY[(.@i*5)+.@j];
		close;
	case 2:
		mes "[Schedule]";
		if (.Size) {
			freeloop(1);
			for(set .@i,0; .@i<.Size; set .@i,.@i+4) {
				mes "> ^FF0000"+.Days$[$WOE_CONTROL[.@i]]+" ("+Add_Zero($WOE_CONTROL[.@i+1])+"-"+Add_Zero($WOE_CONTROL[.@i+2])+")^000000";
				for(set .@j,0; .@j<30; set .@j,.@j+1)
					if ($WOE_CONTROL[.@i+3]&(1<<.@j)) mes "  ~ "+getcastlename(.Castles$[.@j])+" ^777777("+.Castles$[.@j]+")^000000";
				if (.@i+4 < .Size) mes " ";
			}
			freeloop(0);
		} else
			mes "No times are configured.";
		next;
		break;
	case 3:
		mes "[Castle Ownership]";
		for(set .@i,0; .@i<6; set .@i,.@i+1) {
			set .@k, .@i*5;
			mes "> ^FF0000"+.Regions$[.@i]+"^000000";
			for(set .@j,.@k; .@j<(.@k+5); set .@j,.@j+1) { 
				set .@t, getcastledata(.Castles$[.@j],1);
				mes "  ~ "+getcastlename(.Castles$[.@j])+": "+((.@t)?"^0055FF"+getguildname(.@t):"^777777unoccupied")+"^000000";
			}
			if (.@i < 5) mes " ";
		}
		next;
		break;
	case 4:
	while(1) {
		mes "[Session Manager]";
		mes "There are ^0055FF"+(.Size/4)+" session(s)^000000 configured.";
		mes "What would you like to do?";
		next;
		switch(select(" ~ Add a session...: ~ Delete a session...: ~ Reload settings...:"+((agitcheck() || agitcheck2())?" ~ End WOE session...":"")+": ~ ^777777Go back^000000")) {
		case 1:
			mes "[New Session]";
			if (.Size > 127) {
				mes "You have already reached the maximum of 32 sessions.";
				next;
				break;
			}
			mes "Select a day.";
			next;
			set .@Day, select(" ~ "+implode(.Days$,": ~ "))-1;
			mes "[New Session]";
			mes "Select a start time for ^0055FF"+.Days$[.@Day]+"^000000.";
			next;
			set .@menu$,"";
			for(set .@i,0; .@i<23; set .@i,.@i+1)
				set .@menu$, .@menu$+" ~ "+Add_Zero(.@i,1)+":";
			set .@Start, select(.@menu$)-1;
			mes "[New Session]";
			mes "Select an end time for ^0055FF"+.Days$[.@Day]+"^000000.";
			next;
			set .@menu$,"";
			for(set .@i,.@Start+1; .@i<24; set.@i,.@i+1)
				set .@menu$, .@menu$+" ~ "+Add_Zero(.@i,1)+":";
			set .@End, select(.@menu$)+.@Start;
			for(set .@i,0; .@i<.Size; set .@i,.@i+4)
				if (.@Day == $WOE_CONTROL[.@i] &&
				   ((.@Start >= $WOE_CONTROL[.@i+1] && .@Start < $WOE_CONTROL[.@i+2]) ||
				    (.@End > $WOE_CONTROL[.@i+1] && .@End <= $WOE_CONTROL[.@i+2]) ||
				    (.@Start <= $WOE_CONTROL[.@i+1] && .@End >= $WOE_CONTROL[.@i+2]))) {
					mes "[New Session]";
					mes "The chosen times overlap with an existing session.";
					next;
					set .@d,1;
					break;
				}
			if (.@d) { set .@d,0; break; }
			set .@Castle,0;
			while(1) {
				mes "[New Session]";
				mes "^0055FF"+.Days$[.@Day]+" ("+Add_Zero(.@Start)+"-"+Add_Zero(.@End)+")^000000";
				mes " > Castles:";
				if (!.@Castle)
					mes "   ~ ^777777(none selected)^000000";
				else for(set .@i,0; .@i<30; set .@i,.@i+1)
					if (.@Castle&(1<<.@i)) mes "   ~ "+getcastlename(.Castles$[.@i])+" ("+.Castles$[.@i]+")";
				next;
				set .@menu$,((.@Castle)?" ~ ^FF0000Finished...^000000":"")+":";
				for(set .@i,0; .@i<30; set .@i,.@i+1)
					set .@menu$, .@menu$+" ~ "+((.@Castle&(1<<.@i))?"^0055FF":"")+getcastlename(.Castles$[.@i])+" ("+.Castles$[.@i]+")^000000:";
				set .@i, select(.@menu$)-1;
				if (.@i)
					set .@Castle, .@Castle^(1<<(.@i-1));
				else {
					mes "[New Session]";
					mes "Are you sure?";
					next;
					switch(select(" ~ ^0055FFAdd session...^000000: ~ Continue selecting castles...: ~ ^777777Cancel^000000")) {
					case 1:
						for(set .@i,0; .@i<.Size; set .@i,.@i+4)
							if ((.@Day == $WOE_CONTROL[.@i] && .@End <= $WOE_CONTROL[.@i+1]) || .@Day < $WOE_CONTROL[.@i]) {
								set .@d,1;
								break;
							}
						if (!.@d) { set .@d,1; set .@i,.Size; }
						copyarray $WOE_CONTROL[.@i+4], $WOE_CONTROL[.@i], .Size-.@i;
						setarray $WOE_CONTROL[.@i], .@Day, .@Start, .@End, .@Castle;
						set .Size, getarraysize($WOE_CONTROL);
					case 3:
						mes "[New Session]";
						mes ((.@d)?"Session added.":"Cancelled.");
						next;
						set .@d,1;
					case 2:
						break;
					}
					if (.@d) { set .@d,0; break; }
				}
			}
			break;
		case 2:
			mes "[Remove Session]";
			if (!.Size) {
				mes "There are no sessions configured.";
				next;
				break;
			}
			mes "Select a session to remove.";
			next;
			set .@menu$,"";
			for(set .@i,0; .@i<.Size; set .@i,.@i+4)
				set .@menu$, .@menu$+" ~ "+.Days$[$WOE_CONTROL[.@i]]+" ("+Add_Zero($WOE_CONTROL[.@i+1],1)+"-"+Add_Zero($WOE_CONTROL[.@i+2],1)+"):";
			set .@menu$, .@menu$+" ~ ^777777Cancel^000000";
			set .@i, select(.@menu$)-1;
			if (.@i == (.Size/4)) break;
			mes "[Remove Session]";
			mes "Delete ^0055FF"+.Days$[$WOE_CONTROL[.@i*4]]+"'s^000000 session?";
			mes "This action cannot be undone.";
			next;
			set .@j, select(" ~ ^FF0000Delete session...^000000: ~ ^777777Cancel^000000");
			mes "[Remove Session]";
			if (.@j == 2)
				mes "Cancelled.";
			else {
				deletearray $WOE_CONTROL[.@i*4],4;
				set .Size, getarraysize($WOE_CONTROL);
				mes "Session deleted.";
			}
			next;
			break;
		case 3:
			mes "[Reload Settings]";
			mes "This will trigger all events related to new session configurations, if any.";
			if (agitcheck() || agitcheck2()) {
				mes " ";
				mes "Be aware that this will disrupt the current WOE session.";
			}
			next;
			set .@i, select(" ~ ^0055FFReload settings...^000000: ~ ^777777Cancel^000000");
			mes "[Reload Settings]";
			if (.@i == 2) mes "Cancelled.";
			else {
				set .Init,1;
				donpcevent "WOE_CONTROL::OnMinute00";
				mes "Variables have been re-initialized.";
			}
			next;
			break;
		case 4:
			mes "[Force Agit End]";
			if (!agitcheck() && !agitcheck2())  {
				mes "WOE has already ended.";
				next;
				break;
			}
			mes "This command will safely execute all AgitEnd events.";
			mes " ";
			mes "Kill the current WOE session?";
			next;
			set .@i, select(" ~ ^FF0000End session...^000000:"+((.Options&1)?" ~ ^FF0000End session without rewards...^000000":"")+": ~ ^777777Cancel^000000");
			mes "[Force Agit End]";
			if (.@i == 3)
				mes "Cancelled.";
			else {
				set .ForceEnd, .@i;
				donpcevent "WOE_CONTROL::OnWOEEnd";
				mes "WOE session terminated.";
			}
			next;
			break;
		case 5:
			set .@d,1; break;
		}
		if (.@d) { set .@d,0; break; }
		} break;
	case 5:
		close;
	} }
}

 

Link to comment
Share on other sites
  • 0
Skorm Metaling

Skorm

Posted
  • Group:  Forum Moderator
  • Topic Count:  33
  • Topics Per Day:  0.01
  • Content Count:  1268
  • Reputation:   382
  • Joined:  02/03/12
  • Last Seen:  
Posted
3 minutes ago, sikiro said:

I did this the npc does not error but when I set a castle to active the message shows up like that however if no castles are active it still has like a 4 hour countdown idk why lol.

Oh dang yeah I'll look into it when I get home.

Link to comment
Share on other sites
  • 0
sikiro Poring

sikiro

Posted
  • Group:  Members
  • Topic Count:  16
  • Topics Per Day:  0.00
  • Content Count:  171
  • Reputation:   15
  • Joined:  01/26/12
  • Last Seen:  
Posted

@Skorm no problem I appreciate it thank you!

Link to comment
Share on other sites
  • 0
Reborn Poring

Reborn

Posted
  • Group:  Members
  • Topic Count:  104
  • Topics Per Day:  0.03
  • Content Count:  290
  • Reputation:   3
  • Joined:  09/29/13
  • Last Seen:  
  • Author
Posted

@sikiro

this one is working fine with me

 

Link to comment
Share on other sites
  • 0
sikiro Poring

sikiro

Posted
  • Group:  Members
  • Topic Count:  16
  • Topics Per Day:  0.00
  • Content Count:  171
  • Reputation:   15
  • Joined:  01/26/12
  • Last Seen:  
Posted

npc on its own works fine but i would like to combine them.

Link to comment
Share on other sites
  • 0
sikiro Poring

sikiro

Posted
  • Group:  Members
  • Topic Count:  16
  • Topics Per Day:  0.00
  • Content Count:  171
  • Reputation:   15
  • Joined:  01/26/12
  • Last Seen:  
Posted

@Skorm i did not remove credits i was at work and wanted to show u what i did to it.

Link to comment
Share on other sites
  • 0
Reborn Poring

Reborn

Posted
  • Group:  Members
  • Topic Count:  104
  • Topics Per Day:  0.03
  • Content Count:  290
  • Reputation:   3
  • Joined:  09/29/13
  • Last Seen:  
  • Author
Posted

@Skorm

its seems everything is working to me even if the variable for sunday is 0. The countdown is working fine. it automatically starts the WoE and end the WoE to the date and time the I set it up.

P.S

even if I use this one its still working fine. 

//Skormie's WOE Waitingroom Timer v1.02.1
//Should natively work with Euphy's WOE Controller.
prontera,150,150,5	script	Woe Time	100,{
end;
OnInit:
	function add_zero;
	function woe_update;
	
	.@Euphy_Len = getarraysize( $WOE_CONTROL );
	
	if( .@Euphy_Len ) {
		for( .@i = 0; .@i < .@Euphy_Len; .@i += 4 ) {
			.woe_day[ getarraysize( .woe_day ) ] = $WOE_CONTROL[.@i];
			.woe_hour[ getarraysize( .woe_hour ) ] = $WOE_CONTROL[.@i+1];
		}
	} else {
		setarray .woe_day, 5, 4; //Day of the week WOE Starts on. (0 for Sunday, 6 is Saturday)
		setarray .woe_hour, 16, 20; //rAthena works on a 24 hour clock.
	}
	
	woe_update();

	while ( 1 ) {
		.@woe_tick = .woe_time[.current] - gettimetick(2);
		.@day  = .@woe_tick / 86400;
		.@hour = .@woe_tick % 86400 / 3600;
		.@min  = .@woe_tick % 3600 / 60;
		.@sec  = .@woe_tick % 60;
		.@mes$ = add_zero( .@day ) +
				 add_zero( .@hour ) +
				 add_zero( .@min ) +
				 add_zero( .@sec, 1 );
		delwaitingroom strnpcinfo(0);
		waitingroom agitcheck() ? "WOE is Active!" : .@mes$, 0;
		sleep 1000;
	}
	end;
	
	OnAgitEnd:
		woe_update();
		end;
	function add_zero {
		return ( ( getarg(0) < 10 ) ? "0" : "" )+ getarg(0) +( getarg(1,0) ? "" : ":" );
	}
	function woe_update {
		.@woe_len = getarraysize( .woe_day );
		for( .@a = 0; .@a < .@woe_len; .@a++ ) {
			.@woe_day[.@a] = ( .woe_day[.@a] - gettime(4) + 7 ) % 7 * 86400;
			.@woe_hour[.@a] = ( .woe_hour[.@a] * 3600 ) - gettimetick(1);
			.woe_time[.@a] = gettimetick(2) + .@woe_day[.@a] + .@woe_hour[.@a];
			if(gettimetick(2) > .woe_time[.@a])
				.woe_time[.@a] = .woe_time[.@a] + 7 * 86400;
			if( .woe_time[.@a] <= .woe_time[.current] )
				.current = .@a;
		}
	}
}

I dont see any error or experience unusual while the both script are running.

What I did was I combined your timer to Euphy's WoE Controller.

Link to comment
Share on other sites
  • 0
HappyMan Poring

HappyMan

Posted
  • Group:  Members
  • Topic Count:  20
  • Topics Per Day:  0.01
  • Content Count:  191
  • Reputation:   24
  • Joined:  07/19/14
  • Last Seen:  
Posted

@Skorm do you have 2 hours woe count down?

Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 Share
Go to question listing
×
×
  • Create New...