[ Nova's Script Collection ]

Nova · August 26, 2015

As opposed to my previous thread made here, this one will have scripts I share with the community.

I'll be adding more as time goes by, but I intend to share quite a bit. :]

Do whatever you want with these, just don't claim them as your own or sell them of course.

And if you could add credits to them that'd be great as well! If at least on your Features page or on the announcement when the script is added to your server.

Enjoy!

1. Countdown Mini-Game (Cross-Post from Summer Festival Collection):

//===== rAthena Script =======================================
//= Countdown Mini-Game Script
//===== By: ==================================================
//= Nova http://www.novaragnarok.com
//============================================================

summer01,124,121,6	script	Countdown#summ	904,{

	if ( .start == 0 ) {
	.@n$ = "[ ^FF0000Countdown^000000 ]";
	mes .@n$;
	mes "In order to win, you must click me after counting down to 0.";
	mes "Cost of participation is ^3355FF2 Festival Coins^000000";
	mes "If you win, I'll give you ^3355FF35 Coins^000000";
	@novacountdown = 0;
	deltimer "Countdown#summ::OnCountdown";
	next;

	switch(select("Play Countdown:Leave")){

	case 1:
			if (@NovaCount > gettimetick(2)) { .@t = @NovaCount - gettimetick(2); dispbottom "Countdown: You must wait "+.@t+" seconds before playing again."; end; }
			if (.start == 1) { dispbottom "Countdown: Somebody is already playing. Wait for them to finish."; end; }
			if(countitem(6767) < 2) { mes .@n$; mes "You don't have enough coins."; end; }
			initnpctimer;
			delitem 6767,2;
			@NovaCount = gettimetick(2) + 60;
			.start = 1;
			close2;
			.player$ = strcharinfo(0);
			
			.@timer = rand(8,11);
			.@r = rand(600,1000);
			.@timer1 = .@timer*.@r;
			.@timer2 = .@timer1+.@r;
			emotion 27;
			showscript "Countdown: "+.player$+"! Count in your head, and click me again when the timer reaches 0.",.gid$;
			dispbottom "Countdown: Count in your head, and click me on the NPC again when the timer reaches 0.";
			sleep2 5000;
			addtimer .@timer1,"Countdown#summ::OnCountdown";
			addtimer .@timer2,"Countdown#summ::OnCountdown2";
			.@time$ = .@timer;
			showscript .@time$,.gid$;
			sleep2 .@r;
			.@time$ = .@timer-1;
			showscript .@time$,.gid$;
			sleep2 .@r;
			.@time$ = .@timer-2;
			showscript .@time$,.gid$;
			end;

		case 2:
		end;

	}

	end;
	}

	if ( .start == 1 && .player$ == strcharinfo(0) ) {
			if (@novacountdown == 0) { showscript "Countdown: You went too quickly. You lose.",.gid$; .start = 0; @NovaCount = gettimetick(2) + 30; stopnpctimer; end; }
			if (@novacountdown == 1) { showscript "Countdown: Nice one. You win this time "+.player$+".",.gid$; .start = 0; getitem 6767,35; @NovaCount = gettimetick(2) + 30; stopnpctimer; end; }
			if (@novacountdown == 2) { showscript "Countdown: You went too slowly. You lose.",.gid$; .start = 0; @NovaCount = gettimetick(2) + 30; stopnpctimer; end; }
			end;
		} else {
		dispbottom "Somebody is already playing Countdown. Wait for them to finish.";
		end;
		}

OnInit:
	.gid$ = getnpcid(0);
	end;

OnCountdown:
	@novacountdown = 1;
	end;

OnCountdown2:
	@novacountdown = 2;
	end;

OnTimer30000:
	stopnpctimer;
	showscript "Countdown: You went too slowly. You lose.",.gid$; .start = 0;
	end;

}

2. Character Deletion on Death:

//===== rAthena Script =======================================
//= Character Deletion on Death Script
//===== By: ==================================================
//= Nova http://www.novaragnarok.com
//============================================================


