WOE Error

Checkmate · August 2, 2013

Hello all rathena community...

I wondering why RO in my test server thier Emperium cannot be attacked while WOE was begun?..?

Here the picture...

I already upgrading the required skill to able attack emperium but it was in red bar while WOE was in progress.... Why this is happening????

Im setting the WOE 2 hour in all Payon Castle on this day...
But i cannot attack the emperium??..??

I already restart myserver for this.
But same problem occur...

Im using Euphy script....

Here you are...
Is ther something wrong in those script??..??

And


 //===== rAthena Script =======================================
//= Euphy's WOE Controller
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.5
//===== Compatible With: =====================================
//= rAthena SVN r16958+
//===== Description: =========================================
//= A controller for War of Emperium designed for
//= simplicity and ease of use.
//= Many concepts taken from ToastOfDoom's script,
//= and "rewards" function originally by Goddameit.
//===== Additional Comments: =================================
//= Be sure to disable the default agit controllers!
//== npc\guild\agit_controller.txt
//== npc\guild2\agit_start_se.txt
//============================================================

// Information NPC
//============================================================
prontera,154,195,4    script    WOE Information    1288,{
    doevent "WOE_CONTROL::OnMenu";
    end;
OnAgitStart:
    while(agitcheck()) {
        misceffect EF_BEGINSPELL6;
        sleep 425;
    }
    end;
}

