send array through callfunc, it is possible?

[RagnaDev]

Hi, Im trying to send an array using callfunc but I only got the first value. I tried several ways like

- using functions inside same npc

- getting the array value from inside the function with getvariableofnpc

my example:

OnInit:
setarray .items[0],1,2,3,4,5;

...
  
callfunc("MyFunction",.items);

...
  
function	script	MyFunction	{
  
  setarray .@itemsTemp, getarg(0);
  
  for(.@i = 0 ; .@i < getarraysize(.@itemsTemp) ; .@i++)
  {
   	mes "Item: " + .@itemsTemp[.@i];
  }
  
  return;
}

...
  
Output:

Item: 1
  
  
forcing "for" with a fixed number will Output:

Item: 1
Item: null
Item: null
Item: null

 

It is possible? Or should I rethink my NPC behaviour? THanks

Edited March 2, 2020 by Kota

[Emistry]

you can do it these ways

function	script	MyFunction1	{
	.@size = getarraysize(getarg(0));
	for (.@i = 0; .@i < .@size; .@i++)	
		mes "array_1["+.@i+"] = "+getelementofarray(getarg(0), .@i);
	return;
}

function	script	MyFunction2	{
	.@size = getarraysize(getarg(0));
	copyarray .@new_array, getarg(0), .@size;
	for (.@i = 0; .@i < .@size; .@i++)	
		mes "array_2["+.@i+"] = "+.@new_array[.@i];
	return;
}

 

Sample

-	script	sample	-1,{
	OnInit:
		sleep 3000;
		setarray .items_1,1,2,3,4,5;
		callfunc("MyFunction1",.items_1);
		
		setarray .items_2,10,20,30,40,50,60,70;
		callfunc("MyFunction2",.items_2);
		
		end;
}

Output

[Debug]: array_1[0] = 1
[Debug]: array_1[1] = 2
[Debug]: array_1[2] = 3
[Debug]: array_1[3] = 4
[Debug]: array_1[4] = 5

[Debug]: array_2[0] = 10
[Debug]: array_2[1] = 20
[Debug]: array_2[2] = 30
[Debug]: array_2[3] = 40
[Debug]: array_2[4] = 50
[Debug]: array_2[5] = 60
[Debug]: array_2[6] = 70

 

[RagnaDev]

Well.. is now fixed, not an elegant solution but it works. Changed array to string, then...  explode + atoi magic.