-    script    PERMANENTDEATH    -1,{
end;

OnPCDieEvent:
    set .@deadplayer,getcharid(0);
    message strcharinfo(0),"Game Over";
    atcommand "@kick "+strcharinfo(0);
    set .@j, getarraysize( .char_delete$ );
    for (.@i = 0; .@i < .@j; .@i++) {
        query_sql("DELETE FROM `"+ .char_delete$[.@i] +"` WHERE `char_id` = '"+ .@deadplayer +"'");
    }
    query_sql "DELETE FROM `party` WHERE `leader_char` = '"+.@deadplayer+"'";
    end;
    
OnInit:
setarray .char_delete$[0],"bonus_script","char","cart_inventory","elemental","friends","global_reg_value","guild","guild_member","homunculus","hotkey","inventory","memo","mercenary","mercenary_owner","pet","quest","sc_data","skill","skillcooldown";
end;
    
}

3. Instance Based Dead Branch Room:

//===== rAthena Script =======================================
//= Dead Branch Room Script
//===== By: ==================================================
//= Nova http://www.novaragnarok.com
//============================================================

npc_in,9,103,6	script	Branch Manager	89,{
	.@n$ = "[^3355FF Branch Manager ^000000]";
	.@party_id = getcharid(1);
	.@p_name$ = getpartyname(.@party_id);
	.@instance$ = "Dead Branch Room";

		if (getcharid(0) == getpartyleader(.@party_id,2)) {
		mes .@n$;
		mes "Would you like to reserve a private Dead Branch Room? It'll cost 100K for two full hours.";
		mes "Remember, the room and everything inside it will disappear after this time frame.";
			next;
			switch(select("Rent Dead Branch Room:Enter the Room:Cancel")) {
			case 1:
				if (Zeny < 100000) { 
				mes .@n$;
				mes "Are you trying to sneak in without paying? You must bring me 100,000 Zeny if you wish to rent a room.";
				cutin "",255;
				end;
				}
				if (instance_create(.@instance$) < 0) {
					mes "Party Name: "+.@p_name$;
					mes "Party Leader: "+strcharinfo(0);
					mes "^0000ff"+.@instance$+" ^000000- Reservation Failed!";
					close;
				}
				Zeny -= 100000;
				mes .@n$;
				mes "Talk to me again to enter the room now that your room has been reserved.";
				close;
			case 2:
				callsub L_Enter,0,1;
			case 3:
			mes .@n$;
			mes "Have a nice day then, and enjoy Dead Branching in Juperos.";
				close;
			}
		}
		mes .@n$;
		mes "You may enter a Dead Branch Room if it's been reserved by your party leader.";
		next;
		switch(select("Enter the Dead Branch Room:Cancel")) {
		case 1:
			callsub L_Enter,1,1;
		case 2:
			mes .@n$;
			mes "Have a nice day then, and enjoy Dead Branching in Juperos.";
			end;
		}
		
L_Enter:
	switch(instance_enter("Dead Branch Room")) {
	case 3:
		mes .@n$;
		mes "You are not in a party.";
		close;
	case 2:
			mes .@n$;
		mes "The private Dead Branch Room has not yet been reserved.";
		mes "The party leader did not pay the fee.";
		close;
	case 1:
			mes .@n$;
		mes "You can enter the room after making a party.";
		close;
	case 0:
		mapannounce "npc_in", strcharinfo(0)+" of the party, "+.@p_name$+", is entering a Dead Branch Room.",bc_map,"0x00ff99",FW_NORMAL,12;
		end;
	}
}

//==================================================================================
//--------|Map Flags|---------------------------------------------------------------
//==================================================================================

pvp_n_1-3	mapflag	monster_noteleport
pvp_n_1-3	mapflag	nowarpto
pvp_n_1-3	mapflag	nomemo
pvp_n_1-3	mapflag	noteleport
pvp_n_1-3	mapflag	nosave	SavePoint
pvp_n_1-3	mapflag	nopenalty

