Gold Room script problem

[pololzz]

Can someone check for me what went wrong to this script?

Problem:
1. If I kill the Elu mob it also gives chance Ori drops. Due to this, it re-summon the Ori mobs instead the Elu and eventually all mobs in the dungeon becomes monsterid:1951

maintown,169,189,6	script	Ore Dungeon Warper	95,{

mes "[ ^0065DFOre Dungeon Warper^000000 ]";
mes "Welcome Adventurer!!!";
mes "I Can Help You Warp To Ore Dungeon";
next;
mes "[ ^0065DFOre Dungeon Warper^000000 ]";
mes "In this dungeon, you can farm Rough Oridecon and Elunium with a slim chance of Elunium and Oridecon";
mes "The cost would be 5 event ticket per enter.";
next;
mes "[ ^0065DFOre Dungeon Warper^000000 ]";
mes "Shall we?";
switch(select("~ Yes:~ No")) {
	case 1:
		if (countitem(7711) < 5) {
			mes "You don't have enough Event Ticket.";
			close;
		}
		delitem 7711,5;
		warp .map$,0,0;
		close;
		end;
	case 2:
		close;
	}
OnMobKill:
	if( rand(100) < 20 ) getitem 756,1;		//drop r.ori
	if( rand(1000) < 5 ) {
		getitem 984,1;				//drop Ori
		announce "(Ore Dungeon) : "+strcharinfo(0)+" Got Oridecon.",0;
	}
	monster .map$,0,0,"Oridecon",1951,1,strnpcinfo(0)+"::OnMobKill";
	end;

OnMobKill1:
	if( rand(100) < 20 ) getitem 757,1;		//drop r.elu
	if( rand(1000) < 5 ) {
		getitem 985,1;				//drop Elu
		announce "(Ore Dungeon) : "+strcharinfo(0)+" Got Elunium.",0;
	}
	monster .map$,0,0,"Elunium",1954,1,strnpcinfo(0)+"::OnMobKill";
	end;

OnMobKill2:
	monster .map$,0,0,"Guardian",1949,1,strnpcinfo(0)+"::OnMobKill2";
	end;

OnInit:
	set .map$,	"jor_ab02";
	setmapflag .map$,	mf_loadevent;
	monster .map$,0,0,"Oridecon",1951,100,strnpcinfo(0)+"::OnMobKill";
	monster	.map$,0,0,"Elunium",1954,100,strnpcinfo(0)+"::OnMobKill1";
	monster	.map$,0,0,"Guardian",1949,5,strnpcinfo(0)+"::OnMobKill2";
	waitingroom "Ore Dungeon",0;
	end; 
}
jor_ab02	mapflag	novending
jor_ab02	mapflag	nosave
jor_ab02	mapflag	nodrop
jor_ab02	mapflag	notrade
jor_ab02	mapflag	nomobloot
jor_ab02	mapflag	nobranch
jor_ab02	mapflag	loadevent

 

[Rynbef]

Change on the OnMobKill1 label this line

monster .map$,0,0,"Elunium",1954,1,strnpcinfo(0)+"::OnMobKill";
	end

To

monster .map$,0,0,"Elunium",1954,1,strnpcinfo(0)+"::OnMobKill1";
	end

U repawn Elunium but when it dies the label of Oridicon called. At OnInit its correct.

 

Rynbef~

Edited February 12 by Rynbef