Chnage advanced_refiner.txt +1 - +4 suscess 100% ?

[Altimage]

How to change Advanced refine suscess rate 100% +1 - +4

or can chage suscess rate in script.

//===== rAthena Script =======================================
//= Advanced Refiner
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.4
//===== Compatible With: =====================================
//= rAthena SVN
//===== Description: =========================================
//= [Aegis Conversion]
//= Refiner that uses Enriched ores to increase upgrade success.
//= After a conversation with Doddler, it's been established that
//= the advanced refiner works similar the the "Bubble Gum" item.
//= The success percentage is not "increased" however, if it fails
//= You get a second try. This tries twice at the same time,
//= effectively giving you a re-roll on your attempt.
//= - Dialog is only partly official to iRO.
//= - Uses the iRO position for this NPC.
//===== Additional Comments: =================================
//= 1.0 First Version. [L0ne_W0lf]
//= 1.1 Fixed a weird carriage return. o_o [L0ne_W0lf]
//= 1.2 Optimizing refine method [Zephyrus]
//= 1.3 Typo fixes [Yommy]
//= 1.4 Removed unnecessary dialogs [Zephyrus]
//============================================================

payon,174,138,0 script Suhnbi#cash 85,{
mes "[suhnbi]";
mes "I am the Armsmith";
mes "I can refine all kinds of weapons,";
mes "armor and equipment, so let me";
mes "know what you want to refine.";
next;
setarray .@position$[1], "Head","Body","Left hand","Right hand","Robe","Shoes","Accessory 1","Accessory 2","Head 2","Head 3";
set .@menu$,"";
for( set .@i,1; .@i <= 10; set .@i,.@i+1 )
{
if( getequipisequiped(.@i) )
set .@menu$, .@menu$ + .@position$[.@i] + "-" + "[" + getequipname(.@i) + "]";

set .@menu$, .@menu$ + ":";
}
set .@part,select(.@menu$);

if( !getequipisequiped(.@part) )
close;

if( !getequipisenableref(.@part) )
{
mes "[suhnbi]";
mes "I don't think I can refine this item at all.";
close;
}
if( !getequipisidentify(.@part) )
{
mes "[suhnbi]";
mes "This has not been identified. So, it can't be refined...";
close;
}
if( getequiprefinerycnt(.@part) >= 10 )
{
mes "[suhnbi]";
mes "This item cannot be refined because it has already reached its maximum level...";
close;
}

// Make sure you have the neccessary items and Zeny to refine your items
// Determines chance of failure and verifies that you want to continue.
switch( getequipweaponlv(.@part) )
{
case 1: callsub S_RefineValidate,1,7620,50,.@part; break;
case 2: callsub S_RefineValidate,2,7620,200,.@part; break;
case 3: callsub S_RefineValidate,3,7620,5000,.@part; break;
case 4: callsub S_RefineValidate,4,7620,20000,.@part; break;
default: callsub S_RefineValidate,0,7619,2000,.@part; break;
}

if( getequippercentrefinery(.@part) > rand(100) || getequippercentrefinery(.@part) > rand(100) )
{
mes "[suhnbi]";
mes "Clink! Clank! Clunk!";
SuccessRefItem .@part;
next;
Emotion e_no1;
mes "[suhnbi]";
mes "Here you are! It's done.";
mes "It's been a while since I've made such a fine weapon. You must be happy because it has become stronger!";
close;
}
mes "[suhnbi]";
mes "Clink! Clank! Clunk!";
FailedRefItem .@part;
next;
if (rand(5) == 1){
Emotion e_cash;
} else {
Emotion e_omg;
}
mes "[suhnbi]";
mes "Cough!!!!";
next;
mes "[suhnbi]";
mes "Cough...Cough..";
mes "What a shame...";
mes "Your equipment broke during the refining process. I had told you earlier this might happen!";
close;