// Script Core
//============================================================
-    script    WOE_CONTROL    -1,{
function Disp_Owner; function Add_Zero;

OnInit:

// -----------------------------------------------------------
//  Configuration settings.
// -----------------------------------------------------------

    set .CastleWarp,0;        // 1: Always enable all castle warps. | 0: Warp only to active castles.
    set .AutoKick,1;        // Automatically kick players from inactive castles during WOE? (1:yes / 0:no)
    set .NoOwner,0;         // Automatically kick players from unconquered castles outside of WOE? (1:yes / 0:no)
    set .ExitWarp,0;        // Warp all players from castles when WOE ends? (1:yes / 0:no)
    set .GMAccess,99;        // GM level required to access Session Manager.

// -----------------------------------------------------------
//  Reward options.
// -----------------------------------------------------------
//  [1] Enable rewards.
//  [2] Mail all rewards.
//      - If not set, players receive items in their inventory.
//      - Only ONE item can be sent via mail, plus Zeny.
//      - Note that offline players do NOT receive rewards.
//  [4] Only reward Guild Masters.
//      - If not set, all guild members are rewarded.
//      - If mailing is enabled (option 2), offline Guild Masters WILL receive rewards.
//  [8] Duplicate IP check.
//      - Members in a guild with the same IP address are not rewarded.
//      - If Guild Masters is enabled (option 4), this feature is not used.
// -----------------------------------------------------------

    // Combine values as needed (e.g. 1|8 = 1+8 = 9).
    set .Options, 1|8;

    // Rewards per castle.
    // -- when given directly: <itemID>,<amount>{,<itemID>,<amount>,...}
    // -- via mail (option 2): <itemID>,<amount>,<Zeny>
    setarray .Reward[0],14516,2,14545,2,13953,114591,1,12219,2,12216,2,12003,2;

// -----------------------------------------------------------
//  Constants (leave this section alone).
// -----------------------------------------------------------

    setarray .Castles$[0],
        "prtg_cas01","prtg_cas02","prtg_cas03","prtg_cas04","prtg_cas05",
        "payg_cas01","payg_cas02","payg_cas03","payg_cas04","payg_cas05",
        "gefg_cas01","gefg_cas02","gefg_cas03","gefg_cas04","gefg_cas05",
        "aldeg_cas01","aldeg_cas02","aldeg_cas03","aldeg_cas04","aldeg_cas05",
        "arug_cas01","arug_cas02","arug_cas03","arug_cas04","arug_cas05",
        "schg_cas01","schg_cas02","schg_cas03","schg_cas04","schg_cas05";
    setarray .EndLabel$[0],"ar01","ar02","ar03","ar04","ar05","sc01","sc02","sc03","sc04","sc05";
    setarray .Days$[0],"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday";
    setarray .Regions$[0],"Prontera","Payon","Geffen","Aldebaran","Arunafeltz","Schwaltzvalt";
    setarray .Map$[0],"prt_gld","pay_gld","gef_fild13","alde_gld","aru_gld","sch_gld";
    setarray .MapX[0],134,240,153,111,208,121,295,317,140,204,214,308,143,193,305,48, 95,142,239,264,158,83, 68,299,292,293,288, 97,137, 71;
    setarray .MapY[0], 65,128,137,240,240,233,116,293,160,266, 75,240,240,278, 87,83,249, 85,242, 90,272,47,155,345,107,100,252,196, 90,315;

// -----------------------------------------------------------

    set .Size, getarraysize($WOE_CONTROL);
    if (.AutoKick || .NoOwner)
        for(set .@i,0; .@i<30; set .@i,.@i+1) {
            setmapflag .Castles$[.@i], mf_loadevent;
            setd "."+.Castles$[.@i], .@i;
        }
    if (!agitcheck() && !agitcheck2()) sleep 4000;
    set .Init,1;

OnMinute00:
    freeloop(1);
    if (agitcheck() || agitcheck2()) {
        for(set .@i,0; .@i<.Size; set .@i,.@i+4)
            if (gettime(4) == $WOE_CONTROL[.@i] && gettime(3) == $WOE_CONTROL[.@i+2]) {
            OnWOEEnd:
                announce "The War Of Emperium is over!",bc_all|bc_woe;
                AgitEnd; AgitEnd2;
                sleep 1000;
                for(set .@j,0; .@j<30; set .@j,.@j+1) {
                    if (.Active[0]&(1<<.@j)) Disp_Owner(.Castles$[.@j],1);
                    if (.ExitWarp) maprespawnguildid .Castles$[.@j],0,3;
                }
                if (.Options&1 && .Active[0] && .ForceEnd != 2) callsub OnReward, .Active[0];
                deletearray .Active[0],2;
                if (.ForceEnd) { set .ForceEnd,0; end; }
                break;
            }
    }
    if ((!agitcheck() && !agitcheck2()) || .Init) {
        if (!agitcheck() && !agitcheck2()) set .Init,0;
        for(set .@i,0; .@i<.Size; set .@i,.@i+4)
            if (gettime(4) == $WOE_CONTROL[.@i] && gettime(3) >= $WOE_CONTROL[.@i+1] && gettime(3) < $WOE_CONTROL[.@i+2]) {
                deletearray .Active[0],2;
                set .Active[0], $WOE_CONTROL[.@i+3];
                if (.Init) { AgitEnd; AgitEnd2; }
                else announce "The War Of Emperium has begun!",bc_all|bc_woe;
                sleep 1000;
                AgitStart; AgitStart2;
                for(set .@j,0; .@j<30; set .@j,.@j+1) {
                    if (.Active[0]&(1<<.@j)) {
                        if (!.Init) Disp_Owner(.Castles$[.@j],0);
                        set .Active[1], .Active[1] | (1<<((.@j/5)+1));
                    } else {
                        if (.@j<20) {
                            donpcevent "Agit#"+.Castles$[.@j]+"::OnAgitEnd";
                            killmonster .Castles$[.@j], "Agit#"+.Castles$[.@j]+"::OnAgitBreak";
                        } else {
                            donpcevent "Manager#"+.Castles$[.@j]+"::OnAgitEnd2";
                            killmonster .Castles$[.@j], "Steward#"+.EndLabel$[.@j-20]+"::OnStartArena";
                        }
                    }
                }
                break;
            }
    }
    set .Init,0;
    end;

function Disp_Owner {
    set .@o, getcastledata(getarg(0),1);
    if (.@o) announce "The ["+getcastlename(getarg(0))+"] castle "+((getarg(1))?"has been conquered":"is currently held")+" by the ["+getguildname(.@o)+"] guild.",bc_all|bc_woe;
    else announce "The ["+getcastlename(getarg(0))+"] castle is currently unoccupied.",bc_all|bc_woe;
    return;
}
function Add_Zero {
    return ((getarg(0)<10)?"0":"")+getarg(0)+(getarg(1,0)?".":":")+"00";
}

OnReward:
    set .@sql$, ((.Options&4)?"position = 0":"online = 1");
    if (.Options&2) set .@str$,gettimestr("%B %d, %Y",21);
    freeloop(1);
    for(set .@i,0; .@i<30; set .@i,.@i+1)
        if (getarg(0)&(1<<.@i)) {
            set .@gid, getcastledata(.Castles$[.@i],1);
            if (!.@gid) continue;
            set .@size, query_sql("SELECT account_id,char_id FROM `guild_member` WHERE guild_id = '"+.@gid+"' AND "+.@sql$,.@aid,.@cid);
            for(set .@j,0; .@j<.@size; set .@j,.@j+1) {
                if (.Options&8 && !(.Options&4)) {
                    set .@ip$, replacestr(getcharip(.@aid[.@j]),".","a");
                    if (getd(".@ip_"+.@i+"_"+.@ip$)) continue;
                    setd ".@ip_"+.@i+"_"+.@ip$,1;
                }
                if (.Options&2) {
                    query_sql("INSERT INTO `mail` (send_name,dest_id,title,message,nameid,amount,identify,zeny,time) VALUES ("+
                              "'no-reply',"+.@cid[.@j]+",'** Siege Reward: "+getcastlename(.Castles$[.@i])+" **',"+
                              "'Brave one,% % Congratulations!% Your guild has successfully occupied% territory in the War of Emperium on% "+.@str$+".% % % % % [ Your reward is attached. ]',"+
                              .Reward[0]+","+.Reward[1]+",0,"+.Reward[2]+",UNIX_TIMESTAMP(NOW()))");
                    if (!getd(".@str_"+.@cid[.@j]) && isloggedin(.@aid[.@j],.@cid[.@j])) {
                        setd ".@str_"+.@cid[.@j],1;
                        message rid2name(.@aid[.@j]),"You've got mail! Please re-login to update your mailing list.";
                    }
                } else if (isloggedin(.@aid[.@j])) {
                    for(set .@k,0; .@k<getarraysize(.Reward); set .@k,.@k+2)
                        getitem .Reward[.@k], .Reward[.@k+1], .@aid[.@j];
                    message rid2name(.@aid[.@j]),"You have been rewarded for conquering "+getcastlename(.Castles$[.@i])+".";
                }
            }
        }
    if (.Options&2) query_sql("UPDATE `mail` SET message = REPLACE(message,'%',CHAR(13)) WHERE send_name = 'no-reply'");
    return;

OnPCLoadMapEvent:
    if (!compare(strcharinfo(3),"g_cas")) end;
    if (((.AutoKick && .Active[0]) || (.NoOwner && !getcastledata(strcharinfo(3),1))) && !(.Active[0]&(1<<getd("."+strcharinfo(3))))) {
        if (getcharid(2) && getcastledata(strcharinfo(3),1) == getcharid(2)) end;
        sleep2 1000;
        message strcharinfo(0), getcastlename(strcharinfo(3))+" is currently inactive.";
        sleep2 5000;
        if (compare(strcharinfo(3),"g_cas")) warp "SavePoint",0,0;
    }
    end;

OnMenu:
while(1) {
    mes "[WOE Information]";
    if (agitcheck() || agitcheck2()) {
        if (.Active[0]) {
            for(set .@i,0; .@i<.Size; set .@i,.@i+4)
                if (gettime(4) == $WOE_CONTROL[.@i] && gettime(3) >= $WOE_CONTROL[.@i+1] && gettime(3) < $WOE_CONTROL[.@i+2]) {
                    set .@i, $WOE_CONTROL[.@i+2];
                    break;
                }
            mes "The War of Emperium is ^0055FFactive^000000 until ^FF0000"+Add_Zero(.@i)+"^000000 in the following regions:";
            mes " ";
            for(set .@i,0; .@i<6; set .@i,.@i+1)
                if (.Active[1]&(1<<(.@i+1))) mes " > ^777777"+.Regions$[.@i]+"^000000";
        } else
            mes "The War of Emperium is ^0055FFactive^000000.";
    } else {
        for(set .@i,0; .@i<.Size; set .@i,.@i+4)
            if ((gettime(4) == $WOE_CONTROL[.@i] && gettime(3) <= $WOE_CONTROL[.@i+1]) || gettime(4) < $WOE_CONTROL[.@i]) {
                setarray .@time[0],$WOE_CONTROL[.@i],$WOE_CONTROL[.@i+1];
                break;
            }
        if (!getarraysize(.@time))
            setarray .@time[0],$WOE_CONTROL[0],$WOE_CONTROL[1];
        mes "The War of Emperium is ^777777inactive^000000.";
        if (.Size) {
            mes " ";
            mes "The next session will begin";
            mes "on ^0055FF"+.Days$[.@time[0]]+"^000000 at "+Add_Zero(.@time[1])+"^000000.";
        }
    }
    next;
    switch(select(""+((.CastleWarp || .Active[1])?" ~ Warp to castles...":"")+": ~ Check schedule...: ~ View castle owners...:"+((getgmlevel()<.GMAccess || !getgmlevel())?"":" ~ Manage sessions...")+": ~ ^777777Cancel^000000")) {
    case 1:
        if (.CastleWarp) set .@clr$,"^0055FF";
        set .@menu$,"";
        for(set .@i,0; .@i<6; set .@i,.@i+1) {
            if (.CastleWarp || .Active[1]&(1<<(.@i+1)))
                set .@menu$, .@menu$+" ~ "+((.Active[1]&(1<<(.@i+1)))?.@clr$:"^777777")+.Regions$[.@i]+" Castles^000000";
            set .@menu$, .@menu$+":";
        }
        set .@i, select(.@menu$)-1;
        set .@menu$,"";
        for(set .@j,.@i*5; .@j<(.@i*5)+5; set .@j,.@j+1) {
            if (.CastleWarp || .Active[0]&(1<<.@j))
                set .@menu$, .@menu$+" ~ "+((.Active[0]&(1<<.@j))?.@clr$:"^777777")+getcastlename(.Castles$[.@j])+"^000000";
            set .@menu$, .@menu$+":";
        }
        set .@j, select(.@menu$)-1;
        warp .Map$[.@i],.MapX[(.@i*5)+.@j],.MapY[(.@i*5)+.@j];
        close;
    case 2:
        mes "[Schedule]";
        if (.Size) {
            freeloop(1);
            for(set .@i,0; .@i<.Size; set .@i,.@i+4) {
                mes "> ^FF0000"+.Days$[$WOE_CONTROL[.@i]]+" ("+Add_Zero($WOE_CONTROL[.@i+1])+"-"+Add_Zero($WOE_CONTROL[.@i+2])+")^000000";
                for(set .@j,0; .@j<30; set .@j,.@j+1)
                    if ($WOE_CONTROL[.@i+3]&(1<<.@j)) mes "  ~ "+getcastlename(.Castles$[.@j])+" ^777777("+.Castles$[.@j]+")^000000";
                if (.@i+4 < .Size) mes " ";
            }
            freeloop(0);
        } else
            mes "No times are configured.";
        next;
        break;
    case 3:
        mes "[Castle Ownership]";
        for(set .@i,0; .@i<6; set .@i,.@i+1) {
            set .@k, .@i*5;
            mes "> ^FF0000"+.Regions$[.@i]+"^000000";
            for(set .@j,.@k; .@j<(.@k+5); set .@j,.@j+1) { 
                set .@t, getcastledata(.Castles$[.@j],1);
                mes "  ~ "+getcastlename(.Castles$[.@j])+": "+((.@t)?"^0055FF"+getguildname(.@t):"^777777unoccupied")+"^000000";
            }
            if (.@i < 5) mes " ";
        }
        next;
        break;
    case 4:
    while(1) {
        mes "[Session Manager]";
        mes "There are ^0055FF"+(.Size/4)+" session(s)^000000 configured.";
        mes "What would you like to do?";
        next;
        switch(select(" ~ Add a session...: ~ Delete a session...: ~ Reload settings...:"+((agitcheck() || agitcheck2())?" ~ End WOE session...":"")+": ~ ^777777Go back^000000")) {
        case 1:
            mes "[New Session]";
            if (.Size > 127) {
                mes "You have already reached the maximum of 32 sessions.";
                next;
                break;
            }
            mes "Select a day.";
            next;
            set .@Day, select(" ~ "+implode(.Days$,": ~ "))-1;
            mes "[New Session]";
            mes "Select a start time for ^0055FF"+.Days$[.@Day]+"^000000.";
            next;
            set .@menu$,"";
            for(set .@i,0; .@i<23; set .@i,.@i+1)
                set .@menu$, .@menu$+" ~ "+Add_Zero(.@i,1)+":";
            set .@Start, select(.@menu$)-1;
            mes "[New Session]";
            mes "Select an end time for ^0055FF"+.Days$[.@Day]+"^000000.";
            next;
            set .@menu$,"";
            for(set .@i,.@Start+1; .@i<24; set.@i,.@i+1)
                set .@menu$, .@menu$+" ~ "+Add_Zero(.@i,1)+":";
            set .@End, select(.@menu$)+.@Start;
            for(set .@i,0; .@i<.Size; set .@i,.@i+4)
                if (.@Day == $WOE_CONTROL[.@i] &&
                   ((.@Start >= $WOE_CONTROL[.@i+1] && .@Start < $WOE_CONTROL[.@i+2]) ||
                    (.@End > $WOE_CONTROL[.@i+1] && .@End <= $WOE_CONTROL[.@i+2]) ||
                    (.@Start <= $WOE_CONTROL[.@i+1] && .@End >= $WOE_CONTROL[.@i+2]))) {
                    mes "[New Session]";
                    mes "The chosen times overlap with an existing session.";
                    next;
                    set .@d,1;
                    break;
                }
            if (.@d) { set .@d,0; break; }
            set .@Castle,0;
            while(1) {
                mes "[New Session]";
                mes "^0055FF"+.Days$[.@Day]+" ("+Add_Zero(.@Start)+"-"+Add_Zero(.@End)+")^000000";
                mes " > Castles:";
                if (!.@Castle)
                    mes "   ~ ^777777(none selected)^000000";
                else for(set .@i,0; .@i<30; set .@i,.@i+1)
                    if (.@Castle&(1<<.@i)) mes "   ~ "+getcastlename(.Castles$[.@i])+" ("+.Castles$[.@i]+")";
                next;
                set .@menu$,((.@Castle)?" ~ ^FF0000Finished...^000000":"")+":";
                for(set .@i,0; .@i<30; set .@i,.@i+1)
                    set .@menu$, .@menu$+" ~ "+((.@Castle&(1<<.@i))?"^0055FF":"")+getcastlename(.Castles$[.@i])+" ("+.Castles$[.@i]+")^000000:";
                set .@i, select(.@menu$)-1;
                if (.@i)
                    set .@Castle, .@Castle^(1<<(.@i-1));
                else {
                    mes "[New Session]";
                    mes "Are you sure?";
                    next;
                    switch(select(" ~ ^0055FFAdd session...^000000: ~ Continue selecting castles...: ~ ^777777Cancel^000000")) {
                    case 1:
                        for(set .@i,0; .@i<.Size; set .@i,.@i+4)
                            if ((.@Day == $WOE_CONTROL[.@i] && .@End <= $WOE_CONTROL[.@i+1]) || .@Day < $WOE_CONTROL[.@i]) {
                                set .@d,1;
                                break;
                            }
                        if (!.@d) { set .@d,1; set .@i,.Size; }
                        copyarray $WOE_CONTROL[.@i+4], $WOE_CONTROL[.@i], .Size-.@i;
                        setarray $WOE_CONTROL[.@i], .@Day, .@Start, .@End, .@Castle;
                        set .Size, getarraysize($WOE_CONTROL);
                    case 3:
                        mes "[New Session]";
                        mes ((.@d)?"Session added.":"Cancelled.");
                        next;
                        set .@d,1;
                    case 2:
                        break;
                    }
                    if (.@d) { set .@d,0; break; }
                }
            }
            break;
        case 2:
            mes "[Remove Session]";
            if (!.Size) {
                mes "There are no sessions configured.";
                next;
                break;
            }
            mes "Select a session to remove.";
            next;
            set .@menu$,"";
            for(set .@i,0; .@i<.Size; set .@i,.@i+4)
                set .@menu$, .@menu$+" ~ "+.Days$[$WOE_CONTROL[.@i]]+" ("+Add_Zero($WOE_CONTROL[.@i+1],1)+"-"+Add_Zero($WOE_CONTROL[.@i+2],1)+"):";
            set .@menu$, .@menu$+" ~ ^777777Cancel^000000";
            set .@i, select(.@menu$)-1;
            if (.@i == (.Size/4)) break;
            mes "[Remove Session]";
            mes "Delete ^0055FF"+.Days$[$WOE_CONTROL[.@i*4]]+"'s^000000 session?";
            mes "This action cannot be undone.";
            next;
            set .@j, select(" ~ ^FF0000Delete session...^000000: ~ ^777777Cancel^000000");
            mes "[Remove Session]";
            if (.@j == 2)
                mes "Cancelled.";
            else {
                deletearray $WOE_CONTROL[.@i*4],4;
                set .Size, getarraysize($WOE_CONTROL);
                mes "Session deleted.";
            }
            next;
            break;
        case 3:
            mes "[Reload Settings]";
            mes "This will trigger all events related to new session configurations, if any.";
            if (agitcheck() || agitcheck2()) {
                mes " ";
                mes "Be aware that this will disrupt the current WOE session.";
            }
            next;
            set .@i, select(" ~ ^0055FFReload settings...^000000: ~ ^777777Cancel^000000");
            mes "[Reload Settings]";
            if (.@i == 2) mes "Cancelled.";
            else {
                set .Init,1;
                donpcevent "WOE_CONTROL::OnMinute00";
                mes "Variables have been re-initialized.";
            }
            next;
            break;
        case 4:
            mes "[Force Agit End]";
            if (!agitcheck() && !agitcheck2())  {
                mes "WOE has already ended.";
                next;
                break;
            }
            mes "This command will safely execute all AgitEnd events.";
            mes " ";
            mes "Kill the current WOE session?";
            next;
            set .@i, select(" ~ ^FF0000End session...^000000:"+((.Options&1)?" ~ ^FF0000End session without rewards...^000000":"")+": ~ ^777777Cancel^000000");
            mes "[Force Agit End]";
            if (.@i == 3)
                mes "Cancelled.";
            else {
                set .ForceEnd, .@i;
                donpcevent "WOE_CONTROL::OnWOEEnd";
                mes "WOE session terminated.";
            }
            next;
            break;
        case 5:
            set .@d,1; break;
        }
        if (.@d) { set .@d,0; break; }
        } break;
    case 5:
        close;
    } }
}

