pvp room (adding map)

[NANORAY]

prontera,155,181,5 script Sample 757,{

if( select("PVP Room [ "+getmapusers("prontera")+"/50 ]:Cancel") == 1 )

if( getmapusers("prontera") < 50 )

warp "prontera",0,0;

close;

}

question guys. how to add more maps in this script?

[Euphy]

Add more options, then a switch(select()).

[NANORAY]

but how? where will i put it? i don't know how. can you give me a sample script that select more maps? thanks in advance sir euphy

[AnnieRuru]

hmm ... the npc in prontera, and ask to warp into prontera map to pvp ... ? sounds weird

prontera,157,178,5	script	Sample	757,{
mes "select a pvp room";
next;
for ( .@i = 0; .@i < .size; .@i++ )
	.@menu$ = .@menu$ +"Room "+( .@i +1 )+". ["+ getmapusers(.pvpmap$[.@i]) +"/50]:";
.@menu$ = .@menu$ + "Cancel";
.@room = select( .@menu$ ) -1;
if ( .@room == .size ) {
	mes "ok, come back anytime";
	close;
}
if ( getmapusers( .pvpmap$[ .@room ] ) >= 50 ) {
	mes "this room is full";
	close;
}
warp .pvpmap$[ .@room ], 0,0;
end;

OnInit:
setarray .pvpmap$,
	"pvp_y_1-1", "pvp_y_1-2", "pvp_y_1-3"; // add more maps here

.size = getarraysize( .pvpmap$ );
for ( .@i = 0; .@i < .size; .@i++ )
	setmapflag .pvpmap$[.@i], mf_pvp;
end;
}

[NANORAY]

super thanks AnnieRuru and euphy!

how about the mapflag? i'll just put it under the script?

[AnnieRuru]

setmapflag .pvpmap$[.@i], mf_pvp;

I thought I already did it also