How to make this account based?

[Venture]

This is a script I got from the scripting forum.

-    script    login_reward    -1,{
OnPCLoginEvent:
    .@pow = 1 << 10;
    .@todays = gettime(8);
    if ( login_reward % .@pow == .@todays ) end;
    .@count += .reward_day;// reward of the day
    login_reward = ( login_reward &~ ( login_reward % .@pow ) ) + .@todays +

.@pow;// update day and count day +1 ; day/count day/check week/check month
    if ( login_reward != .@todays + .@pow ) {// login_reward was not empty
        .@count_day = ( login_reward >> 10 ) % .@pow;
        .@cond_ofthemonth = ( ( login_reward >> 30 ) % .@pow ) != (

.@count_day / 31 );
        if ( ( ( login_reward >> 20 ) % .@pow ) != ( .@count_day / 7 ) ) {
            .@count += .reward_week;
            login_reward = login_reward + pow( 2,20 );
            .@weekly_message$ = ( .@cond_ofthemonth ? ", " : " and " ) +

.reward_week +" Red Envelopes for being online a week";
        }
        if ( .@cond_ofthemonth ) {
            .@count += .reward_month;
            login_reward = login_reward + pow( 2,30 );
            .@montly_message$ = " and " + .reward_month +" Red Envelopes

for being online a month";
        }
    }
    getitem 12134, .@count;
    dispbottom "Here your daily reward ! You got "+ .reward_day +" Red

Envelopes"+ .@weekly_message$ + .@montly_message$ +".";
    end;
OnInit:
    .reward_day = 1;// reward of the day : amount of Red Envelopes
    .reward_week = 7;// reward of the week : amount of Red Envelopes
    .reward_month = 32;// reward of the month : amount of Red Envelopes
    end;
}
 

The script gives you red envelope every time you log-in, each weekly/monthly log-in gives you additional item.

 

This however gives the item if you change character.

 

How do you make this account based rather than character based?

 

And I want them to be permanent variable, since the server won't run 24/7, it will have a day of rest, hence, it is not possible to get the weekly reward because the

variable is temporary.

Edited September 27, 2013 by gekigengar

[Joseph]

Search for

login_reward

replace them with

#login_reward

[Venture]

Search for

 

login_reward

replace them with

 

#login_reward

 

If the server close, does the "Number of days" still reset?

 

I want them to still prevail even after the server is closed down.

Edited September 28, 2013 by gekigengar

[Capuche]

If the server close, does the "Number of days" still reset?

No the variable is permanent

 

Here a revision

-	script	login_reward	-1,{
OnPCLoginEvent:
	.@pow = 1 << 10;
	.@todays = gettime(8);
	if ( #login_reward % .@pow == .@todays ) end;
	.@count = .reward_day;
	#login_reward = ( #login_reward &~ ( #login_reward % .@pow ) ) + .@todays + .@pow;
	.@count_day = ( #login_reward >> 10 ) % .@pow;
	if ( .@count_day % 7  == 0 ) {
		.@count += .reward_week;
		.@weekly_message$ = ( .@cond_ofthemonth ? ", " : " and " ) + .reward_week +" golds for being online a week";
	}
	if ( .@count_day % 31 == 0 ) {
		.@count += .reward_month;
		.@montly_message$ = " and " + .reward_month +" golds for being online a month";
	}
	getitem 969, .@count;
	dispbottom "Here your daily reward ! You got "+ .reward_day +" golds"+ .@weekly_message$ + .@montly_message$ +".";
	end;
OnInit:
	.reward_day = 2;// reward of the day : amount of gold
	.reward_week = 10;// reward of the week : amount of gold
	.reward_month = 35;// reward of the month : amount of gold
	end;
}