Request NPC that can check cash point or kafra point of player

[Checkmate]

Hello rAthena community..  ^^

As state above.. Did anyone have,willing to help me to make or sharing some script that can be use to check the the amout that have on player id..??..??

 

 

Great Thankfull... 

[Emistry]

try

http://upaste.me/raw/848a4e

[Patskie]

@checkpoints command

// @checkpoints
-    script    Sample    -1,{
    OnInit:
        bindatcmd("checkpoints", strnpcinfo(3)+ "::OnCheck");
        end;
    OnPCLoginEvent:
        dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;
    OnCheck:
        dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;
}

[Checkmate]

It this script is automated showing when player log in?..?
Did you have any npc for this script?

[Patskie]

It this script is automated showing when player log in?..?

Did you have any npc for this script?

You didn't told that the check will be triggered when a certain player log in. Anyway edit the last post

[Checkmate]

What the different with 
 

OnPCLoginEvent:
dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;

 

and 

 

    OnCheck:
        dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;

???

Can you explain this cuz explanation can make and more user read of this topic will be more understand... 
Tq sir....

 

[Patskie]

When player log in, this event will be triggered. It will display your current cash and kafra points.

OnPCLoginEvent:
        dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;

When you use @checkpoints, this event will be triggered. It will display your current cash and kafra points.

OnCheck:
        dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;

[Checkmate]

Oooo.. Know i know.. 
For the second method i dont have any command like @checkpoints...

Btw im using the first method.. Thanks anyway dude ^ ^


**Edit**

Sir... When relog ther is no cash point showing ... =="
Must restart server?..?

Edited August 19, 2013 by CheckMate

[uDe]

Oooo.. Know i know.. 

For the second method i dont have any command like @checkpoints...

Btw im using the first method.. Thanks anyway dude ^ ^

**Edit**

Sir... When relog ther is no cash point showing ... =="

Must restart server?..?

 

You did have @checkpoints command..

 

It's there, at line 4 :

 

// @checkpoints
-    script    Sample    -1,{
    OnInit:
        bindatcmd("checkpoints", strnpcinfo(3)+ "::OnCheck"); // << This is your new custom @command
        end;
OnPCLoginEvent:
dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;
    OnCheck:
        dispbottom "You currently have " +#CASHPOINTS+ " cash points";
        dispbottom "You currently have " +#KAFRAPOINTS+ " kafra points";
        end;
}

For your problems, please post your script/map-server errors at here. Easy for other members to help you.

Edited August 19, 2013 by uDe

[Checkmate]

Sry late reply..
It show like this.....





????

[Ragnar Lothbrok]

