reque 1 NPC

PapaZola · March 18, 2013

anyone got this npc in one?

-job changer

-baby job changer
-platinium skill(2nd job)
-reset stats & skill
-rental npc
-card remover

-sex changer

Edited March 18, 2013 by PapaZola

Mootie · March 18, 2013

http://pastebin.com/raw.php?i=GJ4ukgGH

source http://rathena.org/board/topic/64394-%E2%9C%B0-euphys-scripts-%E2%9C%B0/

PapaZola · March 18, 2013

how if wanna remove some func like refiner and exchanged coin

Rayan · March 18, 2013

// --------------------- Config ---------------------
    setarray .MainMenu$[0],    // Set menu options!
        "Change Jobs",        // [1]
        "Stylist",        // [2]
        "Refiner",        // [4]
        "Remove Cards",        // [8]
        "Exchange Coins",    // [16]
        "Rentals",        // [32]
        "Reset Stats/Skills",    // [64]
        "Platinum Skills",    // [128]
        "Change Sex",        // [256]
        "Identify All";        // [512]

i think putting "//" before the option you wanna disable would do.

PapaZola · March 18, 2013

i edy try but when i choose remove cards the funcs same like stylist

Shakto · March 18, 2013

//===== rAthena Script =======================================

//= All-in-One NPC

//===== By: ==================================================

//= Euphy

//===== Current Version: =====================================

//= 1.6

//===== Description: =========================================

//= A compilation of commonly-used NPC scripts.

//== Includes job changer, stylist, refiner, card remover,

//== coin exchanger, rentals, resetter, platinum skills,

//== sex changer, identifier, healer, buffer, and repairman.

//============================================================

