Can i Request a script that allows a gm to check ip

[Caves]

@ipcheck - displays all the characters related to an IP address

@getip - gets the ip of the player / account

[Ridley]

edit: removed, didn't notice this is rA

Edited September 1, 2014 by Ridley

[Capuche]

my version

@checkip

-	script	jkbddkk	-1,{
OnInit:
	bindatcmd "checkip", strnpcinfo(3) +"::Oncheckip",99,99;
	end;
Oncheckip:
	.@myname$ = strcharinfo(0);
	if ( .@atcmd_numparameters == 0 ) {
		message .@myname$, "usage : "+ .@atcmd_command$ +" <ip>";
		end;
	}
	.@count = countstr( .@atcmd_parameters$[0], "." );
	explode( .@atcmd_parameters$[0], .@tmp$, "." );
	for ( .@i = 0; .@i < .@count; .@i++ )
		if ( .@tmp$[.@i] != "0" && .@tmp$[.@i] != "%" && ( atoi(.@tmp$[.@i]) <= 0 || atoi(.@tmp$[.@i]) > 255 ) ) break;
	if ( .@i < .@count || .@count != 3 ) {
		message .@myname$, "wrong ip";
		end;
	}
	.@amount = query_sql( "select name, last_ip from `char` join login on `char`.account_id = login.account_id WHERE online = 1 and last_ip LIKE '"+ .@atcmd_parameters$[0] +"' order by name desc limit 128", .@name$, .@last_ip$ );
	if ( .@amount <= 0 ) {
		message .@myname$, "none player found";
		end;
	}
	message .@myname$, "player online with this ip :";
	for ( .@i = 0; .@i < .@amount; .@i++ )
		message .@myname$, .@name$[.@i] +" : "+ .@last_ip$[.@i];	
	end;
}

@getip, what about @accinfo?

 

Edit: fixed a typo

[Emistry]

if not mistaken, @accinfo allow you to view the IP addresses of player too.