Quest NPC w/ Question & Answer

skymia · August 10, 2017

does anyone have here a script like this?

I saw this npc in Dark-Ro Force...credits to them...I hope someone have this type of script...thanks

Pay an application Fee (5 Milion Zenies).
Show your survival skills (hunt 5 Majestic Goats).
Do a knowledge Test.

After paying the fees you need to delivery 5 Majestic Goats (They can be bought at @mall).
The last step is the test, you can either answer in small letter (test), in capital letters (TEST), or the normal way (Test), but nothing else will work (i.e teSt). You need at least a 8/10 score to pass the exam. You can't quit the exam before answering all questions. Here are the questions:

What is the special source of energy used by ninjas ?
What is the name of the special eye of the Uchiha clan ?
What is the name of the secret village of the country of Fire ?
What is the prefered jutsu of Naruto ?
How many villages are there in total ?
What is the name of the 'star looking' weapon of the ninjas ?
What is the name of the ultimate warrior/ninja in a particular village ?
What is the name of Kiba's dog ?
Who is the master of Naruto, Sasuke and Sakura ?
What is the name of the nine-tailed demon fox ?

Answers to the question:

chakra
sharingan
konoha
kage bunshin no jutsu
10
shuriken
kage
akamaru
kakashi
kurama

Once you passed on the exam you can choose to be a genin of one country, each country gives a different Head Protector with different status

Item Quest

Headprotector Fire - Country of Fire (Item Effect:+10 STR HP)

Example:
31224,_headprotectorfire,Headprotector Fire,4,0,,200,,3,,1,0xFFFFFFFF,7,2,256,,0,1,1621,{bonus bStr,10; bonus bMaxHP,1000;},{},{}

Headprotector Wind - Country of Wind (Item Effect:+10 AGI HP)
Headprotector Water - Country of Water. (Item Effect:+10 INT HP)
Headprotector Lightning - Country of Lightning. (Item Effect:+10 LUK HP)
Headprotector Earth - Country of Earth. (Item Effect:+10 VIT HP)
Headprotector Sound - Country of Sound. (Item Effect:+10 DEX HP)

Edited August 11, 2017 by skymia

Z3R0 · August 11, 2017

Little rough, I'm tired... but it works enjoy

//===== Script =========================================================================
//= Quizzer
//===== Made by: =======================================================================
//= Z3R0
//===== Current Version: ===============================================================
//= Version: 1.0
//===== Description: ===================================================================
//= rAthena Script Request
//= https://rathena.org/board/topic/112260-quest-npc-w-question-answer
//===== Additional Comments: ===========================================================
//= version 1.0: Initial Attempt
//======================================================================================

prontera,158,173,4	script	Quizzer	92,{ doevent "quizzer_core::OnClick"; }