prontera,148,174,6 script All-in-One NPC 953,{

function Get_Platinum; function Equip_Menu;

if (getarraysize(.OnClick)) {

if (.OnClick[0]) { specialeffect2 313; percentheal 100,100; }

if (.OnClick[1]) { specialeffect2 42; sc_start SC_BLESSING,600000,10; specialeffect2 37; sc_start SC_INCREASEAGI,600000,10; }

if (.OnClick[2] && getbrokenid(1)) { specialeffect2 101; atcommand "@repairall"; } }

set .@menu$,"";

for (set .@i,0; .@i < getarraysize(.MainMenu$); set .@i,.@i+1) {

if (.MenuOption & pow(2,.@i))

set .@menu$, .@menu$+" ~ "+.MainMenu$[.@i];

set .@menu$, .@menu$+":"; }

switch(select(.@menu$)) {

case 1:

function Job_Menu; function A_An;

if (Class > 4049) {

message strcharinfo(0),"No more jobs are available."; close; }

if (checkfalcon() || checkcart() || checkriding() || ismounting()) {

message strcharinfo(0),"Please remove your "+((checkfalcon())?"falcon":"")+((checkcart())?"cart":"")+((checkriding())?"Peco":"")+((ismounting())?"mount":"")+" before proceeding.";

close; }

if (.SkillPointCheck && SkillPoint) { message strcharinfo(0),"Please use all your skill points before proceeding."; close; }

set .@eac, eaclass();

set .@i, ((.ThirdClass)?roclass(.@eac&EAJ_UPPERMASK):Class);

if (.@i > 6 && .@i < 22) {

if (BaseLevel < .Rebirth[0] || JobLevel < .Rebirth[1]) {

set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .Rebirth[1]-JobLevel;

message strcharinfo(0),"You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";

close; }

if (Class > 21) { Job_Menu(roclass(.@eac|EAJL_THIRD)); close; }

while(1) {

set .@i, select(" ~ ^0055FFRebirth^000000:"+((.ThirdClass)?" ~ ^FF0000Third Class^000000":"")+": ~ ^777777Cancel^000000");

if (.@i==3) close;

Job_Menu(((.@i==1)?4001:roclass(.@eac|EAJL_THIRD))); } }

set .@j1, roclass(.@eac|EAJL_2_1); set .@j2,roclass(.@eac|EAJL_2_2);

if ((.@eac&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE) setarray .@exp[0],roclass(.@eac|EAJL_THIRD),99;

if (Class == Job_Ninja) setarray .@exp[0],.@j1,70;

if (.@exp[0] && .ThirdClass) {

if (BaseLevel < .Rebirth[0] || JobLevel < .@exp[1]) {

set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .@exp[1]-JobLevel;

message strcharinfo(0),"You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";

close; }

Job_Menu(.@exp[0]); close; }

if (.@eac&EAJL_2)

if (.@eac&(EAJL_UPPER|EAJL_BABY) || roclass(.@eac|EAJL_UPPER) == -1) {

message strcharinfo(0),"No more jobs are available."; close; }

if ((.@eac&EAJ_BASEMASK) == EAJ_NOVICE) {

if (JobLevel < .JobReq[0]) message strcharinfo(0),"A job level of "+.JobReq[0]+" is required to change into the 1st Class.";

else if (Class == 4001 && .LastJob && lastJob) Job_Menu(roclass((eaclass(lastJob)&EAJ_BASEMASK)|EAJL_UPPER));

else switch(Class) {

case 0: Job_Menu(1,2,3,4,5,6,23,4046,24,25,4023);

case 4001: Job_Menu(4002,4003,4004,4005,4006,4007);

case 4023: Job_Menu(4024,4025,4026,4027,4028,4029,4045);

default: message strcharinfo(0),"An error has occurred."; break; }

close; }

if (roclass(.@eac|EAJL_2_1) == -1 || roclass(.@eac|EAJL_2_2) == -1) message strcharinfo(0),"No more jobs are available.";

else if (!(.@eac&EAJL_2) && JobLevel < .JobReq[1]) message strcharinfo(0),"A job level of "+.JobReq[1]+" is required to change into the 2nd Class.";

else if (.LastJob && lastJob && (.@eac&EAJL_UPPER)) Job_Menu(lastJob+4001);

else Job_Menu(.@j1,.@j2);

close;

function Job_Menu {

if (getargcount() > 1) {

set .@menu$,"";

for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)

set .@menu$, .@menu$+" ~ "+jobname(getarg(.@i))+":";

set .@menu$, .@menu$+" ~ ^777777Cancel^000000"; }

while(1) {

if (getargcount() > 1) {

set .@i, getarg(select(.@menu$)-1,0);

if (!.@i) close; }

else set .@i, getarg(0);

if ((.@i == 23 || .@i == 4045) && BaseLevel < .SNovice) {

message strcharinfo(0),"A base level of "+.SNovice+" is required to turn into a "+jobname(.@i)+"."; }

else if (select(" ~ Change into ^0055FF"+jobname(.@i)+"^000000 class: ~ ^777777Go back^000000")==1) {

message strcharinfo(0),"Became "+A_An(jobname(.@i))+"!";

if (.@i==4001 && .LastJob) set lastJob, Class;

jobchange .@i;

if (.@i==4001 || .@i==4023) resetlvl(1);

specialeffect2 338; specialeffect2 432;

if (.Platinum) Get_Platinum;

close; }

if (getargcount() == 1) return;

} end; }

function Get_Platinum {

skill 142,1,0;

switch(BaseClass) {

case 0: if (Class !=23) skill 143,1,0; break;

case 1: skill 144,1,0; skill 145,1,0; skill 146,1,0; break;

case 2: skill 157,1,0; break;

case 3: skill 147,1,0; skill 148,1,0; break;

case 4: skill 156,1,0; break;

case 5: skill 153,1,0; skill 154,1,0; skill 155,1,0; break;

case 6: skill 149,1,0; skill 150,1,0; skill 151,1,0; skill 152,1,0; break;

default: break; }

switch(roclass(eaclass()&EAJ_UPPERMASK)) {

case 7: skill 1001,1,0; break;

case 8: skill 1014,1,0; break;

case 9: skill 1006,1,0; break;

case 10: skill 1012,1,0; skill 1013,1,0; break;

case 11: skill 1009,1,0; break;

case 12: skill 1003,1,0; skill 1004,1,0; break;

case 14: skill 1002,1,0; break;

case 15: skill 1015,1,0; skill 1016,1,0; break;

case 16: skill 1007,1,0; skill 1008,1,0; skill 1017,1,0; skill 1018,1,0; skill 1019,1,0; break;

case 17: skill 1005,1,0; break;

case 18: skill 238,1,0; break;

case 19: skill 1010,1,0; break;

case 20: skill 1011,1,0; break;

default: break; }

return; }

function A_An {

setarray .@A$[0],"a","e","i","o","u";

set .@B$, "_"+getarg(0);

for(set .@i,0; .@i<5; set .@i,.@i+1)

if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);

return "a "+getarg(0); }

case 2:

setarray .@Look[1],7,1,6;

set .@s, select(" ~ Cloth color: ~ Hairstyle: ~ Hair color");

set .@Revert, getlook(.@Look[.@s]); set .@Style,1;

while(1) {

setlook .@Look[.@s], .@Style;

message strcharinfo(0),"This is style #"+.@Style+".";

set .@menu$, " ~ Next (^0055FF"+((.@Style!=.Styles[.@s])?.@Style+1:1)+"^000000): ~ Previous (^0055FF"+((.@Style!=1)?.@Style-1:.Styles[.@s])+"^000000): ~ Jump to...: ~ Revert to original (^0055FF"+.@Revert+"^000000)";

switch(select(.@menu$)) {

case 1: set .@Style, ((.@Style!=.Styles[.@s])?.@Style+1:1); break;

case 2: set .@Style, ((.@Style!=1)?.@Style-1:.Styles[.@s]); break;

case 3: message strcharinfo(0),"Choose a style between 1 - "+.Styles[.@s]+".";

input .@Style,0,.Styles[.@s];

if (!.@Style) set .@Style, rand(1,.Styles[.@s]);

break;

case 4: set .@Style, .@Revert; setlook .@Look[.@s], .@Revert; break; }

} end;

case 3:

if (.Prices[0]) message strcharinfo(0),"It costs "+.Prices[0]+" Zeny to remove cards.";

Equip_Menu(0);

if (Zeny < .Prices[0]) { message strcharinfo(0),"You don't have enough Zeny."; close; }

set .@j,getequipcardcnt(@i);

if (!.@j) { message strcharinfo(0),"There are no cards compounded to "+getequipname(@i)+"."; close; }

if (!checkweight(4001,(.@j+1))) { message strcharinfo(0),"You're carrying too many items!"; close; }

message strcharinfo(0),"Item: "+getequipname(@i);

if (select(" ~ Remove "+.@j+" card(s): ~ ^777777Cancel^000000")==2) close;

set Zeny, Zeny-.Prices[0];

successremovecards @i;

message strcharinfo(0),"Cards successfully removed!";

close;

case 4:

if (Zeny < .Prices[2]) { message strcharinfo(0),"It costs "+.Prices[2]+" Zeny to rent."; close; }

if (ismounting()) { message strcharinfo(0),"You must first remove your mount."; close; }

else if ((eaclass()&EAJ_THIRDMASK==EAJ_RANGER) && !countitem(6124)) {

if (!checkfalcon() && getskilllv(127) && !checkwug()) {

if(select(" ~ Falcon: ~ Warg")==1) setfalcon;

else getitem 6124,1; }

else if ((eaclass()&EAJ_THIRDMASK==EAJ_MECHANIC) && !checkcart() && getskilllv(39)) {

if (!checkmadogear() && getskilllv(2255)) {

if(select(" ~ Cart: ~ Mado")==1) setcart;

else setmadogear; }

else setcart; }

else if (!checkcart() && getskilllv(39)) setcart;

else if (!checkfalcon() && getskilllv(127) && !checkwug()) setfalcon;

else if (!checkriding() && getskilllv(63)) {

if (eaclass()&EAJ_THIRDMASK==EAJ_RUNE_KNIGHT) setdragon;

else setriding; }

else if (!checkmadogear() && getskilllv(2255)) setmadogear;

else { message strcharinfo(0),"You do not meet requirements to rent."; close; }

set Zeny, Zeny-.Prices[2];

specialeffect2 276;

close;

case 5:

if (.Prices[1]) message strcharinfo(0),"It costs "+.Prices[1]+" Zeny to reset stats or skills.";

set .@i, select(" ~ Stat reset: ~ Skill reset: ~ Cancel");

if (.@i==3) close;

if (Zeny < .Prices[1]) { message strcharinfo(0),"You don't have enough Zeny."; close; }

set Zeny, Zeny-.Prices[1];

if (.@i==1) ResetStatus;

else { sc_end SC_ALL; ResetSkill; }

message strcharinfo(0),((.@i==1)?"Stats":"Skills")+" reset!";

close;

case 6:

Get_Platinum;

specialeffect2 441;

message strcharinfo(0),"Platinum skills received!";

close;

case 7:

set .@Var$, ".SexChange"+((Sex)?"F":"M");

if (getarraysize(getd(.@Var$))) {

message strcharinfo(0),"To turn into a "+((Sex)?"female":"male")+" you need the following items:";

sleep2 1000;

for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2) {

message strcharinfo(0),getd(.@Var$+"["+(.@i+1)+"]")+"x "+getitemname(getd(.@Var$+"["+.@i+"]"));

if (countitem(getd(.@Var$+"["+.@i+"]")) < getd(.@Var$+"["+(.@i+1)+"]")) set .@nreq,1;

sleep2 500; }

if (.@nreq) close; }

if(select(" ~ Change into a "+((Sex)?"female":"male")+": ~ Cancel")==2) close;

if (getarraysize(getd(.@Var$)))

for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2)

