Script @cart

[Motoharo]

Could someone help me create an NPC that uses the @cart command for the player to choose between the 1 ~ 12 appearance of the carts?

[pajodex]

Or you can enable the use of @cart to players instead

[Motoharo]

10 hours ago, pajodex said:

Or you can enable the use of @cart to players instead

Yes, but I want to choose a cost

[pajodex]

// Note: the character needs to have the skill MC_PUSHCART to gain a cart
prontera,149,180,0	script	Cart Select	100,{
	// zeny cost of cart.
	setarray .@cart_cost[1],
		100, // cart 1
		200,
		300,
		400,
		500,
		600,
		700,
		800,
		900,
		1000,
		1100,
		1200; // cart 12
	if (!checkcart()) {
		mes "You must have a cart.";
		close;
	}
	mes "Choose a cart:";
	next;
	.@menu$ = "";
	for (.@i=1; .@i<13; .@i++) {
		.@menu$ += "Cart #"+.@i;
		.@menu$ += ":";
	}
	.@s = select(.@menu$);
	mes "You selected Cart #"+ .@s;
	mes " ";
	mes "Cost price is "+ F_InsertComma(.@cart_cost[.@s]) +"z.";
	next;
	if(select("Yes","No")==2) close;
	if (Zeny < .@cart_cost[.@s]) {
		mes "Not enough zeny,";
		close;
	}
	Zeny -= .@cart_cost[.@s];
	setcart .@s;
	mes "Goodluck!";
	close;
}