//= Be sure to disable the default agit controllers!

//== npc\guild\agit_controller.txt

//== npc\guild2\agit_start_se.txt

Already been disable...
How can i solve this all????

Please anyone pro about this... /sob

Edited August 2, 2013 by CheckMate

Checkmate · August 2, 2013

I already know how to resolve it...
I try lot of thing.....
Here what i found..

Reason..

My hoster did upgrade the server for me and when he upgrade it the /trunk/npc/mapflag/ was delete.(I dont know why)

So server can't read any of mapflag cuz the main file was delete.
Then i put it back and see if i can hit emperium and yes,I can hit emperium

But another error coming out...

[Error]: npc_parsesrcfile: File not found 'npc/re/guild/invest_main.txt'.

[Error]: npc_parsesrcfile: File not found 'npc/re/guild/invest_npc.txt'.

This error was not here before i put back /trunk/npc/mapflag/...

Now i wonder what is that error mean?..?

I try look here
https://rathena.svn.sourceforge.net/svnroot/rathena/trunk/npc/re/guild/

It was look like i must choose one from them and cannot both....
I thing this was bug cuz i read somthing inside that script said
about Expansion for War of Emperium FE.

I dont know if this was updater wrong...(Sry bad english)

**I will take look deep more about this cuz i never meet this problem b4**