-	script	quizzer_core	-1,{

	// Function Declarations
	function MesItem;
	function ChkItem;
	function ChkAnswer;

	OnInit:

		// ---------------------------------
		// Configurable Settings
		// ---------------------------------

			// NPC Name to Display
			set(.npc$, "[Quizzer]");

			// Fee to Pay to Begin Quiz
			set(.fee, 5000000);

			// Show # of Question Player is On and Total number of questions?
			set(.ShowQuestionProgress, 1);

			// Number of Answers to Pass Quiz
			set(.NumRightToPass, 8);

			// Required Items Array (Pair: Item_ID, Item_Amount)
			setarray(.required_items[0], 2256, 5); // Here you can setup multiple items in pairs.. (item_id, amount)

			// Array of Questions (Each question must have a corresponding answer)
			setarray(.questions$[0],
				"What is the special source of energy used by ninjas ?",
				"What is the name of the special eye of the Uchiha clan ?",
				"What is the name of the secret village of the country of Fire ?",
				"What is the prefered jutsu of Naruto ?",
				"How many villages are there in total ?",
				"What is the name of the 'star looking' weapon of the ninjas ?",
				"What is the name of the ultimate warrior/ninja in a particular village ?",
				"What is the name of Kiba's dog ?",
				"Who is the master of Naruto, Sasuke and Sakura ?",
				"What is the name of the nine-tailed demon fox ?"
			);

			// Array of Answers (Each Answer must have a corresponding Question)
			setarray(.answers$[0],
				"Chakra",
				"Sharingan",
				"Konoha",
				"Kage bunshin no jutsu",
				"10",
				"Shuriken",
				"Kage",
				"Akamaru",
				"Kakashi",
				"Kurama"
			);

			// Array of Reward Item ID's
			setarray(.rewards[0], 501, 502, 503, 504, 505, 506);
			setarray(.rewards_effects$[0], "+10 STR HP", "+10 AGI HP", "+10 INT HP", "+10 LUK HP", "+10 VIT HP", "+10 DEX HP");

			// STOP!!! DO NOT EDIT BELOW THIS LINE UNLESS YOU KNOW WHAT YOU ARE DOING!!!!
			// check .ShowQuestionProgress
			if (.ShowQuestionProgress > 1) set(.ShowQuestionProgress, 1);

			// Check .required_items
			if (getarraysize(.required_items) % 2 != 0) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Items in .required_items", bc_all, C_YELLOW); end();
			}

			if (getarraysize(.questions$) != getarraysize(.answers$)) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Questions to Answers", bc_all, C_YELLOW); end();
			}

			if (getarraysize(.rewards) != getarraysize(.rewards_effects$)) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Rewards to Reward Effects", bc_all, C_YELLOW); end();
			}

			set(.error, 0);
			end();



	// Player clicks the initial NPC
	OnClick:
		if (.error) {
			mes("There was an error loading this script. Please contact your server administrator");
			close();
		}

		if (quizzer & 8) {
			mes("You have already completed this trial.");
			close();
		}
		else if (quizzer & 4) doevent("quizzer_core::OnComplete");
		else if (quizzer & 2) doevent("quizzer_core::OnQuiz");
		else if (quizzer & 1) doevent("quizzer_core::OnHunt");
		else doevent("quizzer_core::OnStart");
		end();

	OnStart:
		mes(.npc$);

		if (.fee) {
			mes("You will need " + .fee + " zeny to start this trial.");
			mes("Are you ready to proceed?");
			next();
			switch(select("Yes:No")) {
				case 1:

					if (Zeny < .fee) {
						mes("You do not have enough zeny to start this trial.");
						close();
					}

					set(Zeny, Zeny - .fee);
					set(quizzer, 1);

					mes("I need you to gather these items:");
					for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
						mes( MesItem(.required_items, .@i) );
					}
					mes("I await your return");
					close();

				case 2:
				default:
					mes("I knew you weren't capable!");
					close();
			}
		}

	OnHunt:
		mes(.npc$);

		// Determine if they have completed all the required items...
		mes("Checking Requirement Status:");
		for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
			mes(MesItem(.required_items, .@i) + " - " + ChkItem(.required_items[.@i], .required_items[.@i+1]));
		}

		if (@quizzer_no_items == 1) {
			mes("You do not have enough items... You fail!");
			set(@quizzer_no_items, 0);
			close();
		}

		// Passed let's remove the items
		for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
			delitem .required_items[.@i], .required_items[.@i+1];
		}

		mes("Success! You may now start the quiz!");
		next();
		set(quizzer, quizzer^2);
		doevent("quizzer_core::OnQuiz");
		end();

	OnQuiz:
		mes(.npc$);

		.@num_right = 0;

		for(.@i = 0; .@i < getarraysize(.questions$); .@i++) {

			if (.ShowQuestionProgress) {
				mes("Question #" + (.@i+1) + " / " + getarraysize(.questions$));
			}

			mes(.questions$[.@i]);
			input .player_answers$[.@i];

			// Let's compare the answer :D
			.@num_right += ChkAnswer(.answers$[.@i], .player_answers$[.@i]);

			mes("Answer Recorded. Next Question");
			next();

		}

		if (.@num_right >= .NumRightToPass) {
			set(quizzer, quizzer^4);
			mes("You have passed the quiz!");
			next();
			doevent("quizzer_core::OnComplete");
			end();
		}

		mes("You did not pass the quiz!");
		close();

	OnComplete:
		mes(.npc$);
		mes("Well Done Old Chap!");
		mes("Please select from the following rewards");

		set(.@menu$, "");
		for(.@i = 0; .@i < getarraysize(.rewards); .@i++) {
			set(.@menu$, .@menu$ + getitemname(.rewards[.@i]) + " (" + .rewards_effects$[.@i] + "):");
		}

		getitem .rewards[select(.@menu$) - 1], 1;
		set(quizzer, quizzer^8);

		mes("Thank you for participating");
		close();

	// getarg(0) = Array
	// getarg(1) = Index
	function MesItem {
		.@item_id = getelementofarray(getarg(0), getarg(1));
		.@item_amount = getelementofarray(getarg(0), getarg(1) + 1);

		return .@item_amount + ( .@item_amount > 1 ? "x" : "") + " " + getitemname(.@item_id);
	}

	// getarg(0) = item_id
	// getarg(1) = amount required
	function ChkItem {
		.@has = countitem(getarg(0));

		if (.@has >= getarg(1)) {
			return "^000000" + .@has + "^000000/^000000" + getarg(1) + "^000000";
		}

		set(@quizzer_no_items, 1);
		return "^FF0000" + .@has + "^000000/^000000" + getarg(1) + "^000000";
	}

	// getarg(0) = Answer
	// getarg(1) = Player Answer
	function ChkAnswer {
		if (getarg(0) == getarg(1)) return 1;
		else if (strtoupper(getarg(0)) == getarg(1)) return 1;
		else if (strtolower(getarg(0)) == getarg(1)) return 1;
		else return 0;
	}


}

Edited August 11, 2017 by Z3R0

crazyarashi · August 10, 2017

2 hours ago, skymia said:

does anyone have here a script like this?

I saw this npc in Dark-Ro Force...credits to them...I hope someone have this type of script...thanks

Pay an application Fee (5 Milion Zenies).

Show your survival skills (hunt 5 Majestic Goats).

Do a knowledge Test.

After paying the fees you need to delivery 5 Majestic Goats (They can be bought at @mall).

The last step is the test, you can either answer in small letter (test), in capital letters (TEST), or the normal way (Test), but nothing else will work (i.e teSt). You need at least a 8/10 score to pass the exam. You can't quit the exam before answering all questions. Here are the questions:

What is the special source of energy used by ninjas ?

What is the name of the special eye of the Uchiha clan ?

What is the name of the secret village of the country of Fire ?

What is the prefered jutsu of Naruto ?

How many villages are there in total ?

What is the name of the 'star looking' weapon of the ninjas ?

What is the name of the ultimate warrior/ninja in a particular village ?

What is the name of Kiba's dog ?

Who is the master of Naruto, Sasuke and Sakura ?

What is the name of the nine-tailed demon fox ?

Answers to the question:

chakra

sharingan

konoha

kage bunshin no jutsu

10

shuriken

kage

akamaru

kakashi

kurama

Once you passed on the exam you can choose to be a genin of one country, each country gives a different Head Protector with different status:

