Random Item Random Enhancement

[Norse]

I need someone help to make box script for random item with random with random enhancement. And the enhancement must be at the 4th slot. Please help me if this possible.

[Cyro]

 

prontera,155,175,5	script	CraftWoman#xilence01	4_F_KAFRA9,{
	// success rate
	.@rate = 100;
	// required item
	setarray .@item,7623,1;
	
	mes "[CraftWomen]";
	mes "I can refine Your equiment";
	next;
	mes "[CraftWomen]";
	mes "Depends on your luck you can get up to +10 stat orbs with 100% success rate";
	next;
	mes "[CraftWomen]";
	mes "for Shields i will give different orbs";
	mes "You can get enhanced shield with atk,flee,matk bonus based on your luck";
	next;
	mes "[CraftWomen]";
	mes "Be carefull, once you enhance any equipment";
	mes "You can not remove orb from equipment by any chance";
	next;
	mes "[CraftWomen]";
	mes "Enchant Equipment: "+.@item[1]+"x "+getitemname( .@item[0] );
	switch ( select(
		"Armors",
		"Shields",
		"Garment",
		"Footgear",
		"Cancel"
	)) {
		case 1: 
			.@position = EQI_ARMOR;
			.@enchant = rand( 4700,4759 ); 
			break;
		case 2: 
			.@position = EQI_HAND_L;
			.@enchant = rand( 4760,4767 );
			break;
		case 3: 
			.@position = EQI_GARMENT;
			.@enchant = rand( 4700,4759 ); 
			break;
		case 4: 
			.@position = EQI_SHOES;
			.@enchant = rand( 4700,4759 );
			break;
		default: break;
	}
	if ( .@enchant ) {
		.@itemid = getequipid( .@position );
		if ( .@itemid <= 0 || getiteminfo( .@itemid,2 ) != IT_ARMOR ) {
			mes "[CraftWomen]";
			mes "You didnt wear any equipment.";
		}
		else if ( getequipcardid( .@position,1 ) ) {
			mes "[CraftWomen]";
			mes "The equipment already enchanted.";
		}
		else if ( countitem( .@item[0] ) < .@item[1] ) {
			mes "[CraftWomen]";
			mes "You didnt have "+.@item[1]+"x "+getitemname( .@item[0] );
		}
		else {
			
			.@refine = getequiprefinerycnt( .@position );
			.@card1 = getequipcardid( .@position,0 );
			// .@card2 = getequipcardid( .@position,1 );
			.@card2 = .@enchant;
			.@card3 = getequipcardid( .@position,2 );
			.@card4 = getequipcardid( .@position,3 );
			
			delequip .@position;
			delitem .@item[0],.@item[1]; 
			
			if ( rand( 100 ) < .@rate ) {
				getitem2 .@itemid,1,1,.@refine,0,.@card1,.@card2,.@card3,.@card4;
				mes "Success enchanted with "+getitemname( .@card2 );
			}
			else {
				mes "Fail";
			}
		}
	}	
	close;
}

credits to emistry 

[Norse]

What i want is something like this scripts.

add new item
501,Red_Potion,Red Potion,0,50,,70,,,,,0xFFFFFFFF,7,2,,,,,,{ callfunc "CustomBox"; },{},{}

function	script	CustomBox	{
	setarray .BoxItems[0],501,502,503;
	
	set .Random, getarraysize( .BoxItems );
	getitem .BoxItems[ rand( .Random ) ], 1;
	end;
}

But with some mod, the item is enhance randomly to.

Edited August 24, 2017 by Norse