My Script got Warning after Update SVN

[LearningRO]

Sir My script Got message like this

[Warning]: Incorrect use of 'close' command! (source:Warper#50 / path:npc/custom /***/Warper.txt)

//===== eAthena Script ======================================= 
//= Euphy's Warper
//===== By: ================================================== 
//= Euphy
//===== Current Version: =====================================
//= 1.2
//===== Description: ========================================= 
//= A complete - but very condensed - warper script.
//= Coordinates written largely by Tekno-Kanix and ToastOfDoom.
//============================================================

-	script	Warper	-1,{
function Go; function Disp; function Pick;

// --------------------------------------------------
//	Main Menu:
// --------------------------------------------------

menu	"Last Warp ^777777["+lastwarp$+"]^000000",-,
	" ~ Towns",Towns, " ~ Fields",Fields, " ~ Dungeons",Dungeons,
	" ~ Guild Castles",Castles, " ~ Special Areas",Special;

	if (lastwarp$ == "") dispbottom "You have not warped anywhere yet.";
		else warp lastwarp$,lastwarpx,lastwarpy;
	end;

// ------------------- Functions -------------------
// * Go("<map>",<x>,<y>);
//	~ Warps directly to a map.
// * Disp("<Menu Option>",<first option>,<last option>);
// * Pick("<map_prefix>"{,<index offset>});
//	~ Dynamic menu and map selection.
// * Disp("","<Option 1>:<Option 2>:<etc.>");
// * Pick("","<map1>","<map2>","<etc.>");
//	~ Manual menu and map selection.
//
// Other notes:
//   ~ Array @c[] holds all (x,y) coordinates.
//   ~ Use @c[2] EXCEPT when maps begin dynamically
//	  at 0: use @c[0] and Pick() offset 1.
// --------------------------------------------------

function Go {
	warp getarg(0),getarg(1,0),getarg(2,0);
	getmapxy(lastwarp$,lastwarpx,lastwarpy,0);
	end; }
function Disp {
	set @menu$,"";
	if(getarg(0)=="") {
		set @menu$,getarg(1);
		return; }
	for(set .@i,getarg(1); .@i<=getarg(2); set .@i,.@i+1)
		set @menu$, @menu$+getarg(0)+" "+.@i+":";
	return; }
function Pick {
	if(getarg(0)=="") {
		set .@i, select(@menu$);
		warp getarg(.@i),@c[.@i*2],@c[.@i*2+1]; }
	else {
		set .@i, select(@menu$)-getarg(1,0);
		warp getarg(0)+((.@i<10)?"0":"")+.@i,@c[.@i*2],@c[.@i*2+1]; }
	getmapxy(lastwarp$,lastwarpx,lastwarpy,0);
	end; }

// --------------------------------------------------
	Towns:
// --------------------------------------------------
menu	"Prontera",T1, "Alberta",T2, "Aldebaran",T3, "Amatsu",T4, "Ayothaya",T5,
	"Brasilis",T6, "Comodo",T7, "Dewata",T33, "Eclage",T34, "Einbech",T8, 
	"Einbroch",T9, "El Dicastes",T10, "Geffen",T11, "Gonryun",T12, "Hugel",T13,
	"Izlude",T14, "Jawaii",T15, "Lighthalzen",T16, "Louyang",T17, "Lutie",T18,
	"Malangdo",T35, "Malaya",T36, "Manuk",T19, "Midgarts Expedition Camp",T20,
	"Mora",T21, "Morroc",T22, "Moscovia",T23, "Nameless Island",T24,
	"Niflheim",T25, "Payon",T26, "Rachel",T27, "Splendide",T28, "Thor Camp",T29,
	"Umbala",T30, "Veins",T31, "Yuno",T32;

T1: Go("prontera",155,183);
T2: Go("alberta",28,234);
T3: Go("aldebaran",140,131);
T4: Go("amatsu",198,84);
T5: Go("ayothaya",208,166);
T6: Go("brasilis",195,220);
T7: Go("comodo",209,143);
T8: Go("einbech",138,243);
T9: Go("einbroch",64,200);
T10: Go("dicastes01",197,187);
T11: Go("geffen",120,68);
T12: Go("gonryun",160,121);
T13: Go("hugel",96,145);
T14: Go("izlude",128,114);
T15: Go("jawaii",213,230);
T16: Go("lighthalzen",158,92);
T17: Go("louyang",217,100);
T18: Go("xmas",147,134);
T19: Go("manuk",260,175);
T20: Go("mid_camp",210,288);
T21: Go("mora",111,97);
T22: Go("morocc",156,93);
T23: Go("moscovia",219,193);
T24: Go("nameless_n",256,215);
T25: Go("niflheim",202,174);
T26: Go("payon",179,100);
T27: Go("rachel",130,111);
T28: Go("splendide",200,153);
T29: Go("thor_camp",246,68);
T30: Go("umbala",127,128);
T31: Go("veins",216,123);
T32: Go("yuno",157,51);
T33: Go("dewata",199,179);
T34: Go("eclage",111,39);
T35: Go("malangdo",224,184);
T36: Go("malaya",212,206);

// --------------------------------------------------
	Fields:
// --------------------------------------------------
menu	"Amatsu Fields",F1, "Ayothaya Fields",F2, "Bifrost Fields", F3,
	"Brasilis Fields",F4, "Comodo Fields",F5, "Dewata Fields",F26,
	"Eclage Fields",F27, "Einbroch Fields",F6, "El Dicastes Fields",F7,
	"Geffen Fields",F8, "Gonryun Fields",F9, "Hugel Fields",F10,
	"Lighthalzen Fields",F11, "Louyang Field",F12, "Lutie Field",F13,
	"Malaya Fields",F28, "Manuk Fields",F14, "Mjolnir Fields",F15,
	"Moscovia Fields",F16, "Niflheim Fields",F17, "Payon Forests",F18,
	"Prontera Fields",F19, "Rachel Fields",F20, "Sograt Deserts",F21,
	"Splendide Fields",F22, "Umbala Fields",F23, "Veins Fields",F24,
	"Yuno Fields",F25;

F1: setarray @c[2],190,197;
	Disp("Amatsu Field",1,1); Pick("ama_fild");
F2: setarray @c[2],173,134,212,150;
	Disp("Ayothaya Field",1,2); Pick("ayo_fild");
F3: setarray @c[2],193,220,220,187;
	Disp("Bifrost Field",1,2); Pick("bif_fild");
F4: setarray @c[2],74,32;
	Disp("Brasilis Field",1,1); Pick("bra_fild");
F5: setarray @c[2],180,178,231,160,191,172,228,194,224,203,190,223,234,177,194,175,172,172;
	Disp("Comodo Field",1,9); Pick("cmd_fild");
F6: setarray @c[2],142,225,182,141,187,228,185,173,216,173,195,148,272,220,173,214,207,174,196,200;
	Disp("Einbroch Field",1,10); Pick("ein_fild");
F7: setarray @c[2],143,132,143,217;
	Disp("El Dicastes Field",1,2); Pick("dic_fild");
F8: setarray @c[0],46,199,213,204,195,212,257,192,188,171,166,263,248,158,195,191,186,183,221,117,178,218,136,328,240,181,235,235,211,185;
	Disp("Geffen Field",0,14); Pick("gef_fild",1);
F9: setarray @c[2],220,227;
	Disp("Gonryun Field",1,1); Pick("gon_fild");
F10: setarray @c[2],268,101,222,193,232,185,252,189,196,106,216,220,227,197;
	Disp("Hugel Field",1,7); Pick("hu_fild");
F11: setarray @c[2],240,179,185,235,240,226;
	Disp("Lighthalzen Field",1,3); Pick("lhz_fild");
F12: setarray @c[2],229,187;
	Disp("Louyang Field",1,1); Pick("lou_fild");
F13: setarray @c[2],115,145;
	Disp("Lutie Field",1,1); Pick("xmas_fild");
F14: setarray @c[2],35,236,35,262,84,365;
	Disp("Manuk Field",1,3); Pick("man_fild");
F15: setarray @c[2],204,120,175,193,208,213,179,180,181,240,195,270,235,202,188,215,205,144,245,223,180,206,196,208;
	Disp("Mjolnir Field",1,12); Pick("mjolnir_");
F16: setarray @c[2],82,104,131,147;
	Disp("Moscovia Field",1,2); Pick("mosk_fild");
F17: setarray @c[2],215,229,167,234;
	Disp("Niflheim Field",1,2); Pick("nif_fild");
F18: setarray @c[2],158,206,151,219,205,148,186,247,134,204,193,235,200,177,137,189,201,224,160,205,194,150;
	Disp("Payon Forest",1,11); Pick("pay_fild");
F19: setarray @c[0],208,227,190,206,240,206,190,143,307,252,239,213,185,188,193,194,187,218,210,183,195,149,198,164;
	Disp("Prontera Field",0,11); Pick("prt_fild",1);
F20: setarray @c[2],192,162,235,166,202,206,202,208,225,202,202,214,263,196,217,201,87,121,277,181,221,185,175,200,174,197;
	Disp("Rachel Field",1,13); Pick("ra_fild");
F21: setarray @c[2],219,205,177,206,194,182,184,217,203,213,213,208,224,170,229,177,195,198,209,168,198,216,156,187,185,263,209,219,223,188,206,228,208,238,209,223,85,97,207,202,31,195,38,195;
	Disp("Sograt Desert",1,22); Pick("moc_fild");
F22: setarray @c[2],175,186,236,184,188,204;
	Disp("Splendide Field",1,3); Pick("spl_fild");
F23: setarray @c[2],217,206,223,221,237,215,202,197;
	Disp("Umbala Field",1,4); Pick("um_fild");
F24: setarray @c[2],186,175,196,370,222,45,51,250,202,324,150,223,149,307;
	Disp("Veins Field",1,7); Pick("ve_fild");
F25: setarray @c[2],189,224,192,207,221,157,226,199,223,177,187,232,231,174,196,203,183,214,200,124,195,226,210,304;
	Disp("Yuno Field",1,12); Pick("yuno_fild");
F26: setarray @c[2],371,212;
	Disp("Dewata Field",1,1); Pick("dew_fild");
F27: setarray @c[2],97,314;
	Disp("Eclage Field",1,1); Pick("ecl_fild");
F28: setarray @c[2],40,272,207,180;
	Disp("Malaya Field",1,2); Pick("ma_fild");

// --------------------------------------------------
	Dungeons:
// --------------------------------------------------
menu	"Abyss Lakes",D1, "Amatsu Dungeon",D2, "Anthell",D3,
	"Ayothaya Dungeon",D4, "Beach Dungeon",D5, "Bio Labs",D6,
	"Brasilis Dungeon",D7, "Byalan Dungeon",D8, "Clock Tower",D9,
	"Coal Mines",D10, "Culvert",D11, "Cursed Abbey",D12, "Dewata Dungeon",D41,
	"Einbroch Dungeon",D13, "Endless Tower",D14, "Gefenia",D15,
	"Geffen Dungeon",D16, "Glast Heim",D17, "Gonryun Dungeon",D18,
	"Hidden Dungeon",D19, "Ice Dungeon",D20,
	"Juperos",D21, "Kiel Dungeon",D22, "Louyang Dungeon",D23,
	"Magma Dungeon",D24, "Malangdo Dungeon",D42, "Moscovia Dungeon",D25,
	"Nidhogg's Dungeon",D26, "Odin Temple",D27, "Orc Dungeon",D28, "Payon Dungeon",D29,
	"Pyramids",D30, "Rachel Sanctuary",D31, "Scaraba Hole",D32, "Sealed Shrine",D33,
	"Sphinx",D34, "Sunken Ship",D35, "Thanatos Tower",D36, "Thor Volcano",D37,
	"Toy Factory",D38, "Turtle Dungeon",D39, "Umbala Dungeon",D40;

D1: setarray @c[2],261,272,275,270,116,27;
	Disp("Abyss Lakes",1,3); Pick("abyss_");
D2: setarray @c[2],228,11,34,41,119,14;
	Disp("Amatsu Dungeon",1,3); Pick("ama_dun");
D3: setarray @c[2],35,262,168,170;
	Disp("Anthell",1,2); Pick("anthell");
D4: setarray @c[2],275,19,24,26;
	Disp("","Ancient Shrine Maze:Inside Ancient Shrine"); Pick("ayo_dun");
D5: setarray @c[2],266,67,255,244,23,260;
	Disp("Beach Dungeon",1,3); Pick("","beach_dun","beach_dun2","beach_dun3");
D6: setarray @c[2],150,288,150,18,140,134,245,58;
	Disp("Bio Lab",1,4); Pick("lhz_dun");
D7: setarray @c[2],87,47,262,262;
	Disp("Brasilis Dungeon",1,2); Pick("bra_dun");
D8: setarray @c[0],168,168,253,252,236,204,32,63,26,27,141,187;
	Disp("Byalan Dungeon",1,6); Pick("iz_dun",1);
D9: setarray @c[2],199,159,148,283,65,147,56,155,297,25,127,169,277,178,268,74;
	Disp("","Clock Tower 1:Clock Tower 2:Clock Tower 3:Clock Tower 4:Basement 1:Basement 2:Basement 3:Basement 4");
	Pick("","c_tower1","c_tower2","c_tower3","c_tower4","alde_dun01","alde_dun02","alde_dun03","alde_dun04");
D10: setarray @c[2],52,17,381,343,302,262;
	Disp("Coal Mines",1,3); Pick("mjo_dun");
D11: setarray @c[2],131,247,19,19,180,169,100,92;
	Disp("Culvert",1,4); Pick("","prt_sewb1","prt_sewb2","prt_sewb3","prt_sewb4");
D12: setarray @c[2],51,14,150,11,120,10;
	Disp("Cursed Abbey",1,3); Pick("abbey");
D13: setarray @c[2],22,14,292,290;
	Disp("Einbroch Dungeon",1,2); Pick("ein_dun");
D14: setarray @c[2],72,112;
	Disp("","Misty Island"); Pick("","e_tower");
D15: setarray @c[2],40,103,203,34,266,168,130,272;
	Disp("Gefenia",1,4); Pick("gefenia",0);
D16: setarray @c[0],104,99,115,236,106,132,203,200;
	Disp("Geffen Dungeon",1,4); Pick("gef_dun",1);
D17: setarray @c[2],375,304,199,29,104,25,150,15,157,287,147,15,258,255,108,291,171,283,68,277,156,7,12,7,133,271,224,274,14,70,150,14;
	Disp("","Entrance:Castle 1:Castle 2:Chivalry 1:Chivalry 2:Churchyard:Culvert 1:Culvert 2:Culvert 3:Culvert 4:St. Abbey:Staircase Dungeon:Underground Cave 1:Underground Cave 2:Underground Prison 1:Underground Prison 2");
	Pick("","glast_01","gl_cas01","gl_cas02","gl_knt01","gl_knt02","gl_chyard","gl_sew01","gl_sew02","gl_sew03","gl_sew04","gl_church","gl_step","gl_dun01","gl_dun02","gl_prison","gl_prison1");
D18: setarray @c[2],153,53,28,113,68,16;
	Disp("Gonryun Dungeon",1,3); Pick("gon_dun");
D19: setarray @c[2],176,7,93,20,23,8;
	Disp("Hidden Dungeon",1,3); Pick("prt_maze");
D20: setarray @c[2],157,14,151,155,149,22,33,158;
	Disp("Ice Dungeon",1,4); Pick("ice_dun");
D21: setarray @c[2],140,51,53,247,37,63,150,285;
	Disp("","Entrance:Juperos 1:Juperos 2:Core");
	Pick("","jupe_cave","juperos_01","juperos_02","jupe_core");
D22: setarray @c[2],28,226,41,198;
	Disp("Kiel Dungeon",1,2); Pick("kh_dun");
D23: setarray @c[2],218,196,282,20,165,38;
	Disp("","The Royal Tomb:Inside the Royal Tomb:Suei Long Gon"); Pick("lou_dun");
D24: setarray @c[2],126,68,47,30;
	Disp("Magma Dungeon",1,2); Pick("mag_dun");
D25: setarray @c[2],189,48,165,30,32,135;
	Disp("Moscovia Dungeon",1,3); Pick("mosk_dun");
D26: setarray @c[2],61,239,60,271;
	Disp("Nidhogg's Dungeon",1,2); Pick("nyd_dun");
D27: setarray @c[2],298,167,224,149,266,280;
	Disp("Odin Temple",1,3); Pick("odin_tem");
D28: setarray @c[2],32,170,21,185;
	Disp("Orc Dungeon",1,2); Pick("orcsdun");
D29: setarray @c[0],21,183,19,33,19,63,155,159,201,204;
	Disp("Payon Dungeon",1,5); Pick("pay_dun",1);
D30: setarray @c[2],192,9,10,192,100,92,181,11,94,96,192,8;
	Disp("","Pyramids 1:Pyramids 2:Pyramids 3:Pyramids 4:Basement 1:Basement 2"); Pick("moc_pryd");
D31: setarray @c[2],140,11,32,21,4,149,204,218,150,9;
	Disp("Rachel Sanctuary",1,5); Pick("ra_san");
D32: setarray @c[2],364,44,101,141;
	Disp("Scaraba Hole",1,2); Pick("dic_dun");
D33: setarray @c[2],306,143;
	Disp("","Friar Patrick"); Pick("","monk_test");
D34: setarray @c[2],288,9,149,81,210,54,10,222,100,99;
	Disp("Sphinx",1,5); Pick("","in_sphinx1","in_sphinx2","in_sphinx3","in_sphinx4","in_sphinx5");
D35: setarray @c[2],69,24,102,27;
	Disp("Sunken Ship",1,2); Pick("treasure");
D36: setarray @c[2],150,39,150,136,220,158,59,143,62,11,89,221,35,166,93,148,29,107,159,138,19,20,130,52;
	Disp("Thanatos Tower",1,12); Pick("tha_t");
D37: setarray @c[2],21,228,75,205,34,272;
	Disp("Thor Volcano",1,3); Pick("thor_v");
D38: setarray @c[2],205,15,129,133;
	Disp("Toy Factory",1,2); Pick("xmas_dun");
D39: setarray @c[2],154,49,148,261,132,189,100,192;
	Disp("","Entrance:Turtle Dungeon 1:Turtle Dungeon 2:Turtle Dungeon 3"); Pick("tur_dun");
D40: setarray @c[2],42,31,48,30,204,78;
	Disp("","Carpenter's Shop in the Tree:Passage to a Foreign World:Hvergermil's Fountain");
	Pick("","um_dun01","um_dun02","yggdrasil01");
D41: setarray @c[2],285,160,299,29;
	Disp("Dewata Dungeon",1,2); Pick("dew_dun");
D42: setarray @c[2],33,230;
	Disp("Malangdo Dungeon",1,1); Pick("mal_dun");


// --------------------------------------------------
	Castles:
// --------------------------------------------------
menu	"Aldebaran Castles",C1, "Geffen Castles",C2, "Payon Castles",C3,
	"Prontera Castles",C4, "Arunafeltz Castles",C5, "Schwaltzvalt Castles",C6;

C1: setarray @c[2],48,83,95,249,142,85,239,242,264,90;
	Disp("","Neuschwanstein:Hohenschwangau:Nuenberg:Wuerzburg:Rothenburg");
	Pick("","alde_gld","alde_gld","alde_gld","alde_gld","alde_gld");
C2: setarray @c[2],214,75,308,240,143,240,193,278,305,87;
	Disp("","Repherion:Eeyolbriggar:Yesnelph:Bergel:Mersetzdeitz");
	Pick("","gef_fild13","gef_fild13","gef_fild13","gef_fild13","gef_fild13");
C3: setarray @c[2],121,233,295,116,317,293,140,160,204,266;
	Disp("","Bright Arbor:Scarlet Palace:Holy Shadow:Sacred Altar:Bamboo Grove Hill");
	Pick("","pay_gld","pay_gld","pay_gld","pay_gld","pay_gld");
C4: setarray @c[2],134,65,240,128,153,137,111,240,208,240;
	Disp("","Kriemhild:Swanhild:Fadhgridh:Skoegul:Gondul");
	Pick("","prt_gld","prt_gld","prt_gld","prt_gld","prt_gld");
C5: setarray @c[2],158,272,83,47,68,155,299,345,292,107;
	Disp("","Mardol:Cyr:Horn:Gefn:Banadis");
	Pick("","aru_gld","aru_gld","aru_gld","aru_gld","aru_gld");
C6: setarray @c[2],293,100,288,252,97,196,137,90,71,315;
	Disp("","Himinn:Andlangr:Viblainn:Hljod:Skidbladnir");
	Pick("","sch_gld","sch_gld","sch_gld","sch_gld","sch_gld");

// --------------------------------------------------
	Special:
// --------------------------------------------------
menu	"Auction Hall",S1, "Battlegrounds",S2, "Casino",S3, "Gonryun Arena",S4,
	"Vending Area",S5, "Turbo Track",S6;

S1: Go("auction_01",22,68);
S2: Go("bat_room",154,150);
S3: Go("cmd_in02",179,129);
S4: Go("gon_test",48,10);
S5: Go("payon",155,228);
S6: Go("turbo_room",99,114);
}

// --------------------------------------------------
//	Duplicates:
// --------------------------------------------------
prontera,162,193,4	duplicate(Warper)	Warper#1	601
rachel,135,116,4	duplicate(Warper)	Warper#2	601
alberta,28,240,4	duplicate(Warper)	Warper#3	601
aldebaran,135,120,4	duplicate(Warper)	Warper#4	601
amatsu,203,87,4	duplicate(Warper)	Warper#5	601
ayothaya,209,169,6	duplicate(Warper)	Warper#6	601
comodo,194,158,4	duplicate(Warper)	Warper#7	601
einbech,142,246,4	duplicate(Warper)	Warper#8	601
einbroch,69,202,4	duplicate(Warper)	Warper#9	601
hugel,101,151,4	duplicate(Warper)	Warper#10	601
lighthalzen,151,101,6	duplicate(Warper)	Warper#11	601
geffen,124,72,4	duplicate(Warper)	Warper#12	601
izlude,130,153,4	duplicate(Warper)	Warper#13	601
xmas,150,136,4	duplicate(Warper)	Warper#14	601
morocc,159,97,4	duplicate(Warper)	Warper#15	601
payon,182,108,4	duplicate(Warper)	Warper#16	601
moc_fild04,207,331,4	duplicate(Warper)	Warper#18	601
izlu2dun,104,82,4	duplicate(Warper)	Warper#19	601
mjolnir_02,85,363,4	duplicate(Warper)	Warper#20	601
prt_fild05,273,215,4	duplicate(Warper)	Warper#21	601
glast_01,370,308,4	duplicate(Warper)	Warper#22	601
yuno_fild03,37,135,4	duplicate(Warper)	Warper#23	601
gef_fild10,71,339,4	duplicate(Warper)	Warper#24	601
moc_fild19,106,97,4	duplicate(Warper)	Warper#27	601
tur_dun01,148,239,4	duplicate(Warper)	Warper#29	601
gonryun,162,122,4	duplicate(Warper)	Warper#30	601
louyang,208,103,6	duplicate(Warper)	Warper#31	601
umbala,132,130,4	duplicate(Warper)	Warper#32	601
brasilis,201,222,4	duplicate(Warper)	Warper#33	601
manuk,262,177,4	duplicate(Warper)	Warper#34	601
splendide,205,153,4	duplicate(Warper)	Warper#35	601
mid_camp,216,288,4	duplicate(Warper)	Warper#36	601
dicastes01,194,194,6	duplicate(Warper)	Warper#37	601
mora,110,100,4	duplicate(Warper)	Warper#38	601
moscovia,216,196,6	duplicate(Warper)	Warper#39	601
nameless_n,259,213,4	duplicate(Warper)	Warper#40	601
niflheim,205,179,4	duplicate(Warper)	Warper#41	601
thor_camp,249,76,4	duplicate(Warper)	Warper#42	601
veins,214,123,4	duplicate(Warper)	Warper#43	601
dewata,194,178,6	duplicate(Warper)	Warper#44	601
eclage,107,37,4	duplicate(Warper)	Warper#45	601
malaya,210,205,4	duplicate(Warper)	Warper#46	601
malangdo,220,188,6	duplicate(Warper)	Warper#47	601
poring_w02,117,85,6	duplicate(Warper)	Warper#48	601
new_1-1,141,144,6	duplicate(Warper)	Warper#49	601
prt_fild08,57,53,6	duplicate(Warper)	Warper#50

//===== rAthena Script =======================================
//= All-in-One NPC
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.6
//===== Description: =========================================
//= A compilation of commonly-used NPC scripts.
//== Includes job changer, stylist, refiner, card remover,
//== coin exchanger, rentals, resetter, platinum skills,
//== sex changer, identifier, healer, buffer, and repairman.
//============================================================

prontera,158,193,6	script	All-in-One NPC	953,{
function Get_Platinum; function Equip_Menu;

	if (getarraysize(.OnClick)) {
		if (.OnClick[0]) { specialeffect2 313; percentheal 100,100; }
		if (.OnClick[1]) { specialeffect2 42; sc_start SC_BLESSING,600000,10; specialeffect2 37; sc_start SC_INCREASEAGI,600000,10; }
		if (.OnClick[2] && getbrokenid(1)) { specialeffect2 101; atcommand "@repairall"; } }
	set .@menu$,"";
	for (set .@i,0; .@i < getarraysize(.MainMenu$); set .@i,.@i+1) {
		if (.MenuOption & pow(2,.@i))
			set .@menu$, .@menu$+" ~ "+.MainMenu$[.@i];
		set .@menu$, .@menu$+":"; }
	switch(select(.@menu$)) {
		case 1:
			function Job_Menu; function A_An;
			if (Class > 4049) {
				message strcharinfo(0),"No more jobs are available."; end; }
			if (checkfalcon() || checkcart() || checkriding() || ismounting()) {
				message strcharinfo(0),"Please remove your "+((checkfalcon())?"falcon":"")+((checkcart())?"cart":"")+((checkriding())?"Peco":"")+((ismounting())?"mount":"")+" before proceeding.";
				end; }
			if (.SkillPointCheck && SkillPoint) { message strcharinfo(0),"Please use all your skill points before proceeding."; end; }
			set .@eac, eaclass();
			set .@i, ((.ThirdClass)?roclass(.@eac&EAJ_UPPERMASK):Class);
			if (.@i > 6 && .@i < 22) {
				if (BaseLevel < .Rebirth[0] || JobLevel < .Rebirth[1]) {
					set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .Rebirth[1]-JobLevel;
					message strcharinfo(0),"You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";
					end; }
				if (Class > 21) { Job_Menu(roclass(.@eac|EAJL_THIRD)); end; }
				while(1) {
					set .@i, select(" ~ ^0055FFRebirth^000000:"+((.ThirdClass)?" ~ ^FF0000Third Class^000000":"")+": ~ ^777777Cancel^000000");
					if (.@i==3) end;
					Job_Menu(((.@i==1)?4001:roclass(.@eac|EAJL_THIRD))); } }
			set .@j1, roclass(.@eac|EAJL_2_1); set .@j2,roclass(.@eac|EAJL_2_2);
			if ((.@eac&EAJ_UPPERMASK) == EAJ_SUPER_NOVICE) setarray .@exp[0],roclass(.@eac|EAJL_THIRD),99;
			if (Class == Job_Ninja) setarray .@exp[0],.@j1,70;
			if (.@exp[0] && .ThirdClass) {
				if (BaseLevel < .Rebirth[0] || JobLevel < .@exp[1]) {
					set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .@exp[1]-JobLevel;
					message strcharinfo(0),"You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to continue.";
					end; }
				Job_Menu(.@exp[0]); end; }
			if (.@eac&EAJL_2)
				if (.@eac&(EAJL_UPPER|EAJL_BABY) || roclass(.@eac|EAJL_UPPER) == -1) {
					message strcharinfo(0),"No more jobs are available."; end; }
			if ((.@eac&EAJ_BASEMASK) == EAJ_NOVICE) {
				if (JobLevel < .JobReq[0]) message strcharinfo(0),"A job level of "+.JobReq[0]+" is required to change into the 1st Class.";
				else if (Class == 4001 && .LastJob && lastJob) Job_Menu(roclass((eaclass(lastJob)&EAJ_BASEMASK)|EAJL_UPPER));
				else switch(Class) {
					case 0: Job_Menu(1,2,3,4,5,6,23,4046,24,25,4023);
					case 4001: Job_Menu(4002,4003,4004,4005,4006,4007);
					case 4023: Job_Menu(4024,4025,4026,4027,4028,4029,4045);
					default: message strcharinfo(0),"An error has occurred."; break; }
				end; }
			if (roclass(.@eac|EAJL_2_1) == -1 || roclass(.@eac|EAJL_2_2) == -1) message strcharinfo(0),"No more jobs are available.";
			else if (!(.@eac&EAJL_2) && JobLevel < .JobReq[1]) message strcharinfo(0),"A job level of "+.JobReq[1]+" is required to change into the 2nd Class.";
			else if (.LastJob && lastJob && (.@eac&EAJL_UPPER)) Job_Menu(lastJob+4001);
			else Job_Menu(.@j1,.@j2);
			end;
			function Job_Menu {
				if (getargcount() > 1) {
					set .@menu$,"";
					for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
						set .@menu$, .@menu$+" ~ "+jobname(getarg(.@i))+":";
					set .@menu$, .@menu$+" ~ ^777777Cancel^000000"; }
				while(1) {
					if (getargcount() > 1) {
						set .@i, getarg(select(.@menu$)-1,0);
						if (!.@i) end; }
					else set .@i, getarg(0);
					if ((.@i == 23 || .@i == 4045) && BaseLevel < .SNovice) {
						message strcharinfo(0),"A base level of "+.SNovice+" is required to turn into a "+jobname(.@i)+"."; }
					else if (select(" ~ Change into ^0055FF"+jobname(.@i)+"^000000 class: ~ ^777777Go back^000000")==1) {
						message strcharinfo(0),"Became "+A_An(jobname(.@i))+"!";
						if (.@i==4001 && .LastJob) set lastJob, Class;
						jobchange .@i;
						if (.@i==4001 || .@i==4023) resetlvl(1);
						specialeffect2 338; specialeffect2 432;
						if (.Platinum) Get_Platinum;
						end; }
					if (getargcount() == 1) return;
				} end; }
			function Get_Platinum {
				skill 142,1,0;
				switch(BaseClass) {
					case 0: if (Class !=23) skill 143,1,0; break;
					case 1: skill 144,1,0; skill 145,1,0; skill 146,1,0; break;
					case 2: skill 157,1,0; break;
					case 3: skill 147,1,0; skill 148,1,0; break;
					case 4: skill 156,1,0; break;
					case 5: skill 153,1,0; skill 154,1,0; skill 155,1,0; break;
					case 6: skill 149,1,0; skill 150,1,0; skill 151,1,0; skill 152,1,0; break;
					default: break; }
				switch(roclass(eaclass()&EAJ_UPPERMASK)) {
					case 7: skill 1001,1,0; break;
					case 8: skill 1014,1,0; break;
					case 9: skill 1006,1,0; break;
					case 10: skill 1012,1,0; skill 1013,1,0; break;
					case 11: skill 1009,1,0; break;
					case 12: skill 1003,1,0; skill 1004,1,0; break;
					case 14: skill 1002,1,0; break;
					case 15: skill 1015,1,0; skill 1016,1,0; break;
					case 16: skill 1007,1,0; skill 1008,1,0; skill 1017,1,0; skill 1018,1,0; skill 1019,1,0; break;
					case 17: skill 1005,1,0; break;
					case 18: skill 238,1,0; break;
					case 19: skill 1010,1,0; break;
					case 20: skill 1011,1,0; break;
					default: break; }
				return; }
			function A_An {
				setarray .@A$[0],"a","e","i","o","u";
				set .@B$, "_"+getarg(0);
				for(set .@i,0; .@i<5; set .@i,.@i+1)
					if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
				return "a "+getarg(0); }
		case 2:
			setarray .@Look[1],7,1,6;
			set .@s, select(" ~ Cloth color: ~ Hairstyle: ~ Hair color");
			set .@Revert, getlook(.@Look[.@s]); set .@Style,1;
			while(1) {
				setlook .@Look[.@s], .@Style;
				message strcharinfo(0),"This is style #"+.@Style+".";
				set .@menu$, " ~ Next (^0055FF"+((.@Style!=.Styles[.@s])?.@Style+1:1)+"^000000): ~ Previous (^0055FF"+((.@Style!=1)?.@Style-1:.Styles[.@s])+"^000000): ~ Jump to...: ~ Revert to original (^0055FF"+.@Revert+"^000000)";
				switch(select(.@menu$)) {
					case 1: set .@Style, ((.@Style!=.Styles[.@s])?.@Style+1:1); break;
					case 2: set .@Style, ((.@Style!=1)?.@Style-1:.Styles[.@s]); break;
					case 3: message strcharinfo(0),"Choose a style between 1 - "+.Styles[.@s]+".";
						input .@Style,0,.Styles[.@s];
						if (!.@Style) set .@Style, rand(1,.Styles[.@s]);
						break;
					case 4: set .@Style, .@Revert; setlook .@Look[.@s], .@Revert; break; }
			} end;
		case 3:
			function Refine_Item;
			if (.EnrichedRefine)
				if (select(" ~ Normal Refiner: ~ Enriched Refiner")==2) {
					Equip_Menu(1);
					setarray .@Materials[0],7619,7620,7620,7620,7620;
					setarray .@Safe[0],4,7,6,5,4;
					set .@WLv, getequipweaponlv(@i);
					message strcharinfo(0),"Item: +"+getequiprefinerycnt(@i)+" "+getequipname(@i);
					if(select(" ~ Refine item (2 * ^0055FF"+getequippercentrefinery(@i)+"^000000% success): ~ ^777777Cancel^000000")==2) end;
					Refine_Item(1, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv], 1);
					end; }
			Equip_Menu(1);
			setarray .@Materials[0],985,1010,1011,984,984;
			setarray .@Safe[0],4,7,6,5,4;
			set .@WLv, getequipweaponlv(@i);
			set .@SafeCount, .@Safe[.@WLv]-getequiprefinerycnt(@i);
			message strcharinfo(0),"Item: +"+getequiprefinerycnt(@i)+" "+getequipname(@i);
			switch(select(" ~ Refine once (^0055FF"+getequippercentrefinery(@i)+"^000000% success): ~ Refine multiple times (up to "+(10-getequiprefinerycnt(@i))+"): ~ Refine to safe limit ("+((.@SafeCount>0)?.@SafeCount+" refines":"^777777disabled^000000")+"): ~ ^777777Cancel^000000")) {
				case 1: Refine_Item(1, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]); end;
				case 2:
					input .@Refines;
					if (.@Refines+getequiprefinerycnt(@i) > 10 || .@Refines < 1) message strcharinfo(0),"Invalid number ("+.@Refines+").";
					else Refine_Item(.@Refines, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]);
					end;
				case 3:
					if (.@SafeCount < 1) message strcharinfo(0),"The item has already reached the safe limit.";
					else Refine_Item(.@SafeCount, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]);
					end;  
				case 4: end; }
			function Equip_Menu {
				setarray .@pos$[1],"Upper Headgear","Armor","Left hand","Right hand","Garment","Footgear","Left Accessory","Right Accessory","Mid Headgear","Lower Headgear";
				set .@menu$,"";
				for (set .@i,1; .@i <= 10; set .@i,.@i+1) {
					if (getequipisequiped(.@i))
						set .@menu$, .@menu$+.@pos$[.@i]+" [^0055FF"+getequipname(.@i)+"^000000]";
					set .@menu$, .@menu$+":"; }
				set @i, select(.@menu$);
				if (!getequipisequiped(@i)) { message strcharinfo(0),"Nothing is equipped there!"; end; }
				if (getarg(0)) {
					if (!getequipisenableref(@i)) { message strcharinfo(0),getequipname(@i)+" cannot be refined."; end; }
					if (getequiprefinerycnt(@i) >= 10 ) { message strcharinfo(0),"+"+getequiprefinerycnt(@i)+" "+getequipname(@i)+" cannot be refined any further."; end; } }
				return; }
			function Refine_Item {
				message strcharinfo(0),"I'll need "+getarg(0)+"x "+getitemname(getarg(1))+" and "+getarg(0)*getarg(2)+" Zeny.";
				if (countitem(getarg(1)) < getarg(0) || Zeny < getarg(0)*getarg(2)) {
					sleep2 500; message strcharinfo(0),"Come back when you have the required materials."; end; }
				if (getequiprefinerycnt(@i)+getarg(0) > getarg(3)) {
					sleep2 500; message strcharinfo(0),"The item will be refined above the safe limit. It may break."; }
				sleep2 500;
				if(select(" ~ ^0055FFContinue^000000: ~ ^777777Cancel^000000")==2) end;
				set .@j, getarg(0);
				while(.@j) {
					delitem getarg(1), 1;
					set Zeny, Zeny-getarg(2);
					if (getarg(4,0)) {
						if (getequippercentrefinery(@i) <= rand(100) && getequippercentrefinery(@i) <= rand(100)) {
							message strcharinfo(0),getequipname(@i)+" broke while refining."; failedrefitem @i; end; } }
					else {
						if (getequippercentrefinery(@i) <= rand(100)) {
							message strcharinfo(0),getequipname(@i)+" broke while refining."; failedrefitem @i; end; } }
					successrefitem @i;
					set .@j, .@j-1; }
				message strcharinfo(0),"All done!";
				end; }
		case 4:
			if (.Prices[0]) message strcharinfo(0),"It costs "+.Prices[0]+" Zeny to remove cards.";
			Equip_Menu(0);
			if (Zeny < .Prices[0]) { message strcharinfo(0),"You don't have enough Zeny."; end; }
			set .@j,getequipcardcnt(@i);
			if (!.@j) { message strcharinfo(0),"There are no cards compounded to "+getequipname(@i)+"."; end; }
			if (!checkweight(4001,(.@j+1))) { message strcharinfo(0),"You're carrying too many items!"; end; }
			message strcharinfo(0),"Item: "+getequipname(@i);
			if (select(" ~ Remove "+.@j+" card(s): ~ ^777777Cancel^000000")==2) end;
			set Zeny, Zeny-.Prices[0];
			successremovecards @i;
			message strcharinfo(0),"Cards successfully removed!";
			end;
		case 5:
			message strcharinfo(0),"Coins are worth "+.Coin[1]+" Zeny each.";
			switch(select(" ~ Zeny to coins: ~ Coins to Zeny: ~ Close")) {
				case 1:
					message strcharinfo(0),"How many coins do you want?";
					input .@coins,0,(1000000000/.Coin[1]);
					if (.@coins*.Coin[1] > Zeny) { message strcharinfo(0),"You don't have enough Zeny."; end; }
					if (!checkweight(.Coin[0],.@coins)) { message strcharinfo(0),"You don't have enough inventory space."; end; }
					set Zeny, Zeny-(.Coin[1]*.@coins);
					getitem .Coin[0], .@coins;
					message strcharinfo(0),"Purchased "+.@coins+" coins.";
					end;
				case 2:
					message strcharinfo(0),"How many coins do you want to trade in?";
					input .@coins,0,(1000000000/.Coin[1]);
					if (countitem(.Coin[0]) < .@coins) { message strcharinfo(0),"You don't have that many coins!"; end; }
					if ((Zeny+(.Coin[1]*.@coins)) > 1000000000) { message strcharinfo(0),"You have too much Zeny!"; end; }
					delitem .Coin[0], .@coins;
					set Zeny, Zeny+(.Coin[1]*.@coins);
					message strcharinfo(0),"Exchanged "+.@coins+" coins.";
					end;
				case 3:
					end; }
		case 6:
			if (Zeny < .Prices[2]) { message strcharinfo(0),"It costs "+.Prices[2]+" Zeny to rent."; end; }
			if (ismounting()) { message strcharinfo(0),"You must first remove your mount."; end; }
			else if ((eaclass()&EAJ_THIRDMASK==EAJ_RANGER) && !countitem(6124)) {
				if (!checkfalcon() && getskilllv(127) && !checkwug()) {
					if(select(" ~ Falcon: ~ Warg")==1) setfalcon;
					else getitem 6124,1; }
				else getitem 6124,1; }
			else if ((eaclass()&EAJ_THIRDMASK==EAJ_MECHANIC) && !checkcart() && getskilllv(39)) {
				if (!checkmadogear() && getskilllv(2255)) {
					if(select(" ~ Cart: ~ Mado")==1) setcart;
					else setmadogear; }
				else setcart; }
			else if (!checkcart() && getskilllv(39)) setcart;
			else if (!checkfalcon() && getskilllv(127) && !checkwug()) setfalcon;
			else if (!checkriding() && getskilllv(63)) {
				if (eaclass()&EAJ_THIRDMASK==EAJ_RUNE_KNIGHT) setdragon;
				else setriding; }
			else if (!checkmadogear() && getskilllv(2255)) setmadogear;
			else { message strcharinfo(0),"You do not meet requirements to rent."; end; }
			set Zeny, Zeny-.Prices[2];
			specialeffect2 276;
			end;
		case 7:
			if (.Prices[1]) message strcharinfo(0),"It costs "+.Prices[1]+" Zeny to reset stats or skills.";
			set .@i, select(" ~ Stat reset: ~ Skill reset: ~ Cancel");
			if (.@i==3) end;
			if (Zeny < .Prices[1]) { message strcharinfo(0),"You don't have enough Zeny."; end; }
			set Zeny, Zeny-.Prices[1];
			if (.@i==1) ResetStatus;
			else { sc_end SC_ALL; ResetSkill; }
			message strcharinfo(0),((.@i==1)?"Stats":"Skills")+" reset!";
			end;
		case 8:
			Get_Platinum;
			specialeffect2 441;
			message strcharinfo(0),"Platinum skills received!";
			end;
		case 9:
			set .@Var$, ".SexChange"+((Sex)?"F":"M");
			if (getarraysize(getd(.@Var$))) {
				message strcharinfo(0),"To turn into a "+((Sex)?"female":"male")+" you need the following items:";
				sleep2 1000;
				for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2) {
					message strcharinfo(0),getd(.@Var$+"["+(.@i+1)+"]")+"x "+getitemname(getd(.@Var$+"["+.@i+"]"));
					if (countitem(getd(.@Var$+"["+.@i+"]")) < getd(.@Var$+"["+(.@i+1)+"]")) set .@nreq,1;
					sleep2 500; }
				if (.@nreq) end; }
			if(select(" ~ Change into a "+((Sex)?"female":"male")+": ~ Cancel")==2) end;
			if (getarraysize(getd(.@Var$)))
				for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2)
					delitem getd(.@Var$+"["+.@i+"]"), getd(.@Var$+"["+(.@i+1)+"]");
			changesex;
			end;
		case 10:
			setarray .@Total[0],0,0;
			getinventorylist;
			for(set .@i,0; .@i<@inventorylist_count; set .@i,.@i+1) {
				if (@inventorylist_identify[.@i]) continue;
				if (Zeny < .Prices[3]) {
					dispbottom "It costs "+.Prices[3]+" to identify an item."; break; }
				set Zeny, Zeny-.Prices[3];
				delitem2 @inventorylist_id[.@i],1,0,0,0,0,0,0,0;
				getitem @inventorylist_id[.@i],1;
				setarray .@Total[0], .@Total[0]+1, .@Total[1]+.Prices[3]; }
			if (!.@Total[0]) { message strcharinfo(0),"No items identified."; end; }
			specialeffect2 154;
			message strcharinfo(0),"Identified "+.@Total[0]+" items"+((.@Total[1])?" for "+.@Total[1]+" Zeny":"")+".";
			end;
	}