-<TAB>script<TAB>Sample<TAB>-1,{

[uDe]

-<TAB>script<TAB>Sample<TAB>-1,{

[Checkmate]

Same thing... Cash did not shown... T.T

[uDe]

Any error? Post your script here.

 

• If you demand help for existing scripting code, you have to provide this scripting code in your topic.
• If
  your map-server displays error messages concerning the problem you
  have, you will have to provide these error messages in your topic.
• You will have to use the code bbcode tag whenever you would like to post either scripting code or map-server error messages.

 

Scripting Support Rules

 

No need to be told, ask. Just follow the rules and make other members easier to help. No offense.

[Checkmate]

ok sorry.. cuz of this i need to restrart my server about 5 time...
I will try another method ..
But do you have a script that player can click on that npc and that npc told the player how much you cash point....

[Checkmate]

Like above..
requesting npc checker for

 

+Votepoint
+Kafra point
+CashPoint


Like this

 

prontera,52,110,5	script	CashChecker	92,{

OnAtCommand:
OnPCLoginEvent:
	dispbottom "You got "+#CASHPOINTS+" cash points.";
	end;
	
OnInit:
	bindatcmd "cashpoints",strnpcinfo(3)+"::OnAtCommand";
	end;
}

But those were only cash point...

Anyone help...

 

[Emistry]

dispbottom "You got "+#CASHPOINTS+" cash points.";

dispbottom "You got "+#VOTEFORPOINTS+" vote points.";

dispbottom "You got "+#KAFRAPOINTS+" kafra points.";

[Checkmate]

What about the bottom sir..

Did we must put the same thing like..

 

 

bindatcmd "cashpoints",strnpcinfo(3)+"::OnAtCommand";
bindatcmd "votepoints",strnpcinfo(3)+"::OnAtCommand";
bindatcmd "kafrapoints",strnpcinfo(3)+"::OnAtCommand";

???

[Emistry]

you can add it if you want extra command to trigger it.

[Checkmate]

prontera,175,148,3	script	PointChecker	113,{

OnAtCommand:				
OnPCLoginEvent:
	dispbottom "You got "+#KAFRAPOINTS+" kafra points.";
	dispbottom "You got "+#CASHPOINTS+" cash points.";
	dispbottom "You got "+#VOTEFORPOINTS+" vote points.";
	end;
	
OnInit:
	bindatcmd "kafrapoints",strnpcinfo(3)+"::OnAtCommand";
	bindatcmd "cashpoints",strnpcinfo(3)+"::OnAtCommand";
	bindatcmd "votepoints",strnpcinfo(3)+"::OnAtCommand";
	end;
}

 

Did this script is can be used sir..???

 

[uDe]

prontera,175,148,3	script	PointChecker	113,{

OnAtCommand:				
OnPCLoginEvent:
	dispbottom "You got "+#KAFRAPOINTS+" kafra points.";
	dispbottom "You got "+#CASHPOINTS+" cash points.";
	dispbottom "You got "+#VOTEFORPOINTS+" vote points.";
	end;
	
OnInit:
	bindatcmd "kafrapoints",strnpcinfo(3)+"::OnAtCommand";
	bindatcmd "cashpoints",strnpcinfo(3)+"::OnAtCommand";
	bindatcmd "votepoints",strnpcinfo(3)+"::OnAtCommand";
	end;
}

 

Did this script is can be used sir..???

 

 

For me, to be easy, just use 1 command only to check all your points available.

 

Like this :

 

prontera,155,181,5	script	Sample	757,{

OnAtCommand:
OnPCLoginEvent:
	dispbottom "You got "+#CASHPOINTS+" cash points.";
	dispbottom "You got "+#VOTEFORPOINTS+" vote points.";
	dispbottom "You got "+#KAFRAPOINTS+" kafra points.";
	end;
	
OnInit:
	bindatcmd "cashpoints",strnpcinfo(3)+"::OnAtCommand";
	end;
}

[Checkmate]

That would be nice... But when i try to check it only show my kafra point and cash only not vote point... How can i fix that?..?

[Emistry]

because your vote point stored differently....we dont what how you store your vote point ....all we can do is just show you a way that can display a variable ...

[Checkmate]

//===== rAthena Script =======================================
//= Euphy's Quest Shop
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.6b
//===== Compatible With: =====================================
//= rAthena SVN r16862+
//===== Description: =========================================
//= A dynamic quest shop based on Lunar's, with easier config.
//= Includes support for multiple shops & cashpoints.
//= Item Preview script by ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.2 Added category support.
//= 1.3 More options and fixes.
//= 1.4 Added debug settings.
//= 1.5 Replaced categories with shop IDs.
//= 1.6 Added support for purchasing stackables.
//= 1.6a Added support for previewing costumes and robes.
//= 1.6b Added 'disable_items' command.
//============================================================

// Shop NPCs -- supplying no argument displays entire menu.
//	callfunc "qshopbiz"{,<shop ID>{,<shop ID>{,...}}};
//============================================================
revencia,171,148,3	script	Vote4Point-Shop#biz1	562,{ callfunc "qshopbiz"; }


// Script Core
//============================================================
-	script	quest_shop1	-1,{ 
function Add; function Chk; function Slot; function A_An;
OnInit:
	freeloop(1);

// -----------------------------------------------------------
//  Basic shop settings.
// -----------------------------------------------------------

	set .Announce,1;	// Announce quest completion? (1: yes / 0: no)
	set .ShowSlot,1;	// Show item slots? (2: all equipment / 1: if slots > 0 / 0: never)
	set .ShowID,0;  	// Show item IDs? (1: yes / 0: no)
	set .ShowZeny,0;	// Show Zeny cost, if any? (1: yes / 0: no)
	set .MaxStack,100;	// Max number of quest items purchased at one time.

// -----------------------------------------------------------
//  Points variable -- optional quest requirement.
//	setarray .Points$[0],"<variable name>","<display name>";
// -----------------------------------------------------------

	setarray .Points$[0],"#VOTEPOINTS","Vote Points";

// -----------------------------------------------------------
//  Shop IDs -- to add shops, copy dummy data at bottom of file.
//	setarray .Shops$[1],"<Shop 1>","<Shop 2>"{,...};
// -----------------------------------------------------------

	setarray .Shops$[1],"Headgears","Weapons","Combo(Coming Soon)","Mishellenous";

// -----------------------------------------------------------
//  Quest items -- do NOT use a reward item more than once!
//	Add(<shop ID>,<reward ID>,<reward amount>,
//	    <Zeny cost>,<point cost>,
//	    <required item ID>,<required item amount>{,...});
// -----------------------------------------------------------

	Add(1,5788,1,0,8);
	Add(1,19542,1,0,20);
	Add(1,5270,1,0,8);
	Add(1,5344,1,0,8);
	Add(1,19518,1,0,20);
	Add(1,5236,1,0,8);
	Add(1,5308,1,0,8);
	Add(1,5378,1,0,8);
	Add(1,5796,1,0,8);
	Add(1,19520,1,0,20);
	Add(1,5690,1,0,8);
	Add(1,5856,1,0,20);
	Add(1,5858,1,0,20);
	Add(1,5859,1,0,20);
	
	Add(2,13413,1,0,140);
	Add(2,1284,0,0,20);
	Add(2,0,0,0,0);
	Add(2,0,0,0,0);

	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	Add(3,0,1,0,0);
	
	Add(4,12623,1,0,40);
	Add(4,0,0,0,0);
	Add(4,0,0,0,0);
	Add(4,0,0,0,0);
	Add(4,0,0,0,0);
	
	
	
	
	
	
	
	
	


// -----------------------------------------------------------

	freeloop(0);
	set .menu$,"";
	for(set .@i,1; .@i<=getarraysize(.Shops$); set .@i,.@i+1) {
		set .menu$, .menu$+.Shops$[.@i]+":";
		npcshopdelitem "qshopbiz"+.@i,909;
	}
	end;

OnMenu:
	set .@size, getarraysize(@i);
	if (!.@size) set .@i, select(.menu$);
	else if (.@size == 1) set .@i, @i[0];
	else {
		for(set .@j,0; .@j<.@size; set .@j,.@j+1)
			set .@menu$, .@menu$+.Shops$[@i[.@j]]+":";
		set .@i, @i[select(.@menu$)-1];
	}
	deletearray @i[0],getarraysize(@i);
	if (.Shops$[.@i] == "") {
		message strcharinfo(0),"An error has occurred.";
		end;
	}
	dispbottom "Select one item at a time.";
	callshop "qshopbiz"+.@i,1;
	npcshopattach "qshopbiz"+.@i;
	end;

OnBuyItem:
	// .@q[] : RewardID, BoughtAmt, RewardAmt, BaseAmt, ReqZeny, ReqPts, { ReqItem, ReqAmt, ... }
	setarray .@q[0],@bought_nameid[0],((@bought_quantity[0] > .MaxStack)?.MaxStack:@bought_quantity[0]);
	copyarray .@q[3],getd(".q_"+.@q[0]+"[0]"),getarraysize(getd(".q_"+.@q[0]));
	set .@q[2],.@q[1]*.@q[3];
	if (!.@q[2] || .@q[2] > 30000) {
		message strcharinfo(0),"You can't purchase that many "+getitemname(.@q[0])+".";
		end;
	}
	query_sql( "SELECT `point` FROM `vote_point` WHERE `loginname` = MD5('"+getcharid(3)+"')", .@vote );
	mes "[Quest Shop]";
	mes "Reward: ^0055FF"+((.@q[2] > 1)?.@q[2]+"x ":"")+Slot(.@q[0])+"^000000";
	mes "Requirements:";
	if (.@q[4]) mes " > "+Chk(Zeny,.@q[4]*.@q[1])+(.@q[4]*.@q[1])+" Zeny^000000";
	if (.@q[5]) mes " > "+Chk(.@vote,.@q[5]*.@q[1])+(.@q[5]*.@q[1])+" "+.Points$[1]+" ("+.@vote+"/"+(.@q[5]*.@q[1])+")^000000";
	if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
		mes " > "+Chk(countitem(.@q[.@i]),.@q[.@i+1]*.@q[1])+((.ShowID)?"{"+.@q[.@i]+"} ":"")+Slot(.@q[.@i])+" ("+countitem(.@q[.@i])+"/"+(.@q[.@i+1]*.@q[1])+")^000000";
	next;
	setarray @qe[1], getiteminfo(.@q[0],5), getiteminfo(.@q[0],11);
	if (@qe[2] > 0 && ((@qe[1] & 1) || (@qe[1] & 256) || (@qe[1] & 512) || (@qe[1] & 1024) || (@qe[1] & 2048) || (@qe[1] & 4096) || (@qe[1] & 4) || (@qe[1] & 8192)))
		set .@preview,1;
	addtimer 1000, strnpcinfo(0)+"::OnEnd";
	while(1) {
		switch(select(" ~ Purchase ^0055FF"+getitemname(.@q[0])+"^000000:"+((.@preview && !@qe[7])?" ~ Preview...":"")+": ~ ^777777Cancel^000000")) {
		case 1:
			if (@qe[0]) { 
				mes "[Quest Shop]";
				mes "You're missing one or more quest requirements.";
				close;
			}
			if (!checkweight(.@q[0],.@q[2])) {
				mes "[Quest Shop]";
				mes "^FF0000You need "+(((.@q[2]*getiteminfo(.@q[0],6))+Weight-MaxWeight)/10)+" additional weight capacity to complete this trade.^000000";
				close;
			}
			if (.@q[4]) set Zeny, Zeny-(.@q[4]*.@q[1]);
			if (.@q[5])
				query_sql("UPDATE `vote_point` SET `point` = `point` - "+ (.@q[5]*.@q[1]) +" WHERE `loginname` = MD5('"+getcharid(3)+"')");
			if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
				delitem .@q[.@i],.@q[.@i+1]*.@q[1];
			getitem .@q[0],.@q[2];
			if (.Announce) announce strcharinfo(0)+" has created "+((.@q[2] > 1)?.@q[2]+"x "+getitemname(.@q[0]):A_An(getitemname(.@q[0])))+"!",0;
			specialeffect2 EF_FLOWERLEAF;
			close;
		case 2:
			setarray @qe[3], getlook(LOOK_HEAD_BOTTOM), getlook(LOOK_HEAD_TOP), getlook(LOOK_HEAD_MID), getlook(LOOK_ROBE), 1;
			if ((@qe[1] & 1) || (@qe[1] & 4096)) changelook LOOK_HEAD_BOTTOM, @qe[2];
			else if ((@qe[1] & 256) || (@qe[1] & 1024)) changelook LOOK_HEAD_TOP, @qe[2];
			else if ((@qe[1] & 512) || (@qe[1] & 2048)) changelook LOOK_HEAD_MID, @qe[2];
			else if ((@qe[1] & 4) || (@qe[1] & 8192)) changelook LOOK_ROBE, @qe[2];
			break;
		case 3:
			close;
		}
	}

OnEnd:
	if (@qe[7]) {
		changelook LOOK_HEAD_BOTTOM, @qe[3];
		changelook LOOK_HEAD_TOP, @qe[4];
		changelook LOOK_HEAD_MID, @qe[5];
		changelook LOOK_ROBE, @qe[6];
	}
	deletearray @qe[0],8;
	end;

function Add {
	if (getitemname(getarg(1)) == "null") {
		debugmes "Quest reward #"+getarg(1)+" invalid (skipped).";
		return;
	}
	setarray .@j[0],getarg(2),getarg(3),getarg(4);
	for(set .@i,5; .@i<getargcount(); set .@i,.@i+2) {
		if (getitemname(getarg(.@i)) == "null") {
			debugmes "Quest requirement #"+getarg(.@i)+" invalid (skipped).";
			return;
		} else
			setarray .@j[.@i-2],getarg(.@i),getarg(.@i+1);
	}
	copyarray getd(".q_"+getarg(1)+"[0]"),.@j[0],getarraysize(.@j);
	npcshopadditem "qshopbiz"+getarg(0),getarg(1),((.ShowZeny)?getarg(3):0);
	return;
}

function Chk {
	if (getarg(0) < getarg(1)) {
		set @qe[0],1;
		return "^FF0000";
	} else
		return "^00FF00";
}

function Slot {
	set .@s$,getitemname(getarg(0));
	switch(.ShowSlot) {
		case 1: if (!getitemslots(getarg(0))) return .@s$;
		case 2: if (getiteminfo(getarg(0),2) == 4 || getiteminfo(getarg(0),2) == 5) return .@s$+" ["+getitemslots(getarg(0))+"]";
		default: return .@s$;
	}
}

function A_An {
	setarray .@A$[0],"a","e","i","o","u";
	set .@B$, "_"+getarg(0);
	for(set .@i,0; .@i<5; set .@i,.@i+1)
		if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
	return "a "+getarg(0);
}
}

function	script	qshopbiz	{
	deletearray @i[0],getarraysize(@i);
	for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
		set @i[.@i],getarg(.@i);
	doevent "quest_shop1::OnMenu";
	end;
}


// Dummy shop data -- copy as needed.
//============================================================
-	shop	qshopbiz1	-1,909:-1
-	shop	qshopbiz2	-1,909:-1
-	shop	qshopbiz3	-1,909:-1
-	shop	qshopbiz4	-1,909:-1
-	shop	qshopbiz5	-1,909:-1
-	shop	qshopbiz6	-1,909:-1
-	shop	qshopbiz7	-1,909:-1
-	shop	qshopbiz8	-1,909:-1
-	shop	qshopbiz9	-1,909:-1
-	shop	qshopbiz10	-1,909:-1 

Well.. This was my v4p redeem item script... 

How can i know my variable...?

This script was in discuss with Sir Capuche...

 

Edited August 21, 2013 by CheckMate

[Emistry]

dispbottom "My vote points = "+#VOTEPOINTS;

[Capuche]

In fact it's with a query

query_sql( "SELECT `point` FROM `vote_point` WHERE `loginname` = MD5('"+getcharid(3)+"')", .@vote );

.@vote retrieve the point from vote point table

dispbottom "You got "+ .@vote +" vote points.";

 

#VOTEPOINTS is a dummy variable in this script