Request

[deso]

Request a npc if you talk to it will give you the requirements for the item and if he/she finish the quest it will be announce. thx

[Jaburak]

prontera,150,150,0	script	Test	123,{

mes "Do you want to make Baseball Cap?";
menu "Sure!",-;
next;
mes "You have to bring me these ingredients!";
menu "Okay",-;
next;
mes "50 Moth Wings";
mes "35 Sharp Leaf";
mes "50 Snail Shells";
mes "10 Gold";
menu "I have them",-;
if(countitem(1058) < 50 || countitem(7100) < 35 || countitem(946) < 50 || countitem(969) < 10) goto Lne;
next;
mes "Okay, here you go!";
delitem 1058,50;
delitem 7100,35;
delitem 946,50;
delitem 969,10;
getitem 5199,1;
announce "Wow! "+strcharinfo(0)+" has just created Baseball Cap!",bc_all,0x00FF4C;
close;

Lne:
mes "Are you trying to fool me!?";
close;

}

Just change the item requirements, reward and the announce.

[rans]

-    shop    quest_shop2    -1,909:-1
Map,X,Y,P    script    Custom Quest v2    809,{
set @i,0;
mes "[Shop Quest NPC]";
mes "Which item do you wish to obtain?";
mes "Select only one.";
callshop "quest_shop2",1;
npcshopattach "quest_shop2";
end;

OnBuyItem:
  if(.BuildQuest) {
    for(set .e,0; !compare(getarg(.e+1) + "","Zeny"); set .e,.e+2) {}
    npcshopadditem "quest_shop2",getarg(.e+2),getarg(.e)*compare(getarg(.e+1) + "","SZeny");
    setarray .Shop[.i],getarg(.e+2);
    set .i,.i+1;
    goto Quest_Setup;
  }
  if(.Shop[@i]!=@bought_nameid) for(set @i,1; 1; set @i,@i+1) if(.Shop[@i]==@bought_nameid) { set .i,@i; callsub Quest_Setup; }
  for(set @i,1; !@e; set @i,@i+1) if(.Shop[@i]==@bought_nameid) { set @e,1; set .i,@i; callsub Quest_Setup; }
  mes "[Shop Quest NPC]";
  mes "I require the following:";
  for(set @i,0; !compare(getarg(@i+1) + "","Zeny"); set @i,@i+2) mes "^FF0000" + ((countitem(getarg(@i))>=getarg(@i+1))? "^00FF00":"") + "" + getarg(@i+1) + " " + getitemname(getarg(@i)) + " [" + countitem(getarg(@i)) + "/" + getarg(@i+1) + "]";
  if(getarg(@i)) mes "^FF0000" + ((Zeny>=getarg(@i))? "^00FF00":"") + "" + getarg(@i) + " Zeny";
  mes "^000000In exchange, I will give you:^0000FF";
  for(set @i,@i+2; getarg(@i+1,0); set @i,@i+2) mes getarg(@i+1) + " " + getitemname(getarg(@i));
  switch(select("Exchange:" + (((((getiteminfo(@bought_nameid,5) & 1) || (getiteminfo(@bought_nameid,5) & 256) || (getiteminfo(@bought_nameid,5) & 512)) && @equip==0))? "Preview Item":"") + ":No thanks")) {
    case 1:
      for(set @i,0; !compare(getarg(@i+1) + "","Zeny"); set @i,@i+2) if(countitem(getarg(@i)) < getarg(@i+1)) {
        next;
        mes "You have " + countitem(getarg(@i)) + " " + getitemname(getarg(@i)) + ", while I require " + getarg(@i+1) + ".";
        mes "Please obtain ^FF0000" + (getarg(@i+1)-countitem(getarg(@i))) + " more " + getitemname(getarg(@i)) + "^000000.";
        close;
      }
      if(Zeny < getarg(@i)) {
        next;
        mes "You do not have enough Zeny.";
        mes "Please obtain ^FF0000" + (getarg(@i)-Zeny) + " more Zeny^000000.";
        close;
      }
      for(set @i,0; !compare(getarg(@i+1) + "","Zeny"); set @i,@i+2) delitem getarg(@i),getarg(@i+1);
      set Zeny,Zeny-getarg(@i);
      for(set @i,@i+2; getarg(@i+1,0); set @i,@i+2) getitem getarg(@i),getarg(@i+1);
      if (compare(getarg(@i,0) + "","announce")) announce strcharinfo(0) + " has just obtained " + getitemname(@bought_nameid) + " from the QUEST npc!",bc_all;
      close;
    case 2:
      set @bottomview, getlook(3);
      set @topview, getlook(4);
      set @midview, getlook(5);
      addtimer 1000, strnpcinfo(3)+"::On_Leave";
      set @equip,getiteminfo(@bought_nameid, 5);
      set @view, getiteminfo(@bought_nameid, 11);
      if(@equip != -1 && @view > 0) {
        if(@equip & 1) atcommand "@changelook 3 " + @view;
        if(@equip & 256) atcommand "@changelook 1 " + @view;
        if(@equip & 512) atcommand "@changelook 2 " + @view;
      }
      next;
      goto OnBuyItem;
      case 3:
      close;
  }
On_Leave:
  atcommand "@changelook 1 " + @topview;
  atcommand "@changelook 2 " + @midview;
  atcommand "@changelook 3 " + @bottomview;
  set @equip,0;
  set @view,0;
  set @topview,0;
  set @midview,0;
  set @bottomview,0;
  end;
OnInit:
    npcshopitem "quest_shop2",0,0;
    npcshopdelitem "quest_shop2",0,0;
    set .BuildQuest,1;
    set .i,1;;
  Quest_Setup:
  switch(.i) {
        default: set .BuildQuest,0; set .e,0; set .i,0; end;
        case 1: callsub OnBuyItem,"Item ID","Amount",0,"SZeny","Item Reward","Ammount","announce";
                 
    }
}

 

Something like that??

Edited June 23, 2013 by Emistry
added [code]

[deso]

Thanks for the help i'll try it