Thanks To Both Of You Guys

Sir Emistry +1
&
Sir Evelynn +1

Edited August 2, 2013 by CheckMate

Evelynn · August 2, 2013

Are you maybe perhaps allied to the guild aw ?

Alliance prevents you from attacking their Emperium...

If not, try using a different character other than your main ( GM ) character to see if you are able to kill the Emperium.

Also try using @killmonster or @killmonster2 to test and see if the Emperium is actually there or not.

I can't exactly tell you what's wrong because I didn't read the script you posted lol ( It's too long ): ).

But lets see if my assumptions can be correct

Edited August 2, 2013 by Evelynn

Checkmate · August 2, 2013

Are you maybe perhaps allied to the guild aw ?

Nope.. Already tried another character that not alliend with aw guild = result = SAME

Also try using @killmonster or @killmonster2 to test and see if the Emperium is actually there or not.

Already tried also with admin cmd... The emperium still there and spinning ^ ^ /hmm

I can't exactly tell you what's wrong because I didn't read the script you posted lol ( It's too long ): ).

Actually for the script,i did not touch anything except reward only...

Help me on other ways please.. Im out of idea right now... /sob /sob /sob

Evelynn · August 2, 2013

Hmm I am unsure if Emperium will die with the admin command or not, I forgot...

