Jump to content
  • 0

Dynamic Quest NPC

Yudax

Asked by Yudax,

 Share

Question

Yudax Poring

Yudax

Posted
Posted (edited) 

//===== rAthena Script =======================================
//= Euphy's Quest Shop
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.4c
//===== Compatible With: =====================================
//= rAthena SVN r16862+
//===== Description: =========================================
//= A dynamic quest shop based on Lunar's, with easier config.
//= Includes support for multiple shops & cashpoints.
//= Item Preview script by ToastOfDoom.
//============================================================

prontera,164,164,4    script    Quest Shop    998,{
function Add; function Chk; function Slot; function A_An;

   if (.Shops$ == "") set .@i, select(.menu$);
   else set .@i,1;
   dispbottom "Select one item at a time.";
   callshop "qshop"+.@i,1;
   npcshopattach "qshop"+.@i;
   end;

function Add {
   if (getitemname(getarg(1)) == "null") {
       debugmes "Quest reward #"+getarg(1)+" invalid (skipped).";
       return;
   }
   for(set .@n,5; .@n<127; set .@n,.@n+2) {
       if (!getarg(.@n,0)) break;
       if (getitemname(getarg(.@n)) == "null") {
           debugmes "Quest requirement #"+getarg(.@n)+" invalid (skipped).";
           return;
       }
   }
   for(set .@i,2; .@i<.@n; set .@i,.@i+1)
       set getd(".q_"+getarg(1)+"["+(.@i-2)+"]"), getarg(.@i);
   npcshopadditem "qshop"+getarg(0),getarg(1),((.ShowZeny)?getarg(3):0);
   return;
}
function Chk {
   if (getarg(0) < getarg(1)) {
       set @qe0,1;
       return "^FF0000";
   }
   else return "^00FF00";
}
function Slot {
   set .@s$,getitemname(getarg(0));
   switch(.ShowSlot) {
       case 1: if (!getitemslots(getarg(0))) return .@s$;
       case 2: if (getiteminfo(getarg(0),2) == 4 || getiteminfo(getarg(0),2) == 5) return .@s$+" ["+getitemslots(getarg(0))+"]";
       default: return .@s$;
   }
}
function A_An {
   setarray .@A$[0],"a","e","i","o","u";
   set .@B$, "_"+getarg(0);
   for(set .@i,0; .@i<5; set .@i,.@i+1)
       if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
   return "a "+getarg(0);
}

OnBuyItem:
   set .@q[0],@bought_nameid;
   copyarray .@q[1],getd(".q_"+@bought_nameid+"[0]"),getarraysize(getd(".q_"+@bought_nameid+"[0]"));
   if (!.@q[1]) {
       message strcharinfo(0),"An error has occurred.";
       end;
   }
   mes "[Quest Shop]";
   mes "Reward: ^0055FF"+((.@q[1]>1)?.@q[1]+"x ":"")+Slot(.@q[0])+"^000000";
   mes "Requirements:";
   if (.@q[2]) mes " > "+Chk(Zeny,.@q[2])+.@q[2]+" Zeny^000000";
   if (.@q[3]) mes " > "+Chk(getd(.Points$[0]),.@q[3])+.@q[3]+" "+.Points$[1]+" ("+getd(.Points$[0])+"/"+.@q[3]+")^000000";
   if (.@q[4]) for(set .@i,4; .@i<getarraysize(.@q); set .@i,.@i+2)
       mes " > "+Chk(countitem(.@q[.@i]),.@q[.@i+1])+((.DisplayID)?"{"+.@q[.@i]+"} ":"")+Slot(.@q[.@i])+" ("+countitem(.@q[.@i])+"/"+.@q[.@i+1]+")^000000";
   next;
   set @qe1, getiteminfo(.@q[0],5);
   set @qe2, getiteminfo(.@q[0],11);
   addtimer 1000, strnpcinfo(1)+"::OnEnd";
   while(1) {
       switch(select(" ~ Purchase ^0055FF"+getitemname(.@q[0])+"^000000:"+((((@qe1&1) || (@qe1&256) || (@qe1&512)) && @qe2 > 0 && !@qe6)?" ~ Preview...":"")+": ~ ^777777Cancel^000000")) {
       case 1:
           if (@qe0) {
               mes "[Quest Shop]";
               mes "You're missing one or more quest requirements.";
               close;
           }
           if (!checkweight(.@q[0],.@q[1])) {
               mes "[Quest Shop]";
               mes "^FF0000You need "+(((.@q[1]*getiteminfo(.@q[0],6))+Weight-MaxWeight)/10)+" additional weight capacity to complete this trade.^000000";
               close;
           }
           if (.@q[2]) set Zeny, Zeny-.@q[2];
           if (.@q[3]) setd .Points$[0], getd(.Points$[0])-.@q[3];
           if (.@q[4]) for(set .@i,4; .@i<getarraysize(.@q); set .@i,.@i+2)
               delitem .@q[.@i],.@q[.@i+1];
           getitem .@q[0],.@q[1];
           if (.Announce) announce strcharinfo(0)+" has created "+A_An(getitemname(.@q[0]))+"!",0;
           specialeffect2 699;
           close;
       case 2:
           set @qe3, getlook(LOOK_HEAD_BOTTOM);
           set @qe4, getlook(LOOK_HEAD_TOP);
           set @qe5, getlook(LOOK_HEAD_MID);
           set @qe6,1;
           if (@qe1&1) changelook LOOK_HEAD_BOTTOM, @qe2;
           if (@qe1&256) changelook LOOK_HEAD_TOP, @qe2;
           if (@qe1&512) changelook LOOK_HEAD_MID, @qe2;
           break;
       case 3:
           close;
       }
   }
OnEnd:
   if (@qe6) {
       changelook LOOK_HEAD_BOTTOM, @qe3;
       changelook LOOK_HEAD_TOP, @qe4;
       changelook LOOK_HEAD_MID, @qe5;
   }
   for(set .@i,0; .@i<7; set .@i,.@i+1)
       setd "@qe"+.@i,0;
   end;
OnInit:
   freeloop(1);
// --------------------- Config ---------------------
// Custom points, if needed: "<variable>","<name to display>"
   setarray .Points$[0],"#CASHPOINTS","Cash Points";

   set .Announce,1;    // Announce quest completion? (1: yes / 0: no)
   set .ShowSlot,1;    // Show item slots? (2: all equipment / 1: if slots > 0 / 0: never)
   set .DisplayID,0;    // Show item IDs? (1: yes / 0: no)
   set .ShowZeny,1;    // Show Zeny cost, if any? (1: yes / 0: no)

// Shop categories, if needed: "<Shop 1>","<Shop 2>"{,...};
// Duplicate dummy data for any additional shops (bottom of script).
// If no categories, use the second line instead (remove //).

   setarray .Shops$[1],"Headgears";
   // set .Shops$,"n/a";

// Add(<shop number>,<reward ID>,<reward amount>,<Zeny cost>,<point cost>,
//     <required item ID>,<required item amount>{,...});
// Shop number corresponds with order above (default is 1).
// Note: Do NOT use a reward item more than once!

//    Add(1,5022,1,0,0,7086,1,969,10,999,40,1003,50,984,2);
//    Add(1,5032,1,0,0,1059,250,2221,1,2227,1,7063,600);
//    Add(1,5027,1,0,0,2252,1,1036,400,7001,50,4052,1);
//    Add(1,5045,1,0,0,2252,1,1054,450,943,1200);

   Add(1,30001,1,0,0,948,300,950,250,931,250,998,250,607,50);
   Add(1,30002,1,0,0,932,300,7063,300,994,250,919,200,607,100);
   Add(1,30003,1,0,0,7154,250,11520,250,7001,300,7448,250,1036,200,607,50);
   Add(1,30005,1,0,0,7507,250,7317,250,7003,250,746,200,934,100,607,50);
   Add(1,30007,1,0,0,1035,300,963,200,7100,300,990,250,7033,200,607,100);

//    Add(1,20003,1,0,0,1039,300,12040,200,7106,250,7198,300,1037,200,607,100);
//    Add(1,20015,1,0,0,2254,5,7111,400,7292,300,7097,350,1056,200,607,100);
//    Add(1,20013,1,0,0,2255,5,7119,350,1060,300,7326,250,579,200,607,100);
//    Add(1,20012,1,0,0,748,500,7189,350,7095,300,2656,250,7320,200,607,100);
//    Add(1,20014,1,0,0,748,500,7189,350,7095,300,7301,300,7159,250,607,100);

   setarray .Shops$[1],"Wings";
   // set .Shops$,"n/a";

// Add(<shop number>,<reward ID>,<reward amount>,<Zeny cost>,<point cost>,
//     <required item ID>,<required item amount>{,...});
// Shop number corresponds with order above (default is 1).
// Note: Do NOT use a reward item more than once!

//    Add(1,5022,1,0,0,7086,1,969,10,999,40,1003,50,984,2);
//    Add(1,5032,1,0,0,1059,250,2221,1,2227,1,7063,600);
//    Add(1,5027,1,0,0,2252,1,1036,400,7001,50,4052,1);
//    Add(1,5045,1,0,0,2252,1,1054,450,943,1200);

   Add(1,30000,1,0,0,734,200,737,250,1006,300,607,50);
   Add(1,30004,1,0,0,7507,250,7317,250,7003,250,746,200,7197,100,607,50);
   Add(1,30006,1,0,0,7507,250,7317,250,7003,250,746,200,926,100,607,50);
   Add(1,30008,1,0,0,7161,300,7753,250,7323,250,1059,300,607,100);

   Add(1,30009,1,0,0,1039,300,12040,200,7106,250,7198,300,1037,200,607,100);
   Add(1,30010,1,0,0,2254,5,7111,400,7292,300,7097,350,1056,200,607,100);
   Add(1,30011,1,0,0,2255,5,7119,350,1060,300,7326,250,579,200,607,100);
   Add(1,30012,1,0,0,748,500,7189,350,7095,300,2656,250,7320,200,607,100);
   Add(1,30013,1,0,0,748,500,7189,350,7095,300,7301,300,7159,250,607,100);
   Add(1,30014,1,0,0,748,500,7189,350,7095,300,7301,300,7159,250,607,100);
   Add(1,30015,1,0,0,748,500,7189,350,7095,300,7301,300,7159,250,607,100);


// --------------------------------------------------
   freeloop(0);
   set .menu$,"";
   for(set .@i,1; .@i<=getarraysize(.Shops$); set .@i,.@i+1) {
       set .menu$, .menu$+.Shops$[.@i]+":";
       npcshopdelitem "qshop"+.@i,909;
   }
   end;
}

// -------- Dummy data (duplicate as needed) --------
-    shop    qshop1    -1,909:-1
-    shop    qshop2    -1,909:-1
-    shop    qshop3    -1,909:-1

I've edit my script so I can choose two options, Headgears and Wings but when i Tried to reload it all i saw is the option 'Headgears'.

Can you help me with this?

Edited by Euphy
Codeboxed.

2 answers to this question

Recommended Posts

Euphy Poring

Euphy

Posted
Posted

Follow the default example I included - you don't duplicate the 'setarray' line, you add to the array.

    setarray .Shops$[1],"Headgears","Wings";
   Add(1,...); // 1 = Headgears
   Add(2,...); // 2 = Wings

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 Share
Go to question listing

  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...