Valor Badges to Cash Point =)

[Aya]

can someone make me an npc where in valor badges (or any other BG Badges) will be exchange to cash points?

Thank you!

[Euphy]

prontera,155,177,6    script    Badge Exchange    725,{
   mes "[badge Exchange]";
   mes "I can exchange your badges for Cash Points.";
   mes "Which would you like to exchange?";
   next;
   set .@i, select(.Menu$)-1;
   mes "[badge Exchange]";
   setarray .@j, .Items[.@i*2], .Items[.@i*2+1], countitem(.Items[.@i*2]);
   if (.@j[2]) {
       mes "You have "+.@j[2]+"x "+getitemname(.@j[0])+".";
       mes "They are worth "+.@j[1]+" Cash Points each.";
       mes "How many would you like to exchange?";
       next;
       input .@k,0,.@j[2];
       mes "[badge Exchange]";
       if (.@k) {
           delitem .@j[0],.@k;
           set #CASHPOINTS, #CASHPOINTS+(.@k*.@j[1]);
           mes "Traded "+.@k+"x "+getitemname(.@j[0])+".";
           dispbottom "Total Cash Points: "+#CASHPOINTS;
       }
       else mes "Okay, come back later.";
       close;
   }
   mes "You don't have any "+getitemname(.@j[0])+".";
   close;

OnInit:
   // Format: ItemID,Points,ItemID2,Points2,...
   setarray .Items[0],7829,1,7828,1;
   set .Menu$,"";
   for(set .@i,0; .@i<getarraysize(.Items); set .@i,.@i+2)
       set .Menu$, .Menu$+getitemname(.Items[.@i])+":";
   end;
}

uPaste: http://upaste.me/raw/c91613307a10fb12

[Aya]

Thanks Euphy! =) I'll try it ;D

Sir Euphy it works perfectly but this is not what I want. Im sorry I didn't specify. Cash Point in my server is an item. My players can use this to obtain items. =) It's like I made an NPC where people can exchange Cash Points. Sorry ..

can you make me a script like this? Thank you! =) btw the ID of Cashpoint is 30000 =)

[Emistry]

change

set #CASHPOINTS, #CASHPOINTS+(.@k*.@j[1]);

to

getitem 30000,(.@k*.@j[1]);

[Aya]

Worked perfectly, thanks Emistry and Euphy =)