How many itens in the server

[Profile]

Hi all, I would like to request a script which any player can input an item ID and it will tell him how many of that item exists in the entire server. (sum of inventory, cart, storage, gstorage and equipped itens).

For example, user inputs id 607 (Yggdrasil Berry).

NPC will show the player how many Yggdrasil Berry exists in the entire server from all players.

Thank you!

[AnnieRuru]

function	script	F_MesItemInfo	{
	.@item = getarg(0);
	.@itemname$ = getitemname(.@item);
	if (.@itemname$ != "null") {
		.@itemslot = getitemslots(.@item);
		if (.@itemslot)
			.@itemname$ = sprintf("%s [%d]", .@itemname$, .@itemslot);
	}
	else
		.@itemname$ = "Unknown Item";
	return sprintf("<ITEM>%s<INFO>%d</INFO></ITEM>", .@itemname$, .@item);
}

prontera,155,185,5	script	kjdhfkshfj	1_F_MARIA,{
	input .@itemid;
	if ( getitemname(.@itemid) == "null" ) {
		mes "invalid item";
		close;
	}
	query_sql "select "+
		        "ifnull((select sum(amount) from inventory where nameid = "+ .@itemid +"), 0) + "+
		        "ifnull((select sum(amount) from cart_inventory where nameid = "+ .@itemid +"), 0) + "+
		        "ifnull((select sum(amount) from storage where nameid = "+ .@itemid +"), 0) + "+
		        "ifnull((select sum(amount) from guild_storage where nameid = "+ .@itemid +"), 0) + "+
		        "ifnull((select sum(amount) from mail_attachments where nameid = "+ .@itemid +"), 0)"
			  , .@sum;
	mes F_MesItemInfo(.@itemid) +" has total amount of "+ .@sum +" in the entire server";
	close;
}

 

[Profile]

Thank you Annie! You rock!