Make sure you add the following line to your instance_db

16,Dead Branch Room,7200,pvp_n_1-3,99,95,pvp_n_1-3

Feel free to change the number to whatever is appropriate in your server.

You'll likely also need to unset the PvP mapflags from that map, or move it to a different map, and feel free to add the following to the map according to what you want for your server:

MvP Summoner, Healer, Kafra, Dead Branch Seller.

4. In-game Item Descriptions:

//===== rAthena Script =======================================
//= In-game Item Descriptions Script
//===== By: ==================================================
//= Nova http://www.novaragnarok.com
//============================================================

-	script	itemdescs	-1,{
end;

OnInit:
	bindatcmd "ii2",strnpcinfo(3)+"::OnAtcommand";
	bindatcmd "itemdesc",strnpcinfo(3)+"::OnAtcommand";
	end;
	
OnAtcommand:
  mes "^3355FF[ Item Description Search ]^000000";
  .@item = atoi(.@atcmd_parameters$[0]);
  mes "<ITEMLINK>"+getitemname(.@item)+"<INFO>"+.@item+"</INFO></ITEMLINK>";
  mes "Click on the name of the item above.";
  end;

}

5. Dismounter:

npc_in,50,110,3	script	Dismounter	105,{

	mes "[ Dismounter ]";
	mes "It seems you're stuck on your mount! I'll make that thing run away for you.";
	next;
	
	switch(select("Please! I can't get rid of it.:No! I want to keep my mount.")) {
		case 1:
			mes "[ Dismounter ]";
			mes "OOGA BOOGA!";
			if(SC_ALL_RIDING>=1) { sc_start SC_ALL_RIDING,1,0; }
			mes "- Your mount has ran away -";
			end;
		case 2:
			mes "[ Dismounter ]";
			mes "Keep your mount for all I care!";
			end;
	}
}

If you rent a Halter Lead/Reins of Mount, sometimes they'll expire and leave your players stuck on them. This NPC gives them the option to dismount without the reins.

6. Level Up Function:

-	script	LevelUpQuotes	-1,{
end;

OnInit:
	setarray .q$,"I have advanced forward!","There's no stopping me now!","Look at me go!","There's more where that came from.","This isn't even my final form!";
	.num1 = getarraysize(.q$);
	setarray .maxq$,"I've made it!","I never thought I'd become this strong...","I have reached my final form.";
	.num2 = getarraysize(.maxq$);
	end;

OnPCBaseLvUpEvent:
	if( BaseLevel > 149 && getstatus(SC_ITEMBOOST) == 0 ) { sc_start SC_ITEMBOOST,180000,200; }
	if( BaseLevel == 175 ) { .@r = rand(.num2); showscript strcharinfo(0)+" : "+.maxq$[.@r]; }
	else { .@r = rand(.num1); showscript strcharinfo(0)+" : "+.q$[.@r]; }
	if( getstatus(SC_INCREASEAGI) != 1 ) { sc_start SC_INCREASEAGI,30000,10; }
	end;
}

This one displays one of several quotes when a player levels up on top of their head.

I removed the quotes but you can use your own, I have around 30 on my server. (Just replace Quote 1-3 and add as many as you'd like)

It also gives the player 30 seconds of level 10 INC agi, and if the player is 150 or higher, 3 minutes of Bubble Gum effect.

7. Dice Hack:

-	script	dicehack	-1,{
end;

OnInit:
	bindatcmd "dice",strnpcinfo(3)+"::OnAtcommand";
	end;
	
OnAtcommand:
	if (getgroupid() < 10) { end; }
	.@dice = atoi(.@atcmd_parameters$[0]);
	.@dice += 57; 
	emotion .@dice,1;
	end;

}

This one's a silly one. It lets your GMs use @dice 1 to @dice 6 to cheat at dice. It's fun. :]

