Randomize item drop by unique type, quantity

[Desryuu]

Hello community!

  I need your help with something...

But first, I want to explain how it is expected to work.

Expected Result: After killing x monster, add a chance to obtain randomly from 1 to 3 different items (not duplicating), of random x (from 1 to the max specified amount in the array) amounts. Everything is practically randomized.

Right now, it is throwing duplicate items and the random amount is not in line with the corresponding item.

 

//============================================================ 
//= Dropped Random Items by Monsters
//============================================================ 
-    script    Dropped    -1,{

OnInit:
    .rand_amt = 3;                                  // Amount of random items
    setarray .item_id[1], 501, 645, 533; // Possible items to receive (ID, amount)
    setarray .item_qty[1], 25, 5, 30;
    monster "jupe_ele",0,0,"--ja--",1004,1,"Dropped::OnDropping";
end;

OnDropping:
    getmapxy(@map$, @x, @y, BL_PC);
    do{
        .@loc = rand(1, getarraysize(.item_id) - 1);
        .@pos = rand(1, getarraysize(.item_qty) - 1);
        debugmes ("count: "+.@i);      
        makeitem .item_id[.@loc], .item_qty[.@pos],@map$, @x, @y;  
        .@count++;
        debugmes("Count: "+.@count);
    }while(.@count < rand(0,.rand_amt));
    monster "jupe_ele",0,0,"--ja--",1004,1,"Dropped::OnDropping";
end;

}

Hopefully you guys can help me!

Thanks in advance.

[RagEmp]

// -- This function was originally from Annieruru
function	script	F_ShuffleNumbers	{
	deletearray getarg(2);
	.@static = getarg(0);
	.@range = getarg(1) +1 - .@static;
	.@count = getarg(3, .@range);
	if (.@range <= 0 || .@count <= 0)
		return 0;
	if (.@count > .@range)
		.@count = .@range;
	for (.@i = 0; .@i < .@range; ++.@i)
		.@temparray[.@i] = .@i;
	for (.@i = 0; .@i < .@count; ++.@i) {
		.@rand = rand(.@range);
		set getelementofarray( getarg(2), .@i ), .@temparray[.@rand] + .@static;
		.@temparray[.@rand] = .@temparray[--.@range];
	}
	return .@count;
}

-	script	Dropped	-1,{
OnInit:
	setarray .item_id, 501, 645, 533; // Possible items to receive (ID, amount)
	setarray .item_qty, 25, 5, 30;
	monster "jupe_ele",0,0,"--ja--",1004,1,strnpcinfo(0)+"::OnDropping";
	end;

OnDropping:
	getmapxy(@map$, @x, @y, BL_PC);
	.@t = rand(getarraysize(.item_id));
	callfunc "F_ShuffleNumbers", 0, .@t, .@id;
	callfunc "F_ShuffleNumbers", 0, .@t, .@qt;
	for ( .@i = 0; .@i < .@t; .@i++ )
		makeitem .item_id[.@id[.@i]], .item_qty[.@qt[.@i]], @map$, @x, @y;
	monster "jupe_ele",0,0,"--ja--",1004,1,strnpcinfo(0)+"::OnDropping";
	end;  
}

 

I was using annieruru's number shuffler function because it is reliable (at least for me)

Edited October 29, 2022 by RagEmp

[Desryuu]

Hi @RagEmp

  Thank you so much for your help! The different items dropped in the array list are not duplicated, which is perfect, but, the amounts of each item are not relational based in the order the array, and the amount should be also random from (1 to 25 for 501 , 1 to 5 for 645 and 1 to 30 for 533).

 

Can you help me?

[Emistry]

// -- This function was originally from Annieruru
function	script	F_ShuffleNumbers	{
	deletearray getarg(2);
	.@static = getarg(0);
	.@range = getarg(1) +1 - .@static;
	.@count = getarg(3, .@range);
	if (.@range <= 0 || .@count <= 0)
		return 0;
	if (.@count > .@range)
		.@count = .@range;
	for (.@i = 0; .@i < .@range; ++.@i)
		.@temparray[.@i] = .@i;
	for (.@i = 0; .@i < .@count; ++.@i) {
		.@rand = rand(.@range);
		set getelementofarray( getarg(2), .@i ), .@temparray[.@rand] + .@static;
		.@temparray[.@rand] = .@temparray[--.@range];
	}
	return .@count;
}

-	script	Dropped	-1,{
OnInit:
	setarray .item_id, 501, 645, 533; // Possible items to receive (ID, amount)
	setarray .item_qty, 25, 5, 30;
	.item_id_size = getarraysize(.item_id);
	end;

OnDropping:
	getmapxy(.@map$, .@x, .@y, BL_PC);
	.@t = rand(.item_id_size);
	callfunc "F_ShuffleNumbers", 0, .@t, .@id;
	for ( .@i = 0; .@i < .@t; .@i++ )
		makeitem .item_id[.@id[.@i]], rand(1, .item_qty[.@id[.@i]]), .@map$, .@x, .@y;
	end;  
}


jupe_ele,0,0	monster	Boss	1004,1,5000,0,"Dropped::OnDropping"

use the monster keep respawn, you can consider use the permanent monster spawn script instead.

[RagEmp]

1 hour ago, Desryuu said:

Can you help me?

@Emistry already fixed it for you.

[Desryuu]

Hey @Emistry! It works like a charm! Thanks a lot!

Thanks to you too @RagEmp

Just a final request: how can I condition/limit the number of different items drop in the list? If I include 3 possible different items, I would like to set it manually to 2 (1 to 2).

Thanks!!

[RagEmp]

4 minutes ago, Desryuu said:

Hey @Emistry! It works like a charm! Thanks a lot!

Thanks to you too @RagEmp

Just a final request: how can I condition/limit the number of different items drop in the list? If I include 3 possible different items, I would like to set it manually to 2 (1 to 2).

Thanks!!

 

Change these:

	.item_id_size = getarraysize(.item_id);

----------------------------------------------------------

	.@t = rand(.item_id_size);
	callfunc "F_ShuffleNumbers", 0, .@t, .@id;
	for ( .@i = 0; .@i < .@t; .@i++ )

To these:

	.item_id_size = 1; // To how ever much you want to put

----------------------------------------------------------

	//.@t = rand(.item_id_size);
	callfunc "F_ShuffleNumbers", 0, .@t, .@id;
	for ( .@i = 0; .@i < .item_id_size; .@i++ )