Requesting Gold Room open every 2 min

[MelMel]

Hi Rathena,

 

I would like to request for a gold room that work like this:

 

A Gold room that will open every 2 min.

Before gold room are open monster for ex: marin will be spawn.

and 1 sec just before the gold room announce that the gold room are open all the marin will be killed living the gold on the ground.

and no marin will be spawn by then.

the player then are able to enter the gold room and start picking up the gold.

after 2min the everyone will be kick out of the gold room and the map will be clean.

 

if possible i would like to have a timer to show when they will be kick out or maybe how long have the gold room being run.

 

thanks in advance

Edited May 8, 2013 by MelMel

[Capuche]

prontera,155,156,5	script	sdfsds	87,{

	if ( !.open ) end;
	mes "Would you like to go to the gold room ?";
	if ( select( "Yes", "No" ) -1 ) close;
	close2;
	warp .event_map$,0,0;
	showdigit -( getnpctimer(0)/1000 ),1;
	sleep2( 120000 -getnpctimer(0) );
	showdigit 120;
	end;

OnTimer120000:	// 120 000 ms = 2 mins
	stopnpctimer;
	.open = 0;
	mapwarp .event_map$, "prontera",150,150;
	cleanmap .event_map$;
	delwaitingroom;
	waitingroom "Gold Room Closed",0;

OnLoop:
	sleep 120000;
	delwaitingroom;
	waitingroom "Gold Room Opened",0;
	for ( .@i = 0; .@i < .amount_gold; .@i++ ) {
		do {
			.@x = rand( 50,200 );
			.@y = rand( 50,200 );
		}
		while( !checkcell( .event_map$,.@x,.@y,cell_chkpass ) );
		makeitem 969, 1, .event_map$, .@x, .@y;
	}
	initnpctimer;
	.open = 1;
	end;

OnInit:
	.amount_gold = 150;
	.event_map$ = "geffen";
	
	donpcevent strnpcinfo(3) +"::OnLoop";
	setarray .@mapflag, mf_nowarp, mf_nowarpto, mf_noteleport;
	for( ; .@i < getarraysize( .@mapflag ); .@i++ )
		setmapflag .event_map$, .@mapflag[.@i];
	waitingroom "Gold Room Closed",0;
	end;
}

A Gold room that will open every 2 min.

...

after 2min the everyone will be kick out of the gold room and the map will be clean.

I supposed you mean there are 2 mins of delay before re-opening

[MelMel]

Yup I want it to reopen every 2min at the same time player inside the gold room cannonly collect those gold for 1min and they will be kick out and will be waiting for it to reopen. Also there will be no monster inside just gold the whole floor for then to pick up.

Thank you