8. The Claw:

//===== rAthena Script =======================================
//= The Claw Script
//===== By: ==================================================
//= Nova http://www.novaragnarok.com
//============================================================

moc_para01,13,25,6	script	The Claw	562,{
    set .@n$,"[ ^FF0000The Claw^000000 ]";
    mes .@n$;
    mes "Instructions:";
	mes "You may pay 250 coins for a random headgear, or 500 to pick a specific headgear.";
	mes "New hats will be in stock every month.";
    next;
	
		switch(select("Random Hat",""+.hat1$+"",""+.hat2$+"",""+.hat3$+"",""+.hat4$+"")) {
			case 1:
				mes .@n$;
				mes "Are you sure you want a random hat for 250 Gold Coins?";
				next;
				switch(select("Yes","No")) {
					case 1:
						if (countitem(671)) < (500) { mes .@n$,"You do not have enough Gold Coins to operate The Claw."; close; }
						if (checkweight(.@pickedhat,1) == 0 ) { mes .@n$,"The Claw detects you are over your weight limit."; close; }
						set .HatRandomArray,rand(1,4);
						delitem 671,250;
						if(.HatRandomArray==1) { getitem .hatid1,1; }
						if(.HatRandomArray==2) { getitem .hatid2,1; }
						if(.HatRandomArray==3) { getitem .hatid3,1; }
						if(.HatRandomArray==4) { getitem .hatid4,1; }
						mes .@n$;
						mes "The Claw has chosen. Here is your hat.";
						close;
					case 2:                 
						mes .@n$;
						mes "Come back and play again!";
							close;
				}
				end;
			case 2:
				.@pickedhat = .hatid1;
				.@pickedname$ = .hat1$;
				break;
			case 3:
				.@pickedhat = .hatid2;
				.@pickedname$ = .hat2$;
				break;
			case 4:
				.@pickedhat = .hatid3;
				.@pickedname$ = .hat3$;
				break;
			case 5:
				.@pickedhat = .hatid4;
				.@pickedname$ = .hat4$;
				break;
		}
            
		mes .@n$;
		mes "Are you sure you want to buy: ";
		mes "<ITEMLINK>"+.@pickedname$+"<INFO>"+.@pickedhat+"</INFO></ITEMLINK> ?";
		next;
		
			switch(select("Buy for 500 Gold Coins","Cancel")) {
				case 1:
					if (countitem(671)) < (500) { mes .@n$,"You do not have enough Gold Coins to operate The Claw."; close; }
					if (checkweight(.@pickedhat,1) == 0 ) { mes .@n$,"The Claw detects you are over your weight limit."; close; }
					delitem 671,500;
					getitem .@pickedhat,1;
					mes .@n$;
					mes "The Claw has retrieved your "+.@pickedname$+". Enjoy it.";
					close;	
				case 2:
					mes .@n$;
					mes "Come back and play again!";
					close;
			}
	
OnInit:
	.hatid1 = 5474;
	.hatid2 = 5102;
	.hatid3 = 18678;
	.hatid4 = 5793;
	.hat1$ = getitemname(.hatid1);
	.hat2$ = getitemname(.hatid2);
	.hat3$ = getitemname(.hatid3);
	.hat4$ = getitemname(.hatid4);
	end;
	
}

Just change the IDs of the hats you want to rotate in for the month at the bottom, and change the Gold Coin text as well as the ID to whatever item you wish.

9. Search iRO Wiki/RMS Script (In-Game Browser):

//===== rAthena Script =======================================
//= Search iRO Wiki/RMS Script (In-Game Browser)
//===== By: ==================================================
//= Nova http://www.novaragnarok.com
//============================================================

