little change in Stylist script

[hyuna]

trunk/npc/custom/stylist.txt

here is my default stylist script from rathena....my problem is that when I click previous, next still is the top option.
I want the previous to be the top option after I click previous and next to be top after I click next again. THX...

Edited March 15, 2013 by hyuna

[Capuche]

//===== rAthena Script =======================================

//= Stylist

//===== By: ==================================================

//= Euphy

//===== Current Version: =====================================

//= 1.1

//===== Compatible With: =====================================

//= rAthena SVN

//===== Description: =========================================

//= Changes your hair style, hair color, and cloth color.

//===== Additional Comments: =================================

//= 1.1 Switched to 'getbattleflag', credits to Saithis. [Euphy]

//============================================================

prontera,170,180,1 script Stylist#custom_stylist 122,{

setarray .@Styles[1],getbattleflag("max_cloth_color"),getbattleflag("max_hair_style"),getbattleflag("max_hair_color");

setarray .@Look[1],7,1,6;

set .@s, select(" ~ Cloth color: ~ Hairstyle: ~ Hair color");

set .@Revert, getlook(.@Look[.@s]);

set .@Style,1;

while(1) {

setlook .@Look[.@s], .@Style;

message strcharinfo(0),"This is style #"+.@Style+".";

if( .@s_menu == 2 ) {

set .@menu$, " ~ Previous (^0055FF"+((.@Style!=1)?.@Style-1:.@Styles[.@s])+"^000000): ~ Next (^0055FF"+((.@Style!=.@Styles[.@s])?.@Style+1:1)+"^000000): ~ Jump to...: ~ Revert to original (^0055FF"+.@Revert+"^000000)";

set .@s_menu, select(.@menu$);

if( .@s_menu == 2 )

set .@s_menu, 1;

else if( .@s_menu == 1 )

set .@s_menu, 2;

}

else {

set .@menu$, " ~ Next (^0055FF"+((.@Style!=.@Styles[.@s])?.@Style+1:1)+"^000000): ~ Previous (^0055FF"+((.@Style!=1)?.@Style-1:.@Styles[.@s])+"^000000): ~ Jump to...: ~ Revert to original (^0055FF"+.@Revert+"^000000)";

set .@s_menu, select(.@menu$);

}

switch(.@s_menu) {

case 1: set .@Style, ((.@Style!=.@Styles[.@s])?.@Style+1:1); break;

case 2: set .@Style, ((.@Style!=1)?.@Style-1:.@Styles[.@s]); break;

case 3: message strcharinfo(0),"Choose a style between 1 - "+.@Styles[.@s]+".";

input .@Style,0,.@Styles[.@s];

if (!.@Style) set .@Style, rand(1,.@Styles[.@s]);

break;

case 4: set .@Style, .@Revert; setlook .@Look[.@s], .@Revert; break;

}

}

}

[hyuna]

bump

[iraciz]

is there any existing script that open a slot to save your hairstyle or cloth color?

[hyuna]

THX Capuche!!! SOLVED...