question

[Mootie]

to edit the respawn of the mvp will be in npc>pre-re>mobs?

i already read this http://rathena.org/wiki/Permanent_Monster_Spawn

[Mystery]

to edit the respawn of the mvp will be in npc>pre-re>mobs?

i already read this http://rathena.org/w...t_Monster_Spawn

Editing spawns will always be in the mobs section, pre-re or re. For MvPs, they are labeled with boss_monster in their designated files. For example, Garm. Garm is found in .../mobs/fields/lutie.txt:

//==================================================
// xmas_fild01 - Lutie Field
//==================================================
xmas_fild01,0,0,0,0	monster	Marin	1242,35,0,0,0
xmas_fild01,0,0,0,0	monster	Sasquatch	1243,20,0,0,0
xmas_fild01,0,0,0,0	monster	Garm Baby	1515,1,1800000,0,0
xmas_fild01,0,0,0,0	boss_monster	Garm	1252,1,7200000,600000,1

As you can see, Garm is the last line and according to the time, he'll be spawning in about 2 hours after death. Following the Wiki link you provided, you can get a better understanding.

However, keep in mind not MvP spawns are similar, especially LHZ Dungeon because the MvP in LHZ Dungeon is set in a script function:

lhz_dun03,2,2,0	script	summon_boss_lt	-1,{
OnInit:
initnpctimer;
end;

OnTimer6000000:
if (rand(1,6) == 1) {
	donpcevent "summon_boss_lt::Onsummon";
	stopnpctimer;
}
end;

OnTimer6300000:
if (rand(1,6) == 2) {
	donpcevent "summon_boss_lt::Onsummon";
	stopnpctimer;
}
end;

OnTimer6600000:
if (rand(1,6) == 3) {
	donpcevent "summon_boss_lt::Onsummon";
	stopnpctimer;
}
end;

OnTimer6900000:
if (rand(1,6) == 4) {
	donpcevent "summon_boss_lt::Onsummon";
	stopnpctimer;
}
end;

OnTimer7200000:
if (rand(1,6) == 5) {
	donpcevent "summon_boss_lt::Onsummon";
	stopnpctimer;
}
end;

OnTimer7500000:
if (rand(1,6) == 6) {
	donpcevent "summon_boss_lt::Onsummon";
	stopnpctimer;
}
end;

OnTimer7800000:
donpcevent "summon_boss_lt::Onsummon";
stopnpctimer;
end;

Onsummon:
// Select Coordinates to summon a random MVP on
switch(rand(1,6)) {
case 1: set .@x,140;	set .@y,232;	break;
case 2: set .@x,75;	set .@y,138;	break;
case 3: set .@x,140;	set .@y,87;		break;
case 4: set .@x,205;	set .@y,140;	break;
case 5: set .@x,123;	set .@y,137;	break;
case 6: set .@x,175;	set .@y,137;	break;
}
set .@mob,rand(1646,1651);
monster "lhz_dun03",.@x,.@y,strmobinfo(1,.@mob),.@mob,1,"summon_boss_lt::OnMyMvPDead";

// Select Coordinates to summon a random 99 on
switch(rand(1,6)) {
case 1: set .@x2,183;	set .@y2,97;	break;
case 2: set .@x2,97;	set .@y2,96;	break;
case 3: set .@x2,47;	set .@y2,139;	break;
case 4: set .@x2,231;	set .@y2,140;	break;
case 5: set .@x2,139;	set .@y2,211;	break;
case 6: set .@x2,139;	set .@y2,259;	break;
}
set .@mob2,rand(1640,1645);
monster "lhz_dun03",.@x2,.@y2,strmobinfo(1,.@mob2),.@mob2,1,"summon_boss_lt::OnMVP";
end;

OnMyMvPDead:
killmonster "lhz_dun03","summon_boss_lt::OnMVP";
initnpctimer;
end;

//Required to keep from erroring
OnMVP:
end;

[Emistry]

depend on you are using RE or PRE-RE

if RE then..

https://rathena.svn.sourceforge.net/svnroot/rathena/trunk/npc/re/

if PRE-RE then...

https://rathena.svn.sourceforge.net/svnroot/rathena/trunk/npc/pre-re/

[Mootie]

thank you for the respawn if i set like this thana_boss,0,0,0,35 so it will be random spawn right?

[Mystery]

Changing the time value to 0 will make it respawn instantly.

[Mootie]

uhh what i mean is the coordinates o.o

[Mystery]

uhh what i mean is the coordinates o.o

LOL sorry.. fail moment. Had to read it over :< Yes, changing it to 0,0 will make it spawn in a random location xd