-	script	NovaSearch	-1,{
end;

OnInit:
	bindatcmd "rms",strnpcinfo(3)+"::OnAtcommand";
	bindatcmd "irowiki",strnpcinfo(3)+"::OnAtcommand";
	bindatcmd "search",strnpcinfo(3)+"::OnAtcommand";
	.n$ = "^3355FF[ Search Engine ]^000000";
	end;
	
OnAtcommand:
	mes .n$;
	mes "Note that some information on RMS and iRO wiki might be outdated or inaccurate.";
	mes "Take your search results with a grain of salt!";
	next;
	
		switch(select("RMS Monster Search:RMS Item Search:iRO Wiki Search:Close")){
			case 1:
				input .@search$;
				mes .n$;
				mes "<URL>Click here to open the browser!<INFO>http://ratemyserver.net/index.php?all_mob_select=%23&mob_id=&mob_name="+.@search$+"&element=-1&race=-1&size=-1&mlvsn=0&mlv=&mlv2=&bxpsn=0&exp=&exp2=&jxpsn=0&jexp=&jexp2=&flee=&dr=95&hit=&hr=100&rgc=0&immu=0&mvp=0&minib=0&aggr=0&assi=0&sense=0&det=0&natk=0&immo=0&chcha=0&loot=0&chtar=0&plt=0&sort_r=0&sort_o=0&page=re_mob_db&f=1&mob_search=Search,1000,1000</INFO></URL>";
				close;
			case 2:
				input .@search$;
				mes .n$;
				mes "<URL>Click here to open the browser!<INFO>http://ratemyserver.net/index.php?page=re_item_db&item_id=&iname="+.@search$+"&itype=-1&islot_sign=-1&islot=-1&ij%5B+%5D=-1&iju=-1&idesc=&iscript=&i_ele=-1&i_status=-1&i_race=-1&i_bonus=-1&icfix=&sort_r=0&sort_o=0&isearch=Search,1000,1000</INFO></URL>";
				close;
			case 3:
				input .@search$;
				mes .n$;
				mes "<URL>Click here to open the browser!<INFO>http://irowiki.org/w/index.php?search="+.@search$+",1000,1000</INFO></URL>";
				close;
			case 4:
				end;
		}
	end;
}

This one's pretty simple but neat as well. It allows opening iRO wiki and RMS with searches on the in-game browser.

10. Crystal Chaos Mini-Game

//===== rAthena Script =======================================
//= Crystal Chaos Mini-Game Script
//===== By: ==================================================
//= Nova http://www.novaragnarok.com
//============================================================

