Rebirth/Reborn System

[ays297]

I would like a script that allows my player to reborn/rebirth multiple times after the normal rebirth. Gives additional statpoint (100)

The NPC for the first rebirth to only require 3 kinds of items and only appears twice a day for 10 minutes. (12:00 and 0:00)

The NPC for the second rebirth requires 5 osiris doll (to be exact). This NPC will also be in charged of the next rebirths but will require the same items with the first rebirth.

I would also like that for every rebirth that there will be a server wide announcement. And also, a rebirth ladder in game and if possible also for my website.

Thanks a lot.

[deathscythe13]

ohh is this wafflero? i like wafflero

ok im gonna make mine:

- script reborn1sttrigger -1,{
OnClock1200:
OnClock0000:
announce "I have arrived!",0;
enablenpc "FirstReborn";
end;
OnClock1210:
OnClock0010:
announce "If that's all ill be going now",0;
disablenpc "FirstReborn";
end;
OnInit:
disablenpc "FirstReborn";
end;

}

prontera,151,180,4 script FirstReborn 100,{
set .@maxblevel , 99;
set .@maxjlevel , 70;
set .@reqitem1, 512;
set .@reqitem2, 513;
set .@reqitem3, 514;
set .@reqitem1amt, 1;
set .@reqitem2amt, 1;
set .@reqitem3amt, 1;
mes "[FirstReborn]";
if(reborncount) {
 mes "You have finish reborn!";
 close;
}
if(Upper != 1 || BaseLevel < .@maxblevel || JobLevel < .@maxjlevel || countitem(.@reqitem1) < .@reqitem1amt
 || countitem(.@reqitem2) < .@reqitem2amt || countitem(.@reqitem3) < .@reqitem3amt ) {
 mes "You need to be Base Lvl: "+.@maxblevel;
 mes "You need to be Job Lvl: "+.@maxjlevel;
 mes "You need to have "+.@reqitem1amt+" "+getitemname(.@reqitem1);
 mes "You need to have "+.@reqitem2amt+" "+getitemname(.@reqitem2);
 mes "You need to have "+.@reqitem3amt+" "+getitemname(.@reqitem3);
 mes "You dont have enough requirements!";
 close;
}

mes "Congratulations you are now reborn!";
delitem .@reqitem1,.@reqitem1amt;
delitem .@reqitem2,.@reqitem2amt;
delitem .@reqitem3,.@reqitem3amt;
jobchange Job_Novice_High;
resetlvl(1);
skill 142,1,0;
skill 143,1,0;
set reborncount, reborncount+1;
ResetStatus;
set StatusPoint, StatusPoint+(reborncount*100);
announce strcharinfo(0)+" has been reborn.",0;
close;
}
prontera,155,180,4 script SecondReborn 100,{
set .@maxblevel , 99;
set .@maxjlevel , 70;
set .@reqitem, 751;
set .@reqitemamt, 5;
set .@rebornmax, 10;
mes "[secondReborn]";

if(reborncount < 1) {
mes "You didn't take first reborn yet.";
close;
}

if(reborncount >= .@rebornmax) {
 mes "You cannot reborn anymore.";
 close;
}
if(Upper != 1 || BaseLevel < .@maxblevel || JobLevel < .@maxjlevel || countitem(.@reqitem) < .@reqitemamt ) {
 mes "You need to be Base Lvl: "+.@maxblevel;
 mes "You need to be Job Lvl: "+.@maxjlevel;
 mes "You need to have "+.@reqitemamt+" "+getitemname(.@reqitem);
 mes "You dont have enough requirements!";
 close;
}

mes "Congratulations you are now reborn!";
delitem .@reqitem,.@reqitemamt;
jobchange Job_Novice_High;
resetlvl(1);
skill 142,1,0;
skill 143,1,0;
set reborncount, reborncount+1;
ResetStatus;
set StatusPoint, StatusPoint+(reborncount*100);
announce strcharinfo(0)+" has been reborn "+reborncount+" times.",0;
close;
}
prontera,159,180,4 script RebornLadder 100,{
set .@count, query_sql ("SELECT char_id,value FROM `global_reg_value` WHERE str='reborncount' ORDER BY value DESC",.@charid,.@reborncount);

mes "[RebornLadder]";
for( set .@i, 0; .@i < .@count; set .@i, .@i+1) {
 query_sql "SELECT `name` FROM `char` WHERE char_id="+.@charid[.@i]+"",.@charname$;
 mes .@charname$+" "+.@reborncount[.@i];
}
close;
}

prontera,150,193,4 script Reset Girl 124,{
set .rskill,5000; // Set value in zeny for skill reset here
set .rstat,5000; // Set value in zeny for stat reset here
set .rboth,9000; // Set value for "package deal" (i.e.: reseting both) here.
mes "[Reset Girl]";
mes "I am a Reset Girl.";
mes "Reset Stats: "+ .rstat +"z";
mes "Reset Skills: "+ .rskill +"z";
mes "Reset Both: "+ .rboth +"z";
mes "Please select the service you want:";
next;
switch(select("^FF3355Reset Skills:Reset Stats:Reset Both^000000:Quit")) {
case 1:
 mes "[Reset Girl]";
 if (Zeny < .rskill) {
  mes "Sorry, you don't have enough Zeny.";
  close;
 }
 mes "Alright, here we go now.. Remember, changes won't take effect until you log back on!";
 set Zeny,Zeny-.rskill;
 ResetSkill;
 close;
case 2:
 mes "[Reset Girl]";
 if (Zeny < .rstat) {
  mes "Sorry, you don't have enough Zeny.";
  close;
 }
 mes "Alright, here we go now.. Remember, changes won't take effect until you log back on!";
 set Zeny,Zeny-.rstat;
 ResetStatus;
 set StatusPoint, StatusPoint+(reborncount*100);
 close;
case 3:
 mes "[Reset Girl]";
 if (Zeny < .rboth) {
  mes "Sorry, you don't have enough Zeny.";
  close;
 }
 mes "Alright, here we go now.. Remember, changes won't take effect until you log back on!";
 set Zeny,Zeny-.rboth;
 ResetSkill;
 ResetStatus;
 set StatusPoint, StatusPoint+(reborncount*100);
 close;
case 4:
 mes "Come again soon!";
 close;
}
}

Edited June 21, 2012 by Arcenciel
Codeboxed

[XpaX]

anyone know how add sub job script HELPP

[WhatFT]

I Love waffle ro too long time ago !

Is this working btw? XD Cause I'm here again to ask for some tabbings sorry..

What if the each rebirth must hunt different kinds of items?

Edited May 6, 2012 by Paulinds

[maynard]

sir how to set the required item to be different every reborn?

Edited May 17, 2012 by maynard

[unami89]

ohh is this wafflero? i like wafflero

ok im gonna make mine:

sir why after i load this script its error... is this script only work on rathena?

Edited June 21, 2012 by Arcenciel
Removed code