Country of Fire (+10 STR HP)

Country of Wind (+10 AGI HP)

Country of Water. (+10 INT HP)

Country of Lightning. (+10 LUK HP)

Country of Earth. (+10 VIT HP)

Country of Sound. (+10 DEX HP)

Hello please try this i made it for you :))

Quiz Test.txt

Edited August 10, 2017 by crazyarashi

skymia · August 10, 2017

9 minutes ago, crazyarashi said:

Hello please try this i made it for you :))

Quiz Test.txt

its not working sir

crazyarashi · August 10, 2017

Just now, skymia said:

its not working sir

can you send errors :))

skymia · August 10, 2017

2 minutes ago, crazyarashi said:

can you send errors :))

and this

Country of Fire (+10 STR HP)
Country of Wind (+10 AGI HP)
Country of Water. (+10 INT HP)
Country of Lightning. (+10 LUK HP)
Country of Earth. (+10 VIT HP)
Country of Sound. (+10 DEX HP)

i put the script in items

image.png.436974f2c3a1a7e49c4b4208cad80dd0.png

crazyarashi · August 10, 2017

3 minutes ago, skymia said:

and this

Country of Fire (+10 STR HP)

Country of Wind (+10 AGI HP)

Country of Water. (+10 INT HP)

Country of Lightning. (+10 LUK HP)

Country of Earth. (+10 VIT HP)

Country of Sound. (+10 DEX HP)

i put the script in items

Test agaiiiin :))

Quiz Test.txt

skymia · August 10, 2017

6 minutes ago, crazyarashi said:

Test agaiiiin :))

Quiz Test.txt

crazyarashi · August 10, 2017

3 minutes ago, skymia said:

Quiz Test.txt

skymia · August 10, 2017

12 minutes ago, crazyarashi said:

Quiz Test.txt

crazyarashi · August 10, 2017

Try again :))

Quiz Test.txt

skymia · August 10, 2017

8 minutes ago, crazyarashi said:

Try again :))

Quiz Test.txt

haha still not working man

crazyarashi · August 10, 2017

13 minutes ago, skymia said:

haha still not working man

Quiz Test.txt

skymia · August 10, 2017

3 minutes ago, crazyarashi said:

Quiz Test.txt

crazyarashi · August 10, 2017

Just now, skymia said:

just change the do Quiz2: to goto Quiz02;

skymia · August 10, 2017

the same error man

crazyarashi · August 10, 2017

Quiz Test.txt

Z3R0 · August 10, 2017

lol @ you guys, no one has a test server?

If this doens't get finalized soon, I will write it up

skymia · August 11, 2017

10 hours ago, crazyarashi said:

Quiz Test.txt