prontera,152,175,6	script	Crystal Chaos#summ	762,{

	.@n$ = "[ ^FF0000Crystal Chaos^000000 ]";
	mes .@n$;
	mes "You must think you have good eyes.";
	mes "When the shadow stops moving, select which shadow you think it stopped on.";
	mes "Playing costs ^3355FF"+.costqty+"x "+getitemname(.costid)+"^000000. If you win, you will get ^3355FF"+.rewardqty+"x "+getitemname(.rewardid)+"^000000.";
	next;
	
		switch(select("Play Crystal Chaos:Leave")){
			case 1:
				if(.start == 0) {
				
					if (@NovaCrystal > gettimetick(2)) {
						.@t = @NovaCrystal - gettimetick(2); 
						dispbottom "Crystal Chaos: You must wait "+.@t+" seconds before playing Crystal Chaos again."; 
						end; 
					}
					
					if(countitem(.costid) < .costqty) {
						mes .@n$; 
						mes "You don't have enough "+getitemname(.rewardid)+"."; 
						end; 
					}
					
				delitem .costid,.costqty;
				@NovaCrystal = gettimetick(2) + 60;
				.start = 1;
				initnpctimer;
				
				mes .@n$;
				mes "Press next to start the game.";
				mes "Pay close attention to the Crystal's shadow,";
				mes "When the shadow stops moving, select which shadow you think it stopped on.";
				next;
				
				mes .@n$;
				mes "- Round 1 -";
				donpcevent "Crystal#summshufreal::OnRound1";
				donpcevent "Crystal#summshufreal::OnEnable";
				mes "Which Crystal did the shadow stop on?";
				next;
				
				.@choice = .x[select("Left Crystal:Middle Crystal:Right Crystal") - 1];
				
				if(getvariableofnpc(.shadow, "Crystal#summshufreal") != .@choice ) {
					showscript "You lose",.pchaos$; 
					.start = 0; 
					@NovaCrystal = gettimetick(2) + 60; 
					end; 
				}
				
				mes .@n$;
				mes "Congratulations, now for round 2!";
				showscript "Round 2",.pchaos$;
				next;
				
				mes .@n$;
				mes "- Round 2 -";
				donpcevent "Crystal#summshufreal::OnRound2";
				donpcevent "Crystal#summshufreal::OnEnable";
				mes "Which Crystal did the shadow stop on?";
				next;
				
				.@choice = .x[select("Left Crystal:Middle Crystal:Right Crystal") - 1];
				
				if(getvariableofnpc(.shadow, "Crystal#summshufreal") != .@choice ) {
					showscript "You lose",.pchaos$; 
					.start = 0; 
					@NovaCrystal = gettimetick(2) + 60; 
					end; 
				}
				
				mes .@n$;
				mes "Congratulations, now for round 3!";
				showscript "Round 3",.pchaos$;
				next;
				
				mes .@n$;
				mes "- Round 3 -";
				donpcevent "Crystal#summshufreal::OnRound3";
				donpcevent "Crystal#summshufreal::OnEnable";
				mes "Which Crystal did the shadow stop on?";
				next;
				
				.@choice = .x[select("Left Crystal:Middle Crystal:Right Crystal") - 1];
				
					if(getvariableofnpc(.shadow, "Crystal#summshufreal") != .@choice ) {
						showscript "You lose",.pchaos$; 
						.start = 0; 
						@NovaCrystal = gettimetick(2) + 60; 
						end; 
					}
				
				mes .@n$;
				mes "Congratulations, now for the final round!";
				showscript "Final Round!",.pchaos$;
				next;
				
				mes .@n$;
				mes "- Final Round -";
				donpcevent "Crystal#summshufreal::OnRound4";
				donpcevent "Crystal#summshufreal::OnEnable";
				mes "Which Crystal did the shadow stop on?";
				next;
				
				.@choice = .x[select("Left Crystal:Middle Crystal:Right Crystal") - 1];
				
					if(getvariableofnpc(.shadow, "Crystal#summshufreal") != .@choice ) {
						showscript "You lose",.pchaos$; 
						.start = 0; 
						@NovaCrystal = gettimetick(2) + 60; 
						end; 
					}

				showscript "You win!",.pchaos$;
				getitem .rewardid,.rewardqty;
				.start = 0;
				@NovaCrystal = gettimetick(2) + 60;
				end;
				
				} else {
					mes .@n$;
					mes "Somebody is already playing Crystal Chaos! Please wait until they finish.";
				}

				end;

			case 2:
				mes .@n$;
				mes "Come back when you're ready to play.";
				end;
		}
		
OnTimer60000:
	.start = 0;
	stopnpctimer;
	end;

OnInit:
	.start = 0;
	.pchaos$ = getnpcid(0);
	//Configure the cost of playing as well as the reward.
	.costid = 6767;
	.costqty = 2;
	.rewardid = 6767;
	.rewardqty = 30;
	//Set the following array to be the X Coordinates of the 3 following NPCs
	setarray .x,158,156,154;
	end;
}

//Make sure these NPCs are spaced apart by 2 cells on the X axis. (104, 102, 100) 
//The Coordinates of the last Crystal should be the same as that of the middle one.
//If you change the Y coordinate (174) Make sure you also change it below inside Crystal#summshufreal

prontera,158,174,4	script	Right Crystal#summshuf1	1914,{
end;
}

prontera,156,174,4	script	Middle Crystal#summshuf2	1914,{
end;
}

prontera,154,174,4	script	Left Crystal#summshuf3	1914,{
end;
}

