Castle Owner Warper

[jigsgfx]

Hi, hope that someone can help me with this script

i need a script npc that can warp a Castle Owner (Guild Leader ONLY) to a specific place.

example my OPEN Castle is Krimhield so who ever the guild leader of krim can only use the npc and warp to a specific place? make sense?

thanks in advance to those who will help me...

[Euphy]

if (strcharinfo(0) == getguildmaster(getcharid(2)) && getcharid(2) == getcastledata("prtg_cas01",1)) {}

[jigsgfx]

if (strcharinfo(0) == getguildmaster(getcharid(2)) && getcharid(2) == getcastledata("prtg_cas01",1)) {}

thanks Euphy but how i can make this as npc sorry im not a scripter dont know how to make script i only know how to edit them

[AnnieRuru]

prontera,156,172,5    script    kdfhskfjhs    100,{
   if ( getcharid(2) != getcastledata( "prtg_cas01", 1 ) ) {
       mes "your guild is not the owner of Krimhield castle";
       close;
   }
   if ( getcharid(0) != getguildmasterid( getcharid(2) ) ) {
       mes "you are not guild master of your guild";
       close;
   }
   warp "prtg_cas01", 0,0; // warp to specific places
   end;
}

[jigsgfx]

thanks alot Annie your the best

last question what if i have all prontera castle not only krimheild?

is this correct?

prontera,156,172,5 script kdfhskfjhs 100,{
if ( getcharid(2) != getcastledata( "prtg_cas01", "prtg_cas02", "prtg_cas03", 3 ) ) {
 mes "your guild is not the owner of Krimhield castle";
 close;
}
if ( getcharid(0) != getguildmasterid( getcharid(2) ) ) {
 mes "you are not guild master of your guild";
 close;
}
warp "prontera", 0,0; // warp to specific places
end;
}

Edited January 9, 2013 by jigsgfx

[AnnieRuru]

beginner level script

prontera,156,172,5    script    kdfhskfjhs    100,{
   mes "select a castle";
   next;
   menu "Kriemhild", L_prtg_cas01,
   "Swanhild", L_prtg_cas02,
   "Fadhgridh", L_prtg_cas03;
L_prtg_cas01:
   if ( getcharid(2) != getcastledata( "prtg_cas01", 1 ) ) {
       mes "your guild is not the owner of Krimhield castle";
       close;
   }
   if ( getcharid(0) != getguildmasterid( getcharid(2) ) ) {
       mes "you are not guild master of your guild";
       close;
   }
   warp "prtg_cas01", 0,0; // warp to specific places
   end;
L_prtg_cas02:
   if ( getcharid(2) != getcastledata( "prtg_cas02", 1 ) ) {
       mes "your guild is not the owner of Swanhild castle";
       close;
   }
   if ( getcharid(0) != getguildmasterid( getcharid(2) ) ) {
       mes "you are not guild master of your guild";
       close;
   }
   warp "prtg_cas02", 0,0; // warp to specific places
   end;
L_prtg_cas03:
   if ( getcharid(2) != getcastledata( "prtg_cas03", 1 ) ) {
       mes "your guild is not the owner of Fadhgridh castle";
       close;
   }
   if ( getcharid(0) != getguildmasterid( getcharid(2) ) ) {
       mes "you are not guild master of your guild";
       close;
   }
   warp "prtg_cas03", 0,0; // warp to specific places
   end;
}

advance level

prontera,156,172,5	script	kdfhskfjhs	100,{
mes "select a castle";
next;
.@s = select( .menu$ ) -1;
if ( getcharid(2) != getcastledata( .castle_map$[.@s], 1 ) ) {
	mes "your guild is not the owner of "+ .castle_name$[.@s] +" castle";
	close;
}
if ( getcharid(0) != getguildmasterid( getcharid(2) ) ) {
	mes "you are not guild master of your guild";
	close;
}
warp .castle_map$[.@s], 0,0; // warp to specific places
end;
OnInit:
setarray .castle_map$, "prtg_cas01", "prtg_cas02", "prtg_cas03"; // add more castle map here

while ( getstrlen( .castle_map$[.@i] ) ) {
	.castle_name$[.@i] = getcastlename( .castle_map$[.@i] );
	.@i++;
}
.menu$ = implode( .castle_name$, ":" );
end;
}

EDIT: forgotten about *getcastlemap script command

Edited January 9, 2013 by AnnieRuru