OnInit:

// --------------------- Config ---------------------
	setarray .MainMenu$[0],	// Set menu options!
		"Change Jobs",		// [1]
		"Stylist",		// [2]
		"Refiner",		// [4]
		"Remove Cards",		// [8]
		"Exchange Coins",	// [16]
		"Rentals",		// [32]
		"Reset Stats/Skills",	// [64]
		"Platinum Skills",	// [128]
		"Change Sex",		// [256]
		"Identify All";		// [512]

	set .MenuOption,1|2|4|8|16|32|64|128|256|512;

	setarray .OnClick[0],1,1,1;		// When clicked: heal [0], buff [1], repair [2] (1: yes / 0: no)
	setarray .Styles[1],553,65,250;		// Maximum dye, hair style, and hair color
	setarray .Coin[0],674,1000000;		// Coin item ID, coin price
	setarray .Prices[0],50000,10000,0,100;	// Zeny to remove cards [0], reset [1], rent [2], identify [3]

	setarray .Rebirth[0],99,50;	// Minimum base level, job level to rebirth OR change to third class
	setarray .JobReq[0],10,40;	// Minimum job level to turn into 1st class, 2nd class
	set .ThirdClass,1;		// Enable third classes? (1: yes / 0: no)
	set .SNovice,45;		// Minimum base level to turn into Super Novice
	set .LastJob,1;			// Enforce linear class changes? (1: yes / 0: no)
	set .SkillPointCheck,0;		// Force player to use up all skill points? (1: yes / 0: no)
	set .Platinum,1;		// Get platinum skills automatically? (1: yes / 0: no)

	set .EnrichedRefine,1;			// Allow enriched refiner option? (1: yes / 0: no)
	setarray .RP[0],2000,50,200,5000,20000;	// Zeny for armor, lv1, lv2, lv3, lv4 refines

	setarray .SexChangeF[0],2213,1,1558,1,7152,50;	// Items to turn into Female (ID,Count)
	setarray .SexChangeM[0],5016,1,2241,1,1017,50;	// Items to turn into Male (ID,Count)

// --------------------------------------------------
	end;
}

 

	601

PLease help to Fix that 

 

i was read http://rathena.org/board/topic/81860-r17280-slight-script-engine-update/

 

but still got this message

Edited April 25, 2013 by melv0

[Patskie]

Use end tag on the line which causes the warning sign and replace the close tag. This is caused by the new update that was released recently.

[LearningRO]

@patskie Sir can u help me to modif my script??

im really confuse @-@

[Patskie]

@patskie Sir can u help me to modif my script??

im really confuse @-@

Just replace close tag by end tag.

[LearningRO]

sir look at my script i was change it but still get stuck when chose menu or use next command on NPC

Any idea please??

[Patskie]

sir look at my script i was change it but still get stuck when chose menu or use next command on NPC

Any idea please??

Replace only the line that causes the warning.