Incorporating #item in an NPC.

[noheavenuro]

I'm having trouble with my script.

I want to make it use the charcommand #item.

I want this to be as simple as possible.

Here's my test script.

quiz_01,186,195,4 script zor 802,{

input .plname$;

input .@prize;

input .@prizeqty;

charcommand "#item .plname$ .@prize .@prizeqty";

}

How this NPC might work:

It asks the name, then item number, then quantity of the item. Then when it's all set it uses #item to give the item directly to player inputted in the first inputBox.

But it always says "#item failed. Player not found.

Already tried adding double quotes("<name>") in the input the character name box, but it still says that.

Help.

Or a better script that gives items specifically to players at the whim of a GM.

I tried searching for this but all I keep seeing is the one that goddameit made. I like his script but I don't understand how to edit it to fit my needs. :/

[Emistry]

prontera,155,181,5 script Sample 757,{
if( getgmlevel() > 80 ){
mes "Enter Items ID :";
mes " 0 = Cancel";
do{
 input .@ItemID;
 if( .@ItemID < 1 ) close;
}while( getitemname( .@ItemID ) == "null" );
mes "Enter Amount :";
input .@Amount,1,30000;
mes "Enter Name :";
input .@Name$;
next;
mes "Name : "+.@Name$;
mes "Item : "+getitemname( .@ItemID );
mes "Amount : "+.@Amount;
if( select("Confirm:Cancel") == 1 ){
 if( !attachrid( getcharid(3,.@Name$) ) )
  message strcharinfo(0),"Player not Found.";
 else{
  getitem .@ItemID,.@Amount,getcharid(3,.@Name$);
  message strcharinfo(0),"Item Sent";
  message .@Name$,"You Received item from "+strcharinfo(0);
 }
}
}
close;
}

[noheavenuro]

Thanks Emistry.

Will try this.