prontera,156,174,4	script	Crystal#summshufreal	1914,{
end;

OnInit:
	npcspeed 20;
	//Set the following array to be the X Coordinate of the 3 previous NPCs (Same as above)
	setarray .x,158,156,154;
	disablenpc "Crystal#summshufreal";
	.y = 174; //Set to be the Y coordinate of the previous NPCs
	end;

OnEnable:
	enablenpc "Crystal#summshufreal";
	.r1 = rand(0,2);
	movenpc "Crystal#summshufreal",.x[.r1],.y;
	sleep .round;

		for (.@i = 0; .@i < 15; .@i++){
			.r2 = rand(0,2);
			while (.r2 == .r1)
			 .r2 = rand(0,2);
			movenpc "Crystal#summshufreal",.x[.r2],.y;
			sleep .round;
			.r1 = rand(0,2);
			while (.r1 == .r2)
			 .r1 = rand(0,2);
			movenpc "Crystal#summshufreal",.x[.r1],.y;
			.shadow = .x[.r1];
			sleep .round;
		}

	disablenpc "Crystal#summshufreal";
	end;

// Speed Configuration, change at will.
OnRound1:
	.round = 150;
	end;

OnRound2:
	.round = 100;
	end;

OnRound3:
	.round = 70;
	end;

OnRound4:
	.round = 45;
	end;

}

This one's one of my favorites despite being pretty simple. Make sure you configure it properly!

I'll be adding more scripts over time. Oh and make sure to relocate these as most are from custom maps.

Edited September 13, 2015 by Nova

privateserver · August 26, 2015

Hello nova, i'm very like your script and server concept.

Azeroth · August 27, 2015

Thank you Nova

Nova · August 27, 2015

Thanks guys! Sadly my server is currently undergoing constant DDoS attacks so it's a bit unstable. ._. Hope to get past it soon, I'll add a new script to the opener.

Azeroth · August 27, 2015

Thanks guys! Sadly my server is currently undergoing constant DDoS attacks so it's a bit unstable. ._. Hope to get past it soon, I'll add a new script to the opener.

What happen?

Nova · August 27, 2015

We're clear for now. :] Server's back up! Though in order to not derail the thread, I'll add another script!

Shared The Claw

Edited August 27, 2015 by Nova

Nagad · August 27, 2015

Thanks for sharing Nova!!

Nova · August 27, 2015

You're welcome Nagad! I added one more script this evening, you'll see I'm a big fan of in-game links. Not sure what to share for my 10th script!

Fixed up the level one and adding some quotes to it so it's not so bare.

Edited August 29, 2015 by Nova

Nova · August 31, 2015

Added one more Mini-Game from my Summer Festival at the bottom! Hope you enjoy it.

nanakiwurtz · August 31, 2015

For script #2, you might want to edit your global_reg_value, because since commit https://github.com/rathena/rathena/commit/6295c77d393555fe5a366f092a75f4cf0d2de933 it has changed name to char_reg_str and char_reg_num

Nova · August 31, 2015

