Please help me to make Sure Refiner with required of proof of donation

[unknownuser]

how to make refiner that required proof of donations

 

 

 

example:

 

• +10 is 2 proof of donation

   

  +11 is 3 proof of donation

  +12 to +14 is 4 proof of donation

  +15 is 5 proof of donation

  +16 is 7 proof of donation

  +17 is 8 proof of donation

  +18 is 10 proof of donation

  +19 is 12 proof of donation

  +20 is 15 proof of donation

   

 

PLEASE HELP ME !!

[unknownuser]

please help me ??

[Capuche]

Your "proof of donation" is an item or a variable?

[Patskie]

I think it's an item @Capuche. ID number is 7179

[unknownuser]

item sir , id 7179 please help me to make it )

[Ryokem]

You want to modify the current refiner NPC or create a custom NPC for this matter?

[Capuche]

prontera,150,184,5	script	ouinonjio	75,{

	setarray .@position$[1], "Head","Body","Left hand","Right hand","Robe","Shoes","Accessory 1","Accessory 2","Head 2","Head 3";
	setarray .@amount_item[0], 2,//+10
							3,4,4,4,5,7,8,10,12,15;

	for(set .@i,1; .@i<=10; set .@i,.@i+1) {
		if(getequipisequiped(.@i)) {
			set .@menu$, .@menu$ + .@position$[.@i] + "-" + "[" + getequipname(.@i) + "]";
			set .@equipped,1;
		}
		set .@menu$, .@menu$ + ":";
	}
	if (.@equipped == 0) {
		mes "I don't think I can refine any items you have...";
		close;
	}
	set .@part, select(.@menu$);

	if(!getequipisequiped(.@part)) { //custom check

		mes "You're not wearing";
		mes "anything there that";
		mes "I can refine.";
		emotion e_an;
		close;
	}
	//Check if the item is refinable...
	if(!getequipisenableref(.@part)) {
		mes "I don't think I can";
		mes "refine this item at all...";
		close;
	}
	//Check to see if the items is already +10
	if(getequiprefinerycnt(.@part) >= 20) {
		mes "I can't refine this";
		mes "any more. This is as";
		mes "refined as it gets!";
		close;
	}
	if(getequiprefinerycnt(.@part) < 9) {
		mes "I can't refine this.";
		mes "It must be at last +9.";
		close;
	}
	set .@refineitemid, getequipid(.@part); // save id of the item
	set .@refinerycnt, getequiprefinerycnt(.@part); //save refinery count
	set .@index, .@refinerycnt - 9;

	mes "To refine this I need";
	mes .@amount_item[ .@index ] +" ^003366"+getitemname(7179)+"^000000 and";
	mes "Do you really wish to continue?";
	next;
	if(select("Yes:No") == 2){
		mes "Yeah...";
		mes "There's no need to";
		mes "rush. Take your time.";
		close;
	}
	if((countitem(7179) < .@amount_item[ .@index ]) ) {

		mes "You don't seem to have";
		mes "enough "+getitemname(7179)+"...";
		mes "Go get some more. I'll be";
		mes "here all day if you need me.";
		close;
	}
	delitem 7179, .@amount_item[ .@index ];

	//custom checks
	if(getequipisequiped(.@part) == 0) { // hacker has removed the item (not changed, why?)
		mes "Look here... you don't have any Items on...";
		close;
	}
	if(getequiprefinerycnt(.@part) != .@refinerycnt || getequipid(.@part) != .@refineitemid) { // hacker has changed the item
		emotion e_an;
		mes "Wait a second...";
		mes "Do you think I'm stupid?!";
		mes "You switched the item while I wasn't looking! Get out of here!";
		close;
	}

	successrefitem .@part;
	emotion e_heh;
	set .@win,rand(1,3);
	if (.@win == 1) {
		mes "Perfect!";
		mes "Heh heh!";
		mes "Once again,";
		mes "flawless work";
		mes "from the master~";
	} else if(.@win == 2) {
		mes "Success...!";
		mes "Yet again, my amazing";
		mes "talent truly dazzles";
		mes "and shines today.";
	} else {
		mes "Heh heh!";
		mes "I'm all done.";
		mes "No doubt, my work is";
		mes "to your satisfaction.";
		mes "Sheer, utter perfection~";
	}
	close;
}

he didn't tell us, I guess it doesn't matter

[unknownuser]

custom only sir .. sorry for late responds

[Capuche]

Try IG the script above. If you are not satisfied tell us step by step what you exactly want.