S_RefineValidate:
mes "[suhnbi]";
if (getarg(0))
mes "A level " + getarg(0) + " weapon...";
mes "To refine this I need one ^ff9999" + getitemname(getarg(1)) + "^000000 and a service fee of " + getarg(2) + " Zeny.";
mes "Do you wish to continue?";
next;
if( select("Yes:No") == 1 )
{
if( getequippercentrefinery(getarg(3)) < 100 )
{
mes "[suhnbi]";
mes "Wow!!";
mes "This weapon, probably";
mes "looks like it's been refined...";
mes "many times...";
mes "It may break if";
mes "you refine it again.";
next;
mes "And if it breaks,";
mes "you can't use it anymore!";
mes "All the cards in it and the";
mes "properties";
mes "^ff0000will be lost^000000!!";
mes "^ff0000 besides, the equipment will break!^000000";
mes " ";
mes "Are you sure you still want to continue?";
next;
if( select("Yes:No") == 2 )
{
mes "[suhnbi]";
mes "I completely agree...";
mes "I might be a great refiner, but sometimes even I make mistakes.";
close;
}
}
if( countitem(getarg(1)) > 0 && Zeny > getarg(2) )
{
delitem getarg(1), 1;
set Zeny, Zeny - getarg(2);
return;
}
mes "[suhnbi]";
mes "You don't seem to have enough Zeny or " + getitemname(getarg(1)) + "...";
mes "Go get some more. I'll be here all day if you need me.";
close;
}
mes "[suhnbi]";
mes "Yeah... There's no need to rush.";
mes "Take your time.";
close;
}

when i change refine_db.txt to this

// Armors

0,66,0,0,90:0,90:0,85:0,80:0,60:0,40:0,40:0,20:0,20:0,10:0

// Level 1 weapons

1,200,8,300,95:0,95:0,90:0,90:0,85:0,85:0,80:0,60:0,40:0,20:0

// Level 2 weapons

2,300,7,500,95:0,95:0,90:0,90:0,80:0,80:0,60:0,40:0,20:0,20:0

// Level 3 weapons

3,500,6,800,95:0,90:0,90:0,85:0,80:0,60:0,50:0,20:0,20:0,20:0

// Level 4 weapons

4,700,5,1300,90:0,90:0,85:0,80:0,60:0,40:0,40:0,20:0,20:0,10:0

Edited December 11, 2012 by AnnieRuru
use [codebox] if the script > 10 lines

[AnnieRuru]

this is the default refine_db chance

0,66,0,0,100:0,100:0,100:0,100:0,60:0,40:0,40:0,20:0,20:0,10:0
// Level 1 weapons
1,200,8,300,100:0,100:0,100:0,100:0,100:0,100:0,100:0,60:0,40:0,20:0
// Level 2 weapons
2,300,7,500,100:0,100:0,100:0,100:0,100:0,100:0,60:0,40:0,20:0,20:0
// Level 3 weapons
3,500,6,800,100:0,100:0,100:0,100:0,100:0,60:0,50:0,20:0,20:0,20:0
// Level 4 weapons
4,700,5,1300,100:0,100:0,100:0,100:0,60:0,40:0,40:0,20:0,20:0,10:0

a normal refiner will calculate the chance only once

and advance refiner will calculate the chance twice ( if it failed for the 1st time, it will calculate again for 2nd time )

you mean you want to have your normal refiner and advance refiner doing separated refining rate ?

[Altimage]

i want my refine_db rate

0,66,0,0,90:0,90:0,85:0,80:0,60:0,40:0,40:0,20:0,20:0,10:0
1,200,8,300,95:0,95:0,90:0,90:0,85:0,85:0,80:0,60:0,40:0,20:0
2,300,7,500,95:0,95:0,90:0,90:0,80:0,80:0,60:0,40:0,20:0,20:0
3,500,6,800,95:0,90:0,90:0,85:0,80:0,60:0,50:0,20:0,20:0,20:0
4,700,5,1300,90:0,90:0,85:0,80:0,60:0,40:0,40:0,20:0,20:0,10:0

but How to change Advanced refine suscess rate 100% +1 - +4 or can chage suscess rate in script.

(separated refining rate)

Edited December 13, 2012 by Altimage

[Emistry]

try change

if( getequippercentrefinery(.@part) > rand(100) || getequippercentrefinery(.@part) > rand(100) ){

to

if( ( getequippercentrefinery(.@part) > rand(100) || getequippercentrefinery(.@part) > rand(100) ) || getequiprefinerycnt(.@part) < 4 )
{

btw..i was wondering..isnt that the advanced refiner did refine +1 ~ +4 100% success ?

and normally...player would use normal refiner for +1 ~ +4 then only they start to use advanced refiner...

advanced refiner doesnt give you a constant rate of refine succes...it just gave you "another chances" to get success refine if the first try failed. ( rate calculation )

[Altimage]

thk so much ^------^