KoE prize [ auto reward master guild ]

[DevilingKing]

Helo Guys
who can help me to Fix [ auto reward master guild ] only

-    script    KoE    -1,{
OnInit:
    disablenpc "The King#KoE";
    bindatcmd "koe", strnpcinfo(0)+"::OnCommand", 99,99;
    end;
OnCommand:
    if ( compare( .@atcmd_parameters$, "on" ) ) goto L_start;
    else if ( compare( .@atcmd_parameters$, "off" ) ) goto L_end;
    else {
        dispbottom "type - '@koe on' to start the event";
        dispbottom "type - '@koe off' to end the event";
    }
    end;
//OnTue2030:
L_start:
    if ( .start ) end;
    gvgon "guild_vs1";
    announce "The King of Emperium Hill has begun!", bc_all;
    .start = 1;
    enablenpc "The King#KoE";
    $koegid = 0;
    donpcevent "::OnRevKoE";
    maprespawnguildid "guild_vs1", $koegid, 7;
    monster "guild_vs1",49,49,"EMPERIUM",1288,1,"KoE::OnEmpDead";
    end;
//OnTue2130:
L_end:
    gvgoff "guild_vs1";
    announce "The King of Emperium Hill is over!", bc_all;
    .start = 0;
    disablenpc "The King#KoE";
    killmonsterall "guild_vs1"; 
    //maprespawnguildid "guild_vs1", $koegid, 6;

       //Auto Reward to Master Guild
        if ( getcharid(2) == $koegid && getguildmaster(getcharid(2)) == strcharinfo(0) )
       getitem 607,1; // configure prize here

    end;
OnEmpDead:
    $koegid = getcharid(2);
    announce "The current King of Emperium Hill is the ["+ strcharinfo(2) +"] guild.", bc_all;
    donpcevent "::OnRevKoE";
    maprespawnguildid "guild_vs1", $koegid, 6;
    sleep 500;
    if ( .start )
        monster "guild_vs1",49,49,"EMPERIUM",1288,1,"KoE::OnEmpDead";
    end;
}

// KoE Entrance
prontera,147,169,4    script    The King#KoE    811,{
    mes "[The King]";
    if ( !getcharid(2) ) {
        mes "You must have a guild to participate in the ^FF0000King of Emperium Hill Tournament^000000.";
        close;
    }
    mes "Hello.";
    mes "Would you like to participate in the ^FF0000King of Emperium Hill Tournament^000000?";
    if ( select ( "Yes", "No" ) == 2 ) close;
    switch( rand(1,4) ){
        case 1:    warp "guild_vs1", 50, 88; end;
        case 2:    warp "guild_vs1", 88, 50; end;
        case 3:    warp "guild_vs1", 50, 11; end;
        case 4:    warp "guild_vs1", 11, 50; end;
    }
}

// Flags
guild_vs1,49,38,4    script    King of Emperium Hill#1::koe_flag    722,{
    if ( !$koegid ) end;
    mes "[King of Emperium Hill]";
    mes "The Current King of Emperium Hill is the ["+ getguildname($koegid) +"] guild.";
    close;
OnRevKoE:
    flagemblem $koegid;
    end;
}
guild_vs1,61,49,6    duplicate(koe_flag)    King of Emperium Hill#2    722
guild_vs1,38,49,2    duplicate(koe_flag)    King of Emperium Hill#3    722
guild_vs1,49,61,0    duplicate(koe_flag)    King of Emperium Hill#4    722
delusion,86,94,4    duplicate(koe_flag)    King of Emperium Hill#5    722


guild_vs1    mapflag    nobranch
guild_vs1    mapflag    nomemo
guild_vs1    mapflag    nopenalty
guild_vs1    mapflag    noreturn
guild_vs1    mapflag    nosave    SavePoint
guild_vs1    mapflag    noteleport
guild_vs1    mapflag    gvg_noparty
guild_vs1    mapflag    nowarp
guild_vs1    mapflag    nowarpto
guild_vs1    mapflag    guildlock

 

Edited April 7, 2020 by Emistry
codebox

[chatterboy]

ill try. what happen here? ^_^

[DevilingKing]

you can fix this script?

Edited April 7, 2020 by rizal

[Ukiram]

Be specific @rizal please add more information, what we gonna do to your script?

[DevilingKing]

just i wan add auto reward to Master Guild Only

[Emistry]

       //Auto Reward to Master Guild
        if ( getcharid(2) == $koegid && getguildmaster(getcharid(2)) == strcharinfo(0) )
       getitem 607,1; // configure prize here

change to

	//Auto Reward to Master Guild
	if ($koegid) {
		.@aid = getguildmasterid($koegid);
		if (.@aid && isloggedin(.@aid)) {
			getitem 607, 1, .@aid;
		}
	}

 

[DevilingKing]

@Emistry  

i have testing but no work

[ Guild Master Auto Reward ]

 

 

Koe.txt

Edited April 9, 2020 by rizal

[Emistry]

	if ($koegid) {
		.@aid = getcharid(3, getguildmaster($koegid));
		if (.@aid && isloggedin(.@aid)) {
			getitem 607, 10, .@aid;
		}
	}

use this, it will send the reward as long as the master is online.

[Rook1es]

On 4/19/2020 at 1:39 AM, Emistry said:

	if ($koegid) {
		.@aid = getcharid(3, getguildmaster($koegid));
		if (.@aid && isloggedin(.@aid)) {
			getitem 607, 10, .@aid;
		}
	}

use this, it will send the reward as long as the master is online.

Hello what if all members can received the reward?