Did you set the mapflag of the map to be a gvg / castle?

Does the Emperium go away after @agitend ( End of WoE ) ? or does it remain there?

Checkmate · August 2, 2013

Did you set the mapflag of the map to be a gvg / castle?

Nope sir... I did not touch anything about mapflag...

Does the Emperium go away after @agitend ( End of WoE ) ? or does it remain there?

The emperium was disapear when i use cmd @agitend and when im using @agitstart it was there again...

Anyone... Thanks to Evelynn cuz willing to help even though she did not know...

Anyone...

@Sir Capuche

@Sir Euphy

@Sir Emistry

Help /hmm /hmm /hmm

Evelynn · August 2, 2013

Well that answers that question.

For certain WoE is enabled in that castle if agitend spawns it while agitend disables it... and Emperium does not die upon admin command.

Before implementing ( Editing the rewards )

Did you reloadscript / restart your server?

Have you tried taking any other castle than the current one you've shown in your screenshot?

Checkmate · August 2, 2013

Before implementing ( Editing the rewards )

Did you reloadscript / restart your server?

Nope... Before editing the rewards it ok..

After editing rewards and im just use @reloadscript only..

Did not restart server.

Have you tried taking any other castle than the current one you've shown in your screenshot?

Yap... And the result is the same...

Can we detect this error using putty??