delitem getd(.@Var$+"["+.@i+"]"), getd(.@Var$+"["+(.@i+1)+"]");

changesex;

end;

case 8:

setarray .@Total[0],0,0;

getinventorylist;

for(set .@i,0; .@i<@inventorylist_count; set .@i,.@i+1) {

if (@inventorylist_identify[.@i]) continue;

if (Zeny < .Prices[3]) {

dispbottom "It costs "+.Prices[3]+" to identify an item."; break; }

set Zeny, Zeny-.Prices[3];

delitem2 @inventorylist_id[.@i],1,0,0,0,0,0,0,0;

getitem @inventorylist_id[.@i],1;

setarray .@Total[0], .@Total[0]+1, .@Total[1]+.Prices[3]; }

if (!.@Total[0]) { message strcharinfo(0),"No items identified."; close; }

specialeffect2 154;

message strcharinfo(0),"Identified "+.@Total[0]+" items"+((.@Total[1])?" for "+.@Total[1]+" Zeny":"")+".";

close;

function Equip_Menu {

setarray .@pos$[1],"Upper Headgear","Armor","Left hand","Right hand","Garment","Footgear","Left Accessory","Right Accessory","Mid Headgear","Lower Headgear";

set .@menu$,"";

for (set .@i,1; .@i <= 10; set .@i,.@i+1) {

if (getequipisequiped(.@i))

set .@menu$, .@menu$+.@pos$[.@i]+" [^0055FF"+getequipname(.@i)+"^000000]";

set .@menu$, .@menu$+":"; }

set @i, select(.@menu$);

if (!getequipisequiped(@i)) { message strcharinfo(0),"Nothing is equipped there!"; close; }

if (getarg(0)) {

if (!getequipisenableref(@i)) { message strcharinfo(0),getequipname(@i)+" cannot be refined."; close; }

if (getequiprefinerycnt(@i) >= 10 ) { message strcharinfo(0),"+"+getequiprefinerycnt(@i)+" "+getequipname(@i)+" cannot be refined any further."; close; } }

return; }

}

