Castle Drop Exchanger

[Patskie]

Hello can anyone make me a npc script which trades any castle drop to another castle drop. for example, billow can be trade to ripple or even vice versa. when exchanging castle drops i want the script to be payed (zeny) before the process of exchanging. And also can anyone make me a hokage collector, which trades hokage hat to hokage sunglasses or even vice versa, Thank you to whoever will make me one. !! ) More power rAthena!

[AnnieRuru]

this script can only be written using advance scripting techniques

prontera,155,186,5    script    kjdhfksjfhs    100,{
   mes "require "+ .req_zeny +" zeny";
   next;
   if ( zeny < .req_zeny ) {
       mes "you don't have enough zeny";
       close;
   }
   getinventorylist;
   for ( .@i = 0; .@i < @inventorylist_count; .@i++ ) {
       if ( compare( .itemidcompare$, ":"+ @inventorylist_id[.@i] +":" ) ) {
           .@menu$ = .@menu$ + getitemname( @inventorylist_id[.@i] ) +":";
           .@select[ .@c ] = @inventorylist_id[.@i];
           .@c++;
       }
   }
   if ( .@c == 0 ) {
       mes "you don't have require headgear in your inventory";
       close;
   }
   .@pickid = .@select[ select( .@menu$ ) -1 ];
   mes "picked : "+ getitemname( .@pickid );
   next;
   .@menu$ = getitemname( .itemid );
   for ( .@i = 1; .@i < .itemidsize; .@i++ )
       .@menu$ = .@menu$ +":"+ getitemname( .itemid[.@i] );
   .@buyid = .itemid[ select( .@menu$ ) -1 ];
   mes "are you sure you want to spend "+ .req_zeny +" zeny";
   mes "trade "+ getitemname( .@pickid ) +" into "+ getitemname( .@buyid ) +"?";
   next;
   if ( select ( "Yes", "No" ) == 2 ) close;
   if ( countitem( .@pickid ) == 0 || zeny < .req_zeny ) {
       mes "don't cheat by sending mail away !";
       close;
   }
   delitem .@pickid, 1;
   getitem .@buyid, 1;
   zeny = zeny - .req_zeny;
   mes "traded successfully";
   close;
OnInit:
   .req_zeny = 10000; // zeny requirement
   setarray .itemid, 5001, 5002, 5003, 5004, 5005, 5006; // put all your headgear in this list

   set .itemidsize, getarraysize( .itemid );
   set .itemidcompare$, ":"+ .itemid[0];
   for ( .@i = 1; .@i < .itemidsize; .@i++ )
       .itemidcompare$ = .itemidcompare$ +":"+ .itemid[.@i] +":";
   end;
}

EDIT: search key word = item exchanger

Edited October 21, 2012 by AnnieRuru

[goddameit]

so owner can sell or drop their castle?

Edited October 17, 2012 by goddameit

[Patskie]

They can't sell. They can exchange their castle drops to another castle drops. but before the exchange process. the npc must be payed (zeny)

For example : i have billow here. Then i want to exchange it to ripple. I can use the npc and exchange my billow to ripple but i must pay for example 50 million zeny for it to be exchanged. Sorry for my bad english