check party if all the member and leader has the TCG?

[caspa]

how to script that when you click and npc it will check all users in the party and when the npc confirms they all have the tcg i will party warp them to the specific dungeon and the npc will delete all the item in the players inventory......

[Capuche]

try do like this ?

http://pastebin.com/raw.php?i=FHrz3WNv

Editing

prontera,150,160,5	script	ghjkl	456,{

.@itemid = 7227;
.@amount = 10;
.@event_map$ = "prontera";
.@aid = getcharid(3);

if( !getcharid(1) ) {
	mes "You are not in a party.";
	close;
}

getpartymember getcharid(1),0;
getpartymember getcharid(1),1;
getpartymember getcharid(1),2;

while( .@i < $@partymembercount ){
	if( isloggedin( $@partymemberaid[.@i], $@partymembercid[.@i] ) ) {
		attachrid( $@partymemberaid[ .@i ] );
		if( countitem( .@itemid ) < .@amount ){
			attachrid( .@aid );
			mes "Your member "+$@partymembername$[.@i]+" haven't "+.@amount+" "+getitemname( .@itemid )+".";
			close;
		}
		.@log_in[ getarraysize( .@log_in ) ] = $@partymemberaid[ .@i ];
	}
	.@i++;
}

for( .@i = 0; .@i < getarraysize( .@log_in ); .@i++ )
	delitem .@itemid, .@amount, .@log_in[ .@i ];

attachrid( .@aid );
dispbottom "All got items.";

warpparty .@event_map$, 150,150, getcharid(1);
close;
}

Edited January 19, 2013 by Capuche

[Emistry]

try do like this ?

http://pastebin.com/raw.php?i=FHrz3WNv

[caspa]

solved....... thank you