OnInit:

// --------------------- Config ---------------------

setarray .MainMenu$[0], // Set menu options!

"Change Jobs", // [1]

"Stylist", // [2]

"Remove Cards", // [4]

"Rentals", // [8]

"Reset Stats/Skills", // [16]

"Platinum Skills", // [32]

"Change Sex", // [64]

"Identify All"; // [128]

set .MenuOption,1|2|4|8|16|32|64|128;

setarray .OnClick[0],1,1,1; // When clicked: heal [0], buff [1], repair [2] (1: yes / 0: no)

setarray .Styles[1],553,37,250; // Maximum dye, hair style, and hair color

setarray .Prices[0],50000,10000,0,100; // Zeny to remove cards [0], reset [1], rent [2], identify [3]

setarray .Rebirth[0],99,50; // Minimum base level, job level to rebirth OR change to third class

setarray .JobReq[0],10,40; // Minimum job level to turn into 1st class, 2nd class

set .ThirdClass,1; // Enable third classes? (1: yes / 0: no)

set .SNovice,45; // Minimum base level to turn into Super Novice

set .LastJob,1; // Enforce linear class changes? (1: yes / 0: no)

set .SkillPointCheck,0; // Force player to use up all skill points? (1: yes / 0: no)

set .Platinum,1; // Get platinum skills automatically? (1: yes / 0: no)