Ah yeah I've yet to merge it. I can only imagine how many of my scripts will blow up, but it'll be worth it. :[

I'll update that one soon. Thanks for the notice Nana.

Azeroth · August 31, 2015

Thank you my friend Nova, for releasing it i really appreciate you.

Currently · September 13, 2015

It seems "showscript" is not working for me..

nanakiwurtz · September 13, 2015

It seems "showscript" is not working for me..

Update your server at least to https://github.com/rathena/rathena/commit/6ad4ed13d130702b99d0dbe54767c6d6945d4876

mrlongshen · March 21, 2016

Script no 10, when losing stuck.

Nova · March 22, 2016

Huh very strange, it worked perfectly for me last time I loaded it. Does the console throw up any warnings when it happens or?

halimforgame · April 24, 2016

Hi, i'm having this error with Countdown Mini Game

[Error]: Loading NPC file: npc/seven/event/countdown.txt

script error on npc/seven/event/countdown.txt line 37

parse_line: expect command, missing function name or calling undeclared func tion

32 : .@timer = rand(8,11);

33 : .@r = rand(600,1000);

34 : .@timer1 = .@timer*.@r;

35 : .@timer2 = .@timer1+.@r;

36 : emotion 27;

* 37 : 's'howscript "Countdown: "+.player$+"! Count in your head, and click me again when the timer reaches 0.",.gid$;

38 : dispbottom "Countdown: Count in your head, and c lick me on the NPC again when the timer reaches 0.";

39 : sleep2 5000;

40 : addtimer .@timer1,"Countdown#summ::OnCountdown";

41 : addtimer .@timer2,"Countdown#summ::OnCountdown2" ;

42 : .@time$ = .@timer;

Stolao · April 25, 2016

It seems "showscript" is not working for me..

Update your server at least to https://github.com/rathena/rathena/commit/6ad4ed13d130702b99d0dbe54767c6d6945d4876

Hi, i'm having this error with Countdown Mini Game

[Error]: Loading NPC file: npc/seven/event/countdown.txt

script error on npc/seven/event/countdown.txt line 37

parse_line: expect command, missing function name or calling undeclared func tion

32 : .@timer = rand(8,11);

33 : .@r = rand(600,1000);

34 : .@timer1 = .@timer*.@r;

35 : .@timer2 = .@timer1+.@r;

36 : emotion 27;

* 37 : 's'howscript "Countdown: "+.player$+"! Count in your head, and click me again when the timer reaches 0.",.gid$;

38 : dispbottom "Countdown: Count in your head, and c lick me on the NPC again when the timer reaches 0.";

39 : sleep2 5000;

40 : addtimer .@timer1,"Countdown#summ::OnCountdown";

41 : addtimer .@timer2,"Countdown#summ::OnCountdown2" ;

42 : .@time$ = .@timer;

read comments before posting a problem maybe?

REKT · April 25, 2016

Hi, i'm having this error with Countdown Mini Game

[Error]: Loading NPC file: npc/seven/event/countdown.txt

script error on npc/seven/event/countdown.txt line 37

parse_line: expect command, missing function name or calling undeclared func tion

32 : .@timer = rand(8,11);

33 : .@r = rand(600,1000);

34 : .@timer1 = .@timer*.@r;

35 : .@timer2 = .@timer1+.@r;

36 : emotion 27;

* 37 : 's'howscript "Countdown: "+.player$+"! Count in your head, and click me again when the timer reaches 0.",.gid$;

38 : dispbottom "Countdown: Count in your head, and c lick me on the NPC again when the timer reaches 0.";

39 : sleep2 5000;

40 : addtimer .@timer1,"Countdown#summ::OnCountdown";

41 : addtimer .@timer2,"Countdown#summ::OnCountdown2" ;

42 : .@time$ = .@timer;

Update your rAthena to the latest 'Showscript' is your problem, might your emulator is outdated.

rakuzas · November 29, 2016

Hi,

Very nice script..

But 4. In-game Item Descriptions: I have problem.. Do I need to edit something to make it works? Because when I put @ii2 501, it not works.. Just show

<ITEMLINK>Red Potion <INFO>501</INFO></ITEMLINK>

Click on the name of the item above.

Nova · December 1, 2016

Depending on your client you might need to replace <ITEMLINK> in your script with just <ITEM>

Some clients don't support the feature.

KucingHitam · December 2, 2016

nice share dude.. awesome script..

Stolao · December 2, 2016

@Nova if you want use my link function https://github.com/Stolao/Npc_Release/blob/master/Custom_Functions/F_ItemLink.txt it should help with those who have issues not supporting item link

PoringSpr17 · December 8, 2016

Very good!

KlugFuchs · January 25, 2017

The Crystal Chaos looks pretty good, I'll give it a try. Thanks!

Sign In

[ Nova's Script Collection ]

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Join the conversation

Recently Browsing 0 members