Npc card collector

[kronobr]

Hello everyone, I would like a card collector's npc, where the player needs to have certain cards in your inventory like an sticker album, for example, from card 4001 to 4100 or cards of my choice. And he exchanges all these cards for some item as a prize. This Mission can be done weekly by the same account.

It is not the same thing as the npc Card Trader that we have available.

Thank you! 

Edited August 21, 2020 by kronobr

[buraquera]

alberta,220,42,3	script	CardTrader	60,{
	getinventorylist;
	for(.@i = 0 ; .@i < getarraysize(.cards); .@i++){
		for(.@j = 0; .@j < @inventorylist_count; .@j++){
			if (.cards[.@i] == @inventorylist_id[.@j]){
				.@count++;
				break;
			}
		}
		if (.@count <= .@i){
			mes "[Card Trader]","Sorry you don't have all cards...";
			close;
		}
	}
	mes "[Card Trader]","Congratz you have all cards.";
	for (.@i = 0 ; .@i < getarraysize(.prize); .@i += 2)
		getitem .prize[.@i],.prize[.@i+1];
	for(.@i = 0 ; .@i < getarraysize(.cards); .@i++)
		delitem .cards[.@i],1;
	close;
OnInit:
	setarray .cards,4001,4002,4003,4004;				// Card ID list
	setarray .prize,909,3,901,5;						// <ITEM ID><AMOUNT>{<ITEM ID><AMOUNT>....}
}

 

[Emistry]

a slightly more optimized version...

alberta,220,42,3	script	CardTrader	60,{
	mes "Exchange Cards:";
	for (.@i = 0; .@i < .cards_size; .@i++) {
		mes "~ "+getitemname(.cards[.@i]);
		if (!countitem(.cards[.@i])
			.@fail++;
	}
	if (!.@fail) {
		next;
		mes "[Card Trader]","Congratz you have all cards.";
		for (.@i = 0; .@i < .cards_size; .@i++)
			delitem .cards[.@i], 1;
		mes "You gained:";
		for (.@i = 0 ; .@i < .price_size; .@i += 2) {
			mes "~ "+.prize[.@i+1]+"x "+getitemname(.prize[.@i]);
			getitem .prize[.@i],.prize[.@i+1];
		}
	}
	close;
	
OnInit:
	setarray .cards,4001,4002,4003,4004;				// Card ID list
	setarray .prize,909,3,901,5;						// <ITEM ID><AMOUNT>{<ITEM ID><AMOUNT>....}
	
	.cards_size = getarraysize(.cards);
	.price_size = getarraysize(.prize);
	end;
}