prontera,145,173,4	script	Wise Ninja	637,{
	
if( !application ) {
	goto Intro; 
	}
	
	if( application == 1 ) {
	goto Challenge;
	}
	
	if ( application && explanation == 1) {
	goto Challenge2;
	}
	
	if ( application && explanation && challenge == 1){
	goto Quiz;
	}
	
	if ( application && explanation && challenge && passed == 1){
	goto Reward;
	}

	if ( application && explanation && challenge && passed && reward == 1){
	goto Finish;
	}
	
	

Intro:
	mes .npc$;
	mes "Hello, I am travelling shinobi. I am looking for a wise people";
	mes "who can answer all my questions";
	next;
	mes .npc$;
	mes "If you can finish my challenges and answer all my questions";
	mes "I will make you a genin and reward you with a special item";
	next;
	mes .npc$;
	mes "But of course its not for free";
	mes "The application fee for one try is ^FF0000" + .zeny + " z^000000.";
	next;
	mes .npc$;
	mes "Do you want to try answering my questions?";
	next;
		switch(select("Yes I Do!:No Thanks:Ignore Him")) {
			case 1:
				mes .npc$;
				mes "The Application Fee is ^FF0000" + .amount[0] + " z^000000";
				next;
					switch(select("Pay!:I will get the money first")) {
						case 1:
							if(Zeny < .zeny){
								mes .npc$;
								mes "Kid this is not enough!";
								mes "You need^FF0000 " + .zeny$ + " for the application fee^000000";
								close;
						} else {
								mes .npc$;
								set Zeny, Zeny - .zeny[0];
								mes "Okay, This is enough";
								set application,1; 
								next;
								mes .npc$;
								mes "I will think about your challenge";
								mes "come talk to me again in a bit";
								end;
								}
						case 2:
								mes .npc$;
								mes "Okay, come back to me anytime";
								close;
								}
			case 2:
				mes .npc$;
				mes "Are you sure kid?";
				mes "It's once in a lifetime offer";
				close;
			case 3:
				mes .npc$;
				mes "......";
				close;
				}
Challenge:
	set explanation,1;
	mes .npc$;
	mes "So for your challenge, I want you to get me a";
	mes "^00FF005"+ getitemname(.item[0]) +" "+.item_amount[0]+"^000000 ";
	close;

Challenge2:
	if(countitem(.item[0]) == .item_amount){
	mes .npc$;
	delitem .item[0],.item_amount[0]; 
	mes "Oh, I see you have collected all the items for the challenge";
	next;
	mes .npc$;
	mes "Give them to me";
	next;
	mes .npc$;
	mes "You may now take the quiz";
	mes "Talk to me anytime you're ready";
	set challenge,1;
	close;
	} else {
	mes .npc$;
	mes "So for your challenge, I want you to get me a";
	mes "^00FF005"+ getitemname(.item[0]) +" "+.item_amount[0]+"^000000 ";
	close;
	}

Quiz:
mes .npc$;
mes "Are you ready?";
next;
	switch(select("Yes!:No")) {
		case 1:
			mes .npc$;
			mes "Okay, let's start";
			goto Quiz02;
		case 2:
			mes .npc$;
			mes "Okay, whenever youre ready";
			close;
			}
Quiz02:
	set .@correct$, .answers[.@i];
	mes .npc$;
	mes "1st Question";
	mes ".questions[0]";
	input .@a1$;
	if (.@correct$ == .@a1$) {
	set score, +1; }
	end;
	next;
	mes .npc$;
	mes "2nd Question";
	mes ".questions[1]";
	input .@a2$;
	if (.@correct$ == .@a2$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "3rd Question";
	mes ".questions[2]";
	input .@a3$;
	if (.@correct$ == .@a3$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "4th Question";
	mes ".questions[3]";
	input .@a4$;
	if (.@correct$ == .@a4$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "5th Question";
	mes ".questions[4]";
	input .@a5$;
	if (.@correct$ == .@a5$) {
	set score, +1; }
	next;	
	mes .npc$;
	mes "6th Question";
	mes ".questions[5]";
	input .@a6$;
	if (.@correct$ == .@a6$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "7th Question";
	mes ".questions[6]";
	input .@a7$;
	if (.@correct$ == .@a7$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "8th Question";
	mes ".questions[7]";
	input .@a8$;
	if (.@correct$ == .@a8$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "9th Question";
	mes ".questions[8]";
	input .@a9$;
	if (.@correct$ == .@a9$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "10th Question";
	mes ".questions[9]";
	input .@a10$;
	if (.@correct$ == .@a10$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "The Quiz is done";
	mes "Let me check your answers";
	goto Checking;
	next;

Checking:
	if( score > 7 ){
	mes .npc$;
	mes "Congratulations you passed the quiz";
	set passed, 1;
	close;
	} else {
	mes .npc$;
	set score, 0;
	mes "You Failed the quiz";
	mes "Feel free to try again";
	close;
	}

Reward:
	mes .npc$;
	mes "Congratulations for passing my challenge";
	mes "As a promise here is your reward";
	mes "Select Carefully for your reward";
	next;
		.@menu_item_size = getarraysize(.@rewardname$);
		for (.@i = 0; .@i < .@menu_item_size; .@i++) {
		.@menu$ = .@menu$ + (.@i > 0 ? ":" : "") + .@rewardname$[.@i];
		}
		.@i = select( .@menu$ ) - 1;
		mes "You selected : "+ .@menu_item$[.@i];
		getitem .rewardid$[.@i],1;
		set reward,1;
		end;
		
		
Finish:
	mes .npc$;
	mes "Congratulations on finishing my challenge";
	mes "I hope you have a nice day";
	close;
	
OnInit:	
set .npc$ = "[ ^0000FFWise Ninja^000000 ]"
setarray .zeny, 5000000 //zeny 
setarray .item, 5160; // challenge item id
setarray .item_amount, 5;	//challenge item amount
setarray .questions, What is the special source of energy used by ninjas ?, What is the name of the special eye of the Uchiha clan ? , What is the name of the secret village of the country of Fire ? , What is the prefered jutsu of Naruto ?, How many villages are there in total ?, What is the name of the 'star looking' weapon of the ninjas ?, What is the name of the ultimate warrior/ninja in a particular village ?, What is the name of Kiba's dog ?, Who is the master of Naruto, Sasuke and Sakura ?, What is the name of the nine-tailed demon fox ?;
setarray .answers, Chakra, Sharingan, Konoha, Kage bunshin no jutsu, 10, Shuriken, Kage, Akamaru, Kakashi, Kurama;
setarray .@rewardname$, "Country of Fire", "Country of Wind", "Country of Water", "Country of Lightning", "Country of Earth", "Country of Sound";
setarray .rewardid$, 33001, 33002, 33003, 33004, 33005, 33006;
setarray .effect$, "+10 STR HP", "+10 AGI HP", "+10 INT HP", "+10 LUK HP", "+10 VIT HP", "+10 DEX HP";
.totalreward = 6;
end;
}

I check all Quiz2 and change them all to Quiz02

and here's the new error sir

crazyarashi · August 11, 2017

1 minute ago, skymia said:


prontera,145,173,4	script	Wise Ninja	637,{
	
if( !application ) {
	goto Intro; 
	}
	
	if( application == 1 ) {
	goto Challenge;
	}
	
	if ( application && explanation == 1) {
	goto Challenge2;
	}
	
	if ( application && explanation && challenge == 1){
	goto Quiz;
	}
	
	if ( application && explanation && challenge && passed == 1){
	goto Reward;
	}

	if ( application && explanation && challenge && passed && reward == 1){
	goto Finish;
	}
	
	

Intro:
	mes .npc$;
	mes "Hello, I am travelling shinobi. I am looking for a wise people";
	mes "who can answer all my questions";
	next;
	mes .npc$;
	mes "If you can finish my challenges and answer all my questions";
	mes "I will make you a genin and reward you with a special item";
	next;
	mes .npc$;
	mes "But of course its not for free";
	mes "The application fee for one try is ^FF0000" + .zeny + " z^000000.";
	next;
	mes .npc$;
	mes "Do you want to try answering my questions?";
	next;
		switch(select("Yes I Do!:No Thanks:Ignore Him")) {
			case 1:
				mes .npc$;
				mes "The Application Fee is ^FF0000" + .amount[0] + " z^000000";
				next;
					switch(select("Pay!:I will get the money first")) {
						case 1:
							if(Zeny < .zeny){
								mes .npc$;
								mes "Kid this is not enough!";
								mes "You need^FF0000 " + .zeny$ + " for the application fee^000000";
								close;
						} else {
								mes .npc$;
								set Zeny, Zeny - .zeny[0];
								mes "Okay, This is enough";
								set application,1; 
								next;
								mes .npc$;
								mes "I will think about your challenge";
								mes "come talk to me again in a bit";
								end;
								}
						case 2:
								mes .npc$;
								mes "Okay, come back to me anytime";
								close;
								}
			case 2:
				mes .npc$;
				mes "Are you sure kid?";
				mes "It's once in a lifetime offer";
				close;
			case 3:
				mes .npc$;
				mes "......";
				close;
				}
Challenge:
	set explanation,1;
	mes .npc$;
	mes "So for your challenge, I want you to get me a";
	mes "^00FF005"+ getitemname(.item[0]) +" "+.item_amount[0]+"^000000 ";
	close;

Challenge2:
	if(countitem(.item[0]) == .item_amount){
	mes .npc$;
	delitem .item[0],.item_amount[0]; 
	mes "Oh, I see you have collected all the items for the challenge";
	next;
	mes .npc$;
	mes "Give them to me";
	next;
	mes .npc$;
	mes "You may now take the quiz";
	mes "Talk to me anytime you're ready";
	set challenge,1;
	close;
	} else {
	mes .npc$;
	mes "So for your challenge, I want you to get me a";
	mes "^00FF005"+ getitemname(.item[0]) +" "+.item_amount[0]+"^000000 ";
	close;
	}

Quiz:
mes .npc$;
mes "Are you ready?";
next;
	switch(select("Yes!:No")) {
		case 1:
			mes .npc$;
			mes "Okay, let's start";
			goto Quiz02;
		case 2:
			mes .npc$;
			mes "Okay, whenever youre ready";
			close;
			}
Quiz02:
	set .@correct$, .answers[.@i];
	mes .npc$;
	mes "1st Question";
	mes ".questions[0]";
	input .@a1$;
	if (.@correct$ == .@a1$) {
	set score, +1; }
	end;
	next;
	mes .npc$;
	mes "2nd Question";
	mes ".questions[1]";
	input .@a2$;
	if (.@correct$ == .@a2$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "3rd Question";
	mes ".questions[2]";
	input .@a3$;
	if (.@correct$ == .@a3$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "4th Question";
	mes ".questions[3]";
	input .@a4$;
	if (.@correct$ == .@a4$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "5th Question";
	mes ".questions[4]";
	input .@a5$;
	if (.@correct$ == .@a5$) {
	set score, +1; }
	next;	
	mes .npc$;
	mes "6th Question";
	mes ".questions[5]";
	input .@a6$;
	if (.@correct$ == .@a6$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "7th Question";
	mes ".questions[6]";
	input .@a7$;
	if (.@correct$ == .@a7$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "8th Question";
	mes ".questions[7]";
	input .@a8$;
	if (.@correct$ == .@a8$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "9th Question";
	mes ".questions[8]";
	input .@a9$;
	if (.@correct$ == .@a9$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "10th Question";
	mes ".questions[9]";
	input .@a10$;
	if (.@correct$ == .@a10$) {
	set score, +1; }
	next;
	mes .npc$;
	mes "The Quiz is done";
	mes "Let me check your answers";
	goto Checking;
	next;

Checking:
	if( score > 7 ){
	mes .npc$;
	mes "Congratulations you passed the quiz";
	set passed, 1;
	close;
	} else {
	mes .npc$;
	set score, 0;
	mes "You Failed the quiz";
	mes "Feel free to try again";
	close;
	}

Reward:
	mes .npc$;
	mes "Congratulations for passing my challenge";
	mes "As a promise here is your reward";
	mes "Select Carefully for your reward";
	next;
		.@menu_item_size = getarraysize(.@rewardname$);
		for (.@i = 0; .@i < .@menu_item_size; .@i++) {
		.@menu$ = .@menu$ + (.@i > 0 ? ":" : "") + .@rewardname$[.@i];
		}
		.@i = select( .@menu$ ) - 1;
		mes "You selected : "+ .@menu_item$[.@i];
		getitem .rewardid$[.@i],1;
		set reward,1;
		end;
		
		
Finish:
	mes .npc$;
	mes "Congratulations on finishing my challenge";
	mes "I hope you have a nice day";
	close;
	
OnInit:	
set .npc$ = "[ ^0000FFWise Ninja^000000 ]"
setarray .zeny, 5000000 //zeny 
setarray .item, 5160; // challenge item id
setarray .item_amount, 5;	//challenge item amount
setarray .questions, What is the special source of energy used by ninjas ?, What is the name of the special eye of the Uchiha clan ? , What is the name of the secret village of the country of Fire ? , What is the prefered jutsu of Naruto ?, How many villages are there in total ?, What is the name of the 'star looking' weapon of the ninjas ?, What is the name of the ultimate warrior/ninja in a particular village ?, What is the name of Kiba's dog ?, Who is the master of Naruto, Sasuke and Sakura ?, What is the name of the nine-tailed demon fox ?;
setarray .answers, Chakra, Sharingan, Konoha, Kage bunshin no jutsu, 10, Shuriken, Kage, Akamaru, Kakashi, Kurama;
setarray .@rewardname$, "Country of Fire", "Country of Wind", "Country of Water", "Country of Lightning", "Country of Earth", "Country of Sound";
setarray .rewardid$, 33001, 33002, 33003, 33004, 33005, 33006;
setarray .effect$, "+10 STR HP", "+10 AGI HP", "+10 INT HP", "+10 LUK HP", "+10 VIT HP", "+10 DEX HP";
.totalreward = 6;
end;
}

I check all Quiz2 and change them all to Quiz02

and here's the new error sir

I will up a test server and test it :))

skymia · August 11, 2017

30 minutes ago, crazyarashi said:

I will up a test server and test it :))

ok master..thanks hehe

Z3R0 · August 11, 2017

I wanna take on this challenge tonight possibly. So we will see who wins haha

skymia · August 11, 2017

21 minutes ago, Z3R0 said:

I wanna take on this challenge tonight possibly. So we will see who wins haha

haha good luck master

skymia · August 11, 2017

7 hours ago, Z3R0 said:

Little rough, I'm tired... but it works enjoy


//===== Script =========================================================================
//= Quizzer
//===== Made by: =======================================================================
//= Z3R0
//===== Current Version: ===============================================================
//= Version: 1.0
//===== Description: ===================================================================
//= rAthena Script Request
//= https://rathena.org/board/topic/112260-quest-npc-w-question-answer
//===== Additional Comments: ===========================================================
//= version 1.0: Initial Attempt
//======================================================================================

prontera,158,173,4	script	Quizzer	92,{ doevent "quizzer_core::OnClick"; }

-	script	quizzer_core	-1,{

	// Function Declarations
	function MesItem;
	function ChkItem;
	function ChkAnswer;

	OnInit:

		// ---------------------------------
		// Configurable Settings
		// ---------------------------------

			// NPC Name to Display
			set(.npc$, "[Quizzer]");

			// Fee to Pay to Begin Quiz
			set(.fee, 5000000);

			// Show # of Question Player is On and Total number of questions?
			set(.ShowQuestionProgress, 1);

			// Number of Answers to Pass Quiz
			set(.NumRightToPass, 8);

			// Required Items Array (Pair: Item_ID, Item_Amount)
			setarray(.required_items[0], 2256, 5); // Here you can setup multiple items in pairs.. (item_id, amount)

			// Array of Questions (Each question must have a corresponding answer)
			setarray(.questions$[0],
				"What is the special source of energy used by ninjas ?",
				"What is the name of the special eye of the Uchiha clan ?",
				"What is the name of the secret village of the country of Fire ?",
				"What is the prefered jutsu of Naruto ?",
				"How many villages are there in total ?",
				"What is the name of the 'star looking' weapon of the ninjas ?",
				"What is the name of the ultimate warrior/ninja in a particular village ?",
				"What is the name of Kiba's dog ?",
				"Who is the master of Naruto, Sasuke and Sakura ?",
				"What is the name of the nine-tailed demon fox ?"
			);

			// Array of Answers (Each Answer must have a corresponding Question)
			setarray(.answers$[0],
				"Chakra",
				"Sharingan",
				"Konoha",
				"Kage bunshin no jutsu",
				"10",
				"Shuriken",
				"Kage",
				"Akamaru",
				"Kakashi",
				"Kurama"
			);

			// Array of Reward Item ID's
			setarray(.rewards[0], 501, 502, 503, 504, 505, 506);
			setarray(.rewards_effects$[0], "+10 STR HP", "+10 AGI HP", "+10 INT HP", "+10 LUK HP", "+10 VIT HP", "+10 DEX HP");

			// STOP!!! DO NOT EDIT BELOW THIS LINE UNLESS YOU KNOW WHAT YOU ARE DOING!!!!
			// check .ShowQuestionProgress
			if (.ShowQuestionProgress > 1) set(.ShowQuestionProgress, 1);

			// Check .required_items
			if (getarraysize(.required_items) % 2 != 0) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Items in .required_items", bc_all, C_YELLOW); end();
			}

			if (getarraysize(.questions$) != getarraysize(.answers$)) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Questions to Answers", bc_all, C_YELLOW); end();
			}

			if (getarraysize(.rewards) != getarraysize(.rewards_effects$)) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Rewards to Reward Effects", bc_all, C_YELLOW); end();
			}

			set(.error, 0);
			end();



	// Player clicks the initial NPC
	OnClick:
		if (.error) {
			mes("There was an error loading this script. Please contact your server administrator");
			close();
		}

		if (quizzer & 8) {
			mes("You have already completed this trial.");
			close();
		}
		else if (quizzer & 4) doevent("quizzer_core::OnComplete");
		else if (quizzer & 2) doevent("quizzer_core::OnQuiz");
		else if (quizzer & 1) doevent("quizzer_core::OnHunt");
		else doevent("quizzer_core::OnStart");
		end();

	OnStart:
		mes(.npc$);

		if (.fee) {
			mes("You will need " + .fee + " zeny to start this trial.");
			mes("Are you ready to proceed?");
			next();
			switch(select("Yes:No")) {
				case 1:

					if (Zeny < .fee) {
						mes("You do not have enough zeny to start this trial.");
						close();
					}

					set(Zeny, Zeny - .fee);
					set(quizzer, 1);

					mes("I need you to gather these items:");
					for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
						mes( MesItem(.required_items, .@i) );
					}
					mes("I await your return");
					close();

				case 2:
				default:
					mes("I knew you weren't capable!");
					close();
			}
		}

	OnHunt:
		mes(.npc$);

		// Determine if they have completed all the required items...
		mes("Checking Requirement Status:");
		for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
			mes(MesItem(.required_items, .@i) + " - " + ChkItem(.required_items[.@i], .required_items[.@i+1]));
		}

		if (@quizzer_no_items == 1) {
			mes("You do not have enough items... You fail!");
			set(@quizzer_no_items, 0);
			close();
		}

		// Passed let's remove the items
		for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
			delitem .required_items[.@i], .required_items[.@i+1];
		}

		mes("Success! You may now start the quiz!");
		next();
		set(quizzer, quizzer^2);
		doevent("quizzer_core::OnQuiz");
		end();

	OnQuiz:
		mes(.npc$);

		.@num_right = 0;

		for(.@i = 0; .@i < getarraysize(.questions$); .@i++) {

			if (.ShowQuestionProgress) {
				mes("Question #" + (.@i+1) + " / " + getarraysize(.questions$));
			}

			mes(.questions$[.@i]);
			input .player_answers$[.@i];

			// Let's compare the answer :D
			.@num_right += ChkAnswer(.answers$[.@i], .player_answers$[.@i]);

			mes("Answer Recorded. Next Question");
			next();

		}

		if (.@num_right >= .NumRightToPass) {
			set(quizzer, quizzer^4);
			mes("You have passed the quiz!");
			next();
			doevent("quizzer_core::OnComplete");
			end();
		}

		mes("You did not pass the quiz!");
		close();

	OnComplete:
		mes(.npc$);
		mes("Well Done Old Chap!");
		mes("Please select from the following rewards");

		set(.@menu$, "");
		for(.@i = 0; .@i < getarraysize(.rewards); .@i++) {
			set(.@menu$, .@menu$ + getitemname(.rewards[.@i]) + " (" + .rewards_effects$[.@i] + "):");
		}

		getitem .rewards[select(.@menu$) - 1], 1;
		set(quizzer, quizzer^8);

		mes("Thank you for participating");
		close();

	// getarg(0) = Array
	// getarg(1) = Index
	function MesItem {
		.@item_id = getelementofarray(getarg(0), getarg(1));
		.@item_amount = getelementofarray(getarg(0), getarg(1) + 1);

		return .@item_amount + ( .@item_amount > 1 ? "x" : "") + " " + getitemname(.@item_id);
	}

	// getarg(0) = item_id
	// getarg(1) = amount required
	function ChkItem {
		.@has = countitem(getarg(0));

		if (.@has >= getarg(1)) {
			return "^000000" + .@has + "^000000/^000000" + getarg(1) + "^000000";
		}

		set(@quizzer_no_items, 1);
		return "^FF0000" + .@has + "^000000/^000000" + getarg(1) + "^000000";
	}

	// getarg(0) = Answer
	// getarg(1) = Player Answer
	function ChkAnswer {
		if (getarg(0) == getarg(1)) return 1;
		else if (strtoupper(getarg(0)) == getarg(1)) return 1;
		else if (strtolower(getarg(0)) == getarg(1)) return 1;
		else return 0;
	}


}

Nice master you did it. thanks a lot

thanks also to

crazyarashi

skymia · August 13, 2017

On 8/11/2017 at 1:43 PM, Z3R0 said:

Little rough, I'm tired... but it works enjoy


//===== Script =========================================================================
//= Quizzer
//===== Made by: =======================================================================
//= Z3R0
//===== Current Version: ===============================================================
//= Version: 1.0
//===== Description: ===================================================================
//= rAthena Script Request
//= https://rathena.org/board/topic/112260-quest-npc-w-question-answer
//===== Additional Comments: ===========================================================
//= version 1.0: Initial Attempt
//======================================================================================

prontera,158,173,4	script	Quizzer	92,{ doevent "quizzer_core::OnClick"; }

-	script	quizzer_core	-1,{

	// Function Declarations
	function MesItem;
	function ChkItem;
	function ChkAnswer;

	OnInit:

		// ---------------------------------
		// Configurable Settings
		// ---------------------------------

			// NPC Name to Display
			set(.npc$, "[Quizzer]");

			// Fee to Pay to Begin Quiz
			set(.fee, 5000000);

			// Show # of Question Player is On and Total number of questions?
			set(.ShowQuestionProgress, 1);

			// Number of Answers to Pass Quiz
			set(.NumRightToPass, 8);

			// Required Items Array (Pair: Item_ID, Item_Amount)
			setarray(.required_items[0], 2256, 5); // Here you can setup multiple items in pairs.. (item_id, amount)

			// Array of Questions (Each question must have a corresponding answer)
			setarray(.questions$[0],
				"What is the special source of energy used by ninjas ?",
				"What is the name of the special eye of the Uchiha clan ?",
				"What is the name of the secret village of the country of Fire ?",
				"What is the prefered jutsu of Naruto ?",
				"How many villages are there in total ?",
				"What is the name of the 'star looking' weapon of the ninjas ?",
				"What is the name of the ultimate warrior/ninja in a particular village ?",
				"What is the name of Kiba's dog ?",
				"Who is the master of Naruto, Sasuke and Sakura ?",
				"What is the name of the nine-tailed demon fox ?"
			);

			// Array of Answers (Each Answer must have a corresponding Question)
			setarray(.answers$[0],
				"Chakra",
				"Sharingan",
				"Konoha",
				"Kage bunshin no jutsu",
				"10",
				"Shuriken",
				"Kage",
				"Akamaru",
				"Kakashi",
				"Kurama"
			);

			// Array of Reward Item ID's
			setarray(.rewards[0], 501, 502, 503, 504, 505, 506);
			setarray(.rewards_effects$[0], "+10 STR HP", "+10 AGI HP", "+10 INT HP", "+10 LUK HP", "+10 VIT HP", "+10 DEX HP");

			// STOP!!! DO NOT EDIT BELOW THIS LINE UNLESS YOU KNOW WHAT YOU ARE DOING!!!!
			// check .ShowQuestionProgress
			if (.ShowQuestionProgress > 1) set(.ShowQuestionProgress, 1);

			// Check .required_items
			if (getarraysize(.required_items) % 2 != 0) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Items in .required_items", bc_all, C_YELLOW); end();
			}

			if (getarraysize(.questions$) != getarraysize(.answers$)) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Questions to Answers", bc_all, C_YELLOW); end();
			}

			if (getarraysize(.rewards) != getarraysize(.rewards_effects$)) {
				set(.error, 1);
				announce(strnpcinfo(0) + ": [ERROR] Invalid Number of Rewards to Reward Effects", bc_all, C_YELLOW); end();
			}

			set(.error, 0);
			end();



	// Player clicks the initial NPC
	OnClick:
		if (.error) {
			mes("There was an error loading this script. Please contact your server administrator");
			close();
		}

		if (quizzer & 8) {
			mes("You have already completed this trial.");
			close();
		}
		else if (quizzer & 4) doevent("quizzer_core::OnComplete");
		else if (quizzer & 2) doevent("quizzer_core::OnQuiz");
		else if (quizzer & 1) doevent("quizzer_core::OnHunt");
		else doevent("quizzer_core::OnStart");
		end();

	OnStart:
		mes(.npc$);

		if (.fee) {
			mes("You will need " + .fee + " zeny to start this trial.");
			mes("Are you ready to proceed?");
			next();
			switch(select("Yes:No")) {
				case 1:

					if (Zeny < .fee) {
						mes("You do not have enough zeny to start this trial.");
						close();
					}

					set(Zeny, Zeny - .fee);
					set(quizzer, 1);

					mes("I need you to gather these items:");
					for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
						mes( MesItem(.required_items, .@i) );
					}
					mes("I await your return");
					close();

				case 2:
				default:
					mes("I knew you weren't capable!");
					close();
			}
		}

	OnHunt:
		mes(.npc$);

		// Determine if they have completed all the required items...
		mes("Checking Requirement Status:");
		for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
			mes(MesItem(.required_items, .@i) + " - " + ChkItem(.required_items[.@i], .required_items[.@i+1]));
		}

		if (@quizzer_no_items == 1) {
			mes("You do not have enough items... You fail!");
			set(@quizzer_no_items, 0);
			close();
		}

		// Passed let's remove the items
		for(.@i = 0; .@i < getarraysize(.required_items); .@i+=2) {
			delitem .required_items[.@i], .required_items[.@i+1];
		}

		mes("Success! You may now start the quiz!");
		next();
		set(quizzer, quizzer^2);
		doevent("quizzer_core::OnQuiz");
		end();

	OnQuiz:
		mes(.npc$);

		.@num_right = 0;

		for(.@i = 0; .@i < getarraysize(.questions$); .@i++) {

			if (.ShowQuestionProgress) {
				mes("Question #" + (.@i+1) + " / " + getarraysize(.questions$));
			}

			mes(.questions$[.@i]);
			input .player_answers$[.@i];

			// Let's compare the answer :D
			.@num_right += ChkAnswer(.answers$[.@i], .player_answers$[.@i]);

			mes("Answer Recorded. Next Question");
			next();

		}

		if (.@num_right >= .NumRightToPass) {
			set(quizzer, quizzer^4);
			mes("You have passed the quiz!");
			next();
			doevent("quizzer_core::OnComplete");
			end();
		}

		mes("You did not pass the quiz!");
		close();

	OnComplete:
		mes(.npc$);
		mes("Well Done Old Chap!");
		mes("Please select from the following rewards");

		set(.@menu$, "");
		for(.@i = 0; .@i < getarraysize(.rewards); .@i++) {
			set(.@menu$, .@menu$ + getitemname(.rewards[.@i]) + " (" + .rewards_effects$[.@i] + "):");
		}

		getitem .rewards[select(.@menu$) - 1], 1;
		set(quizzer, quizzer^8);

		mes("Thank you for participating");
		close();

	// getarg(0) = Array
	// getarg(1) = Index
	function MesItem {
		.@item_id = getelementofarray(getarg(0), getarg(1));
		.@item_amount = getelementofarray(getarg(0), getarg(1) + 1);

		return .@item_amount + ( .@item_amount > 1 ? "x" : "") + " " + getitemname(.@item_id);
	}

	// getarg(0) = item_id
	// getarg(1) = amount required
	function ChkItem {
		.@has = countitem(getarg(0));

		if (.@has >= getarg(1)) {
			return "^000000" + .@has + "^000000/^000000" + getarg(1) + "^000000";
		}

		set(@quizzer_no_items, 1);
		return "^FF0000" + .@has + "^000000/^000000" + getarg(1) + "^000000";
	}

	// getarg(0) = Answer
	// getarg(1) = Player Answer
	function ChkAnswer {
		if (getarg(0) == getarg(1)) return 1;
		else if (strtoupper(getarg(0)) == getarg(1)) return 1;
		else if (strtolower(getarg(0)) == getarg(1)) return 1;
		else return 0;
	}


}

how can i make multiple item in one character? because this script is 1 item per character only sir

Z3R0 · August 13, 2017

Why would u want it multiple times? Once they do it right they shouldn't choose a different one?

You want it to be repeatable?

Sign In

Quest NPC w/ Question & Answer

Question

Link to comment

Share on other sites

30 answers to this question

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Join the conversation

Recently Browsing 0 members