Guild vs Guild

[brunoshp]

i use this AnnieRuru script's  :http://www.eathena.ws/board/index.php?showtopic=271291&st=0&p=1491475entry1491475

 

The reward will be given to all guild members only members particped Event

AnnieRuru can help?

Edited May 3, 2013 by brunoshp

[Capuche]

Try this

-	script	KoE	-1,{
OnInit:
	disablenpc "The King#KoE";
	sleep 1;
	disablenpc "gefg02-1";
	disablenpc "gefg01-1";
	end;

OnWhisperGlobal:
	if ( getgmlevel() < 99 ) end;
	else if ( compare ( @whispervar0$, "on" ) ) goto L_start;
	else if ( compare ( @whispervar0$, "off" ) ) goto L_end;
	else end;
		
L_end:
OnClock1800:
	announce "The King of Emperium Hill is over!", 0;
	set .koe_start, 0;
	disablenpc "The King#KoE";
	killmonsterall "gefg_cas01";
	donpcevent "Reward#KoE::Onresetreward";
	end;

L_start:
OnClock1700:
	donpcevent "The King#KoE::OnReset";
	announce "The King of Emperium Hill has begun!", 0;
	set .koe_start, 1;
	enablenpc "The King#KoE";
	disablenpc "Reward#KoE";
	set $koegid, 0;
	donpcevent "::OnRevKoE";
	maprespawnguildid "gefg_cas01", $koegid, 6;
	monster "gefg_cas01",197,182,"EMPERIUM",1288,1,"KoE::OnEmpDead";
	end;

OnEmpDead:
	set $koegid, getcharid(2);
	announce "The current King of Emperium Hill is the [" + strcharinfo(2) + "] guild.", 0;
	donpcevent "::OnRevKoE";
	maprespawnguildid "gefg_cas01", $koegid, 6;
	sleep 500;
	if ( .koe_start )
		monster "gefg_cas01",197,182,"EMPERIUM",1288,1,"KoE::OnEmpDead";
	end;
}

// KoE Entrance
prontera,155,191,4	script	The King#KoE	58,{
    mes "[The King]";
	if ( getcharid(2) == 0 ) {
		mes "You must have a guild to participate in the ^FF0000King of Emperium Hill Tournament^000000.";
		close;
	}
    mes "Hello.";
    mes "Would you like to participate in the ^FF0000King of Emperium Hill Tournament^000000?";
	if ( select ( "Yes", "No" ) == 2 ) close;
	warp "z_agit",168,17;
	while( .@i < .size_koe ) set .@i, .@i +1;
	if( .@i != .size_koe ) {
		set .koe_register[ .size_koe ], getcharid(0);
		set .size_koe, .size_koe +1;
	}
	end;
OnReset:
	deletearray .koe_register;
	set .size_koe, 0;
	end;
OnPCLogoutEvent:
	while( .@i < .size_koe ) set .@i, .@i +1;
	if( .@i == .size_koe ) end;
	deletearray .koe_register[.@i], 1;
	set .size_koe, .size_koe -1;
	end;
}

// KoE Reward
prontera,151,191,5	script	Reward#KoE	51,{
	mes "[Reward]";
	if ( getvariableofnpc( .koe_start, "KoE" ) ) {
		mes "King of Emperium Hill event is currently running";
		close;
	}
	if ( getcharid(2) == $koegid ) {
		set .@size, getarraysize(.koe_prize);
		for ( set .@i, 0; .@i < .@size; set .@i, .@i +1 ) {
			if ( .koe_prize[.@i] == getcharid(0) ) {
				mes "You already received the rewards";
				close;
			}
		}
		set .@size, getvariableofnpc( .size_koe,"The King#KoE" );
		for ( set .@i, 0; .@i < .@size; set .@i, .@i +1 )
			if( getvariableofnpc( .koe_register[.@i],"The King#KoE" ) == getcharid(0) ) break;
		if( .@i == .@size ) {
			mes "Not register, no prize.";
			close;
		}
		mes "Congratulation on becoming the winner of ^FF0000King of Emperium Hill Tournament^000000";
		getitem 501, 1; // configure prize here

		set .koe_prize[ getarraysize(.koe_prize) ], getcharid(0);
	}
	else {
		mes "Your guild is not the winner of King of Emperium Hill event";
	}
	close;
Onresetreward:
	deletearray .koe_prize;
	end;
}


gefg_cas01,28,157,4	script	King of Emperium Hill#1::custom_koe_flag	722,{
	set .@gid, $koegid;
	if ( .@gid == 0 ) end;
	mes "[King of Emperium Hill]";
	mes "The Current King of Emperium Hill is the ["+ getguildname(.@gid) +"] guild.";
	close;
OnRevKoE:
	flagemblem $koegid;
	end;
}
gefg_cas01,22,156,5	duplicate(custom_koe_flag)	King of Emperium Hill#2	722
gefg_cas01,68,185,3	duplicate(custom_koe_flag)	King of Emperium Hill#3	722
gefg_cas01,17,171,5	duplicate(custom_koe_flag)	King of Emperium Hill#4	722
gefg_cas01,59,16,4	duplicate(custom_koe_flag)	King of Emperium Hill#5	722
gefg_cas01,64,16,4	duplicate(custom_koe_flag)	King of Emperium Hill#6	722

gefg_cas01	mapflag	gvg
gefg_cas01	mapflag	nobranch
gefg_cas01	mapflag	nomemo
gefg_cas01	mapflag	nopenalty
gefg_cas01	mapflag	noreturn
gefg_cas01	mapflag	nosave	SavePoint
gefg_cas01	mapflag	noteleport
gefg_cas01	mapflag	gvg_noparty
gefg_cas01	mapflag	nowarp
gefg_cas01	mapflag	nowarpto

z_agit	mapflag	gvg
z_agit	mapflag	nobranch
z_agit	mapflag	nomemo
z_agit	mapflag	nopenalty
z_agit	mapflag	noreturn
z_agit	mapflag	nosave	SavePoint
z_agit	mapflag	noteleport
z_agit	mapflag	gvg_noparty
z_agit	mapflag	nowarp
z_agit	mapflag	nowarpto

z_agit,168,179,0	warp	#to_gef_castle	1,1,gefg_cas01,99,178

[brunoshp]

but leader use rally and player not talk to npc?

[Capuche]

but leader use rally and player not talk to npc?

The guild members must talk to the npc to gain something at the end of the event.

 

You mean if the leader use @guildrecall ? the member which doesn't talk to the npc gained nothing