Login Commands

[Nokia]

Hi,

can i request a login command npc? seems like all links are down.

like the player can choose what command is activated on his next login.

[llchrisll]

Login Commands v1.0

Try this one :I, @autoloot, @noask and @main

If you want another, PM me I will try my best to make modifications, but I'm busy the next weeks at work so I only have a little time.

Regards,

Chris

Edited December 24, 2012 by llchrisll

[Nokia]

Thanks.

[AnnieRuru]

this kind of script can eats up quite some variable space

as we only have 256 permanent player variable limitations

if I'm doing this, I'll use this as a bit-masking to save more variable space

prontera,157,173,5    script    Login Settings    100,{
   .@npcname$ = "["+ strnpcinfo(1) +"]";
//    dispbottom atcommand_login +""; // debugging
   mes .@npcname$;
   mes "Hello, "+strcharinfo(0);
   mes "What setting do you want to change?";
   next;
   for ( .@i = 0; .@i < .total; .@i++ )
       .@menu$ = .@menu$ + .atname$[.@i] +"["+( ( atcommand_login & 1 << .@i )? "^00BB22On^000000" : "^FF2200Off^000000" )+"]:";
   .@s = select( .@menu$ ) -1;
   mes .@npcname$;
   mes "Status: "+( ( atcommand_login & 1 << .@s )? "^00BB22On^000000" : "^FF2200Off^000000");
   next;
   mes .@npcname$;
   if ( select( "I want to "+( ( atcommand_login & 1 << .@s )? "^FF2200disable^000000": "^00BB22enable^000000"  )+" it", "Nothing" ) == 2 ) {
       mes "See ya.";
       close;
   }
   if ( atcommand_login & 1 << .@s ) {
       mes .atname$[.@s] +" is now ^FF2200Off^000000.";
       atcommand "@"+ .atcommand$[.@s] +" off";
   }
   else {
       mes .atname$[.@s] +" is now ^00BB22On^000000.";
       atcommand "@"+ .atcommand$[.@s] +( ( .@s == 1 )? " on": "" );
   }
   atcommand_login = atcommand_login ^ 1 << .@s;
   close;
OnPCLoginEvent:
   if ( !atcommand_login ) end;
   for ( .@i = 0; .@i < .total; .@i++ ) {
       if ( atcommand_login & 1 << .@i ) {
           atcommand "@"+ .atcommand$[.@i] +( ( .@i == 1 )? " on": "" );
           dispbottom .atname$[.@i] +" is now On";
       }
   }
   end;
OnInit:
   setarray .atname$, "Autoloot", "Main Chat", "@NoAsk";
   setarray .atcommand$, "autoloot", "main", "noask";
   .total = 3;
   end;
}

also your script has a bug

the main chat can only enable by

@main on | off

using just @main will ask for the user to input some strings in order to announce something

Edited December 25, 2012 by AnnieRuru

[Capuche]

OMG nice script AnnieRuru !

[Nokia]

i just need to change the arrays if i want to add new commands?

[AnnieRuru]

@Capuche

already saw some of your script out there ... wanna become my student ? xD

http://www.eathena.ws/board/index.php?showtopic=154325

just guess how long have I been scripting, hahaha XD

... anyway, just continue comply the script request section here, and I'll watch over your progress

@Nokia

yup

however you have to know there are certain commands like @main that needs on|off

so you have to watch out which one works, and which one don't

well I guess you can learn by starting how to edit this script ...

Edited December 25, 2012 by AnnieRuru