setarray .SexChangeF[0],2213,1,1558,1,7152,50; // Items to turn into Female (ID,Count)

setarray .SexChangeM[0],5016,1,2241,1,1017,50; // Items to turn into Male (ID,Count)

// --------------------------------------------------

end;

}

Edited March 20, 2013 by Shakto

Capuche · March 18, 2013

// --------------------- Config ---------------------
	setarray .MainMenu$[0],	// Set menu options!
		"Change Jobs",		// [1]
		"Stylist",		// [2]
		"Refiner",		// [4]
		"Remove Cards",		// [8]
		"Exchange Coins",	// [16]
		"Rentals",		// [32]
		"Reset Stats/Skills",	// [64]
		"Platinum Skills",	// [128]
		"Change Sex",		// [256]
		"Identify All";		// [512]

	set .MenuOption,1|2|4|8|16|32|64|128|256|512;

If you want all the npc, keep

set .MenuOption,1|2|4|8|16|32|64|128|256|512;

If you want all the npc except

"Change Sex",		// [256]

Remove 256 in

set .MenuOption,1|2|4|8|16|32|64|128|512;

etc..

PapaZola · March 19, 2013

i got this

thanks i will try later

thanks for u guys reply

PapaZola · March 19, 2013

aww still same

here my script im edy follow Capuche guide

http://pastebin.com/fE8rZz0g

PapaZola · March 19, 2013

bump

Shakto · March 20, 2013

I posted the script try it

Capuche · March 20, 2013

aww still same

here my script im edy follow Capuche guide

http://pastebin.com/fE8rZz0g

	setarray .MainMenu$[0],	// Set menu options!
		"Change Jobs",		// [1]
		"Stylist",		// [2]
		"Refiner",		// [4]
		"Remove Cards",		// [8]
		"Exchange Coins",	// [16]
		"Rentals",		// [32]
		"Reset Stats/Skills",	// [64]
		"Platinum Skills",	// [128]
		"Change Sex",		// [256]
		"Identify All";		// [512]

Don't comment theses lines - you have commented some in your script - just set .MenuOption.

Or try the script by Shakto (well I don't test it lol)

PapaZola · March 20, 2013

solved

Sign In

reque 1 NPC

Question

PapaZola

12 answers to this question

Recommended Posts

Mootie

PapaZola

Rayan

PapaZola

Shakto

Capuche

PapaZola

PapaZola

PapaZola

Shakto

Capuche

PapaZola

Join the conversation

Recently Browsing 0 members

Docs

Get Started

Github

Community

My Account