Help with Event

[Hyoru]

Hi, I found this event here in rathena "Cluck! Cluck! Boom", but its too hard to win, i want raise the chances to win.

Here is the script:

//===== Athena Script =====================================
//= Cluck! Cluck! Boom!
//===== By Keale of VoidRO ================================
//= http://voidro.com
//===== Description =======================================
//= Click the chicken and try retrieve the item at a low
//= chance. If you fail he will nuke, freeze, stone,
//= stun, or make you fall asleep.
//= The prize is configurable and triggered by the NPC.
//===== Credits ===========================================
//= LuTze for his 'Chicken of Punishment' script.
//= BrianL for suggesting the 'switch' command.
//===== Version ===========================================
//= v1.1
//=========================================================
//= v1.0 - First release.
//= v1.1 - Using 'switch rand' instead.
//=========================================================
prontera.gat,147,173,4 script Cluckers 800,{
if ($@startcluck == 1) goto L_playcluck;
cluckcluck:
if (getgmlevel() >= 80) goto cluckadmin;
mes "[Cluckers]";
mes "Cluck cluck! Cluuuuuck?";
mes "Cluck....";
close;

cluckadmin:
mes "[Cluckers]";
mes "Cluck cluck! Cluuuuuck? ^FF0000~Hi GM " + strcharinfo(0) + ", Wanna play today?~^000000";
mes "Cluck cluck... CLUCK! ^FF0000~Just tell me what to do!~^000000";
switch(select("Start Event:Check Prize:Set Prize:Not today Cluckers")) {
case 1:
	next;
	mes "[Cluckers]";
	mes "CLUCK! ^FF0000~Sure thing!~^000000";
	emotion 33;
	close2;
	goto L_cluckannounce;
case 2:
	next;
	mes "[Cluckers]";
	mes "Cluck, cluck cluck... Cluck! ^FF0000~The current prize is^000000 ^008000"+ $cluck_item_amount +" "+ getitemname($cluck_item_id) +".^000000";
	next;
	goto cluckadmin;
case 3:
	next;
	mes "[Cluckers]";
	mes "Cluck cluck? Cluck??? ^FF0000~What should the prize for winning be? Please input the ID.~^000000";
	input $cluck_item_id;
	next;
	mes "[Cluckers]";
	mes "Cluck? cluuuck? ^FF0000~How many if this item should I give away?~^000000";
	input $cluck_item_amount;
	next;
	mes "[Cluckers]";
	mes "Cluck cluck..? Cluck. ^FF0000~So, the prize is^000000 ^008000"+ $cluck_item_amount +" "+ getitemname($cluck_item_id) +"^000000? ^FF0000Great.~^000000";
	emotion 33;
	next;
	goto cluckadmin;
case 4:
	next;
	mes "[Cluckers]";
	mes "Cluck cluck cluck...";
	close;
}
L_cluckannounce:
announce "[Cluck! Cluck! Boom!] Akan Di mulai Di Kota Prontera!!",bc_blue;
initnpctimer;
end;
OnTimer10000:
announce "Tolong Cepat Permainan Ayam Gila Akan Segera Di mulai Di Prontera!",bc_blue;
end;
OnTimer20000:
announce "Bagi Pemenang Akan Mendapatkan Aloe 500 Buah Lho!",bc_blue;
end;
OnTimer30000:
announce "Cara Bermain nya sangat mudah Lho, Kalian Tinggal Klik Npc Ayam nya Setelah itu Jika Kalian Hoki Maka Kalian akan menjadi Pemenang, Berminat??",bc_blue;
end;
OnTimer40000:
announce "Ayooo Teman - Teman Semua Hadiah nya Aloe 500 buah Lumayan Lho!",bc_blue;
set $@startcluck,1;
end;

L_playcluck:
specialeffect2 2;
switch( rand(15) ) {
case 0:
	npctalk "CLUUUUUUCK!!!";
	emotion 23;
	atcommand "@nuke "+strcharinfo(0);
	break;
case 1:
	npctalk "Cluuuuuck!~";
	break;
case 2:
	atcommand "@nuke "+strcharinfo(0);
	break;
case 3:
	sc_start SC_Freeze,10000,0;
	break;
case 4:
	npctalk "CLUUUUUUUUUCK!!!";
	emotion 23;
	atcommand "@nuke "+strcharinfo(0);
	break;
case 5:
	sc_start SC_Sleep,10000,0;
	break;
case 6:
	emotion 29;
	sc_start SC_Stone,10000,0;
	break;
case 7:
	npctalk "CLUUUUUUCK!!!";
	emotion 23;
	atcommand "@nuke "+strcharinfo(0);
	break;
case 8:
	npctalk "Cluck! CLUUUCK!!";
	emotion 23;
	atcommand "@nuke "+strcharinfo(0);
	break;
case 9:
	sc_start SC_Stun,10000,0;
	break;
case 10:
	emotion 29;
	sc_start SC_Sleep,10000,0;
	break;
case 11:
	npctalk "Cluck! Cluck!";
	break;
case 12:
	sc_start SC_Stun,10000,0;
	break;
case 13:
	atcommand "@nuke "+strcharinfo(0);
	break;
default:
	if( rand(50) < 3 ) {
		npctalk "WOOF!...........";
		specialeffect2 72;
		announce "[Cluck! Cluck! Boom!] " + strcharinfo(0) + " Squeezed out the prize! Well done!",0;
		getitem $cluck_item_id,$cluck_item_amount;
		set $@startcluck,0;
	} else {
		npctalk "Cluck! CLUUUCK!!";
		atcommand "@nuke "+strcharinfo(0);
	}
	break;
}
}

Thanks Adv.

Edited April 30, 2012 by Brian
use [codebox] for script/code longer than 10 lines

[kadze]

if( rand(50) < 3) 

change this

example:

if( rand(50) < 10 )

Edited April 28, 2012 by kadze

[Snap]

How can we make this as an automated?

[Emistry]

find this

L_cluckannounce:

add above or below

OnMinute30:
OnClock0100:
OnClock0500:
//etc..

[isaw4sal3]

i've use this script for test and nothing happens.

OnMinute1:

or i can use this one instead.

OnClock0000:

Edited April 30, 2012 by isaw4sal3

[Jheiar]

how to make the chicken moves? ive seen some of the server i played the chicken is moving lol.

[Joseph]

how to make the chicken moves? ive seen some of the server i played the chicken is moving lol.

There is a script command for it: npcwalkto