**Btw i wondering,can all WOE be online or activated at the same time in the same map??**

Edited August 2, 2013 by CheckMate

Evelynn · August 2, 2013

Try restarting your server, it may be one of the best solutions to everything x:. Always try that if nothing else works, especially if it's just a test server.

Secondly, mind if I ask you to place your script inside a codebox so that I won't have to use too much effort scrolling down ? ):

( Edit your first post and put the long script inside a codebox instead of a quote so that it doesn't take up the whole page... )

EDIT

Please let us know if your issue is solved ):

Thanks changing it into a codebox (:.

Edited August 2, 2013 by Evelynn

Emistry · August 2, 2013

did you removed the original mapflags applied on that map ?? like..gvg...castle...etc ??

you can use @mapinfo to check the mapflags..

Checkmate · August 2, 2013

Sorry sir Euphy and Sir Evelynn..

Late reply..

Try restarting your server, it may be one of the best solutions to everything x:. Always try that if nothing else works, especially if it's just a test server.

Already restart it for 3 time... but the thing is the same... =="

Actually....

After sir Emisrtry said that,i remember that this evening lately i use @mapflag nosave,and 3 more cmd i cant rememebr on map quiz_01 map.
It this cmd will make all map in ragnarok happen the same?..?

How to solve all this sir?..

How to roll back all again cuz i did not make some backup..
And where can i change it back to normal... ??..??

**Edit**
Here are the screen shot one one of payon WOE map that error while hitting emperium during WOE

The mapflag are there but i still cannot hit it...

**Another Edit***

gvg
The gvg mapflags set the Guild vs. Guild mode on the specified map. All guilds will appear with their icon over the head and will be able to attack other guilds. WoE damage reduction calculations will be taken into consideration.

gvg_castle
Defines a guild castle
On guild castle maps, GVG is only on when WoE is active

I read this thing on

http://rathena.org/wiki/Mapflag

and trying to put cmd @mapflag gvg_castle on map WOE and i can attack those emperium but i seem to show damage done by 1.
And i did search and make compare that
/trunk/conf/mapflag
does't contain

gvg_castle.txt

and only contain gvg.txt...

So what did i do now... Im lost.....
Im using rAthena Version SVN r17424

Edited August 2, 2013 by CheckMate

Evelynn · August 2, 2013

I stated for you to try restarting your server since you said you didn't before .

I found another mapflag folder inside your NPC folder...

npc/mapflag/gvg.txt

This is where the gvg_castle mapflag is located for each individual castle.

Try to check and see if the map 'pay_gcas02' has the mapflag in that text document.

Hopefully this is the problem. Good luck!

Evelynn · August 2, 2013

It seems like your service provider somehow deleted some of your files.

Basicly the error is saying that you do NOT have those files inside the folder npc/re/guild.

Did you try downloading them both and placing them inside your npc/re/guild folder?

-EDIT

Looks like it was resolved (:

Edited August 2, 2013 by Evelynn

Checkmate · August 2, 2013

Yeahh.. Mybe he was wrongly delete files...
Then i supposed to have this headache.. =="
Im afraid if im putting this other error will came out....
But i will try to make backup first ^^

Again thanks cuz helping me out... ^ ^

Sign In

WOE Error

Question

Link to comment

Share on other sites

13 answers to this question

Recommended Posts

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Link to comment

Share on other sites

Join the conversation

Recently Browsing 0 members