Teleporter

[hardelite]

Hello everyone!
Could someone add these options to me in my script?
I've tried it in many ways, but I'm inexperienced ...

Script:

Spoiler

prontera,100,100,4    script    Champions Room    100,{

set @npc$,"[Champions Room]";

    setarray .@castles$[0],
        "prtg_cas01","prtg_cas02","prtg_cas03","prtg_cas04","prtg_cas05",
        "payg_cas01","payg_cas02","payg_cas03","payg_cas04","payg_cas05",
        "gefg_cas01","gefg_cas02","gefg_cas03","gefg_cas04","gefg_cas05",
        "aldeg_cas01","aldeg_cas02","aldeg_cas03","aldeg_cas04","aldeg_cas05",
        "arug_cas01","arug_cas02","arug_cas03","arug_cas04","arug_cas05",
        "schg_cas01","schg_cas02","schg_cas03","schg_cas04","schg_cas05";

    .@guild = getcharid(2);
    for(.@size = getarraysize(.@castles$);.@i < .@size;.@i++) {
        .@winner = getcastledata(.@castles$[.@i],CD_GUILD_ID);
        if(.@winner && .@winner == .@guild) {
            warp "sec_in01,167,37;
            end;
        }
    }
    mes "Sorry, only members of the clans that have conquered the castles can enter!";
    close;

}

I would like to add these options:

	mes @npc$;
	mes "Welcome to the Champions Hall!";
	mes "What do you want?";
	switch(select("- Enter","- Information","Leave"))

	case 1:
	mes @npc$;
	mes	"I'll take you there!";

	case 2:
	mes @npc$;
	mes	"There you will find exclusive quests.";

	case 3:
	mes @npc$;
	mes	"Come back when you need";

Thank you very much.

[Emistry]

try this

prontera,100,100,4	script	Champions Room	100,{
	.@guild = getcharid(2);

	mes "[Champions Room]";
	for(.@i = 0; .@i < .castle_size; .@i++) {
		.@winner = getcastledata(.castles$[.@i],CD_GUILD_ID);
		if(.@winner && .@winner == .@guild) {
			mes "Welcome to the Champions Hall!";
			mes "What do you want?";
			next;
			switch(select(
				"- Enter",
				"- Information",
				"Leave"
			)) {
				case 1:
					mes "[Champions Room]";
					mes	"I'll take you there!";
					close2;
					warp "sec_in01",167,37;
					end
				case 2:
					mes "[Champions Room]";
					mes	"There you will find exclusive quests.";
					break;
				default:
					mes "[Champions Room]";
					mes	"Come back when you need";
					break;
			}
			close;
		}
	}
	mes "Sorry, only members of the clans that have conquered the castles can enter!";
	close;

	OnInit:
		setarray .castles$[0],
			"prtg_cas01","prtg_cas02","prtg_cas03","prtg_cas04","prtg_cas05",
			"payg_cas01","payg_cas02","payg_cas03","payg_cas04","payg_cas05",
			"gefg_cas01","gefg_cas02","gefg_cas03","gefg_cas04","gefg_cas05",
			"aldeg_cas01","aldeg_cas02","aldeg_cas03","aldeg_cas04","aldeg_cas05",
			"arug_cas01","arug_cas02","arug_cas03","arug_cas04","arug_cas05",
			"schg_cas01","schg_cas02","schg_cas03","schg_cas04","schg_cas05";
		.castle_size = getarraysize(.castles$);
		end;
}