script_rid2sd: fatal error ! HELP!

[caspa]

hi guys i just want to ask what causes this type of behavior to my script? can't seem to find out..

by the way some of this script were modified based on the original poster and so if the script doesnt have any script creator name. its because i copied it like that already and just modified the npc names and etc. 

fast type event

 
	poring_c01,107,90,3    script    Fast-Type Event    488,{
if(getgmlevel() >= 60) callsub L_GM;
if( !.Event ) { 
    mes "[ Fast-Type Event ]";
    mes "^777777Status^000000 : ^ff0000OFFLINE^000000";
    mes "   ";
    mes "^777777Event Info^000000 :";
    mes "Whoever enters the highlighted code first, wins the prize.";
    mes "^777777Event Rounds^000000 : ^0000ff5^000000";
    mes "^777777Event Prize^000000 : ^0000ff4x Event Cards^000000";
    
} else if ( .String$ == "A" ) {
    mes "[ Fast-Type Event ]";
    mes "^ff0000The round has already ended.^000000";
} else {
    mes "[ Fast-Type Event ]";
    mes "       ";
    mes "Input ^0000ffCode Strings^000000 :";
    mes " • ^CC00CC" + .String$ + "^000000 •";
    mes "^ffac26¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯^000000";
    input .@Type$;
    if( .String$ == "A" ) {
	        mes "^ff0000ERROR^000000 : You were too slow.";
        close;
    }
    if ( .String$ == .@Type$ && .Event ) {
	        mes "^00cc40Code Strings Correct^000000";
        
        getitem 21017, 4;
        npctalk "'"+strcharinfo(0)+"' typed the correct strings!";
        set .String$, "A";
        set .typeround, .typeround + 1;
        donpcevent "Fast-Type Event::OnStart2";
    } else {
	        mes "^ff0000Code Strings Incorrect^000000";
    }
}
close;
	OnMinute15:
if(.Event) end;
donpcevent "Fast-Type Event::OnStart";
end;
	OnStart:
announce "[Fast-Type Event] : Fast-Type Event will be starting in 10 seconds.",0,0x00FFFF;
sleep2 3000;
announce "[Fast-Type Event] : Click the event area warper, if you want to participate.",0,0x00FFFF;
sleep2 7000;
goto L_Begin;
end;
	L_Begin:
set .Event, 1;
set .String$, "A";
while( getstrlen( .String$ ) < .Length ){
    set .String$,.String$ + .List$[ rand( getarraysize( .List$ ) ) ];
}
announce "[Fast-Type Event] : The event has started.",0,0x00FFFF;
end;
	OnStart2:
sleep2 5000;
if(.typeround == .Rounds) {
    if(!.Event) end;
    announce "[Fast-Type Event] : The event has ended.",bc_map,0x00FFFF;
    set .Event, 0;
    set .typeround, 0;
    end;
}
if(!.Event) end;
announce "[Fast-Type Event] : Next round starts in 5 seconds.",bc_map,0x00FFFF;
sleep2 5000;
if(!.Event) end;
goto L_Begin;
	L_GM:
mes "[ Fast-Type Event ]";
mes "Fast-Type Event :" + (.Event?"^009900 ON^000000":"^FF0000 OFF^000000");
mes "Turn it" + (!.Event?"^009900 ON^000000":"^FF0000 OFF^000000") +"?";
next;
if(select((!.Event?"Turn ^009900ON^000000":"Turn ^ff0000OFF^000000") + " Event^000000","Normal Player") == 2) return;
switch(.Event) {
    case 1:
        set .Event, 0;
        set .typeround, 0;
        set .String$, "A";
        announce "[Fast-Type Event] : A GM has ended the event.",0,0x00FFFF;
        break;
    default: 
        donpcevent "Fast-Type Event::OnStart";
}
close;
OnInit:
set .Length,10;
set .Rounds,5;
setarray .List$,"a","B","c","D","e","F","g","H","i","J","k","L","m","N","o","P","q","R","s","T","u","V","w","X","y","Z","1","2","3","4","5","6","7","8","9","0";
end;
}

find the mushroom event (original)
find the plants event ( modified )
 

 
	//===== rAthena Script ======================================= 
//= Find the Mushroom
//===== By: ================================================== 
//= Mysterious
//===== Current Version: ===================================== 
//= 3.6a
//===== Compatible With: ===================================== 
//= rAthena Project
//===== Description: ========================================= 
//= Find the Mushroom - random amount of Mushrooms spawns in random maps.
//= Players need to find these mushrooms and kill them to gain prizes!
//===== Additional Comments: =================================
//= 3.0 Fully Functional with Rewritten script. [Mysterious]
//= 3.6a Slightly edited. [Euphy]
//============================================================ 
	poring_c01,101,114,5    script    Find the Plant#plant    524,{
    if ( .plantstatus )
            end;
     else {
	        mes "[ Find the Plant ]";
        mes "^777777Status^000000 : ^ff0000OFFLINE^000000";
        mes "   ";
        mes "^777777Event Info^000000 :";
        mes "Find and kill the plants to win the prize.";
        mes "^777777Event Prize^000000 : ^0000ff5x Event Card";
    }
    if (.plantstatus || getgmlevel() < .GM) close;
    next;
    mes "[ Find the Plant ]";
    mes "Start the event?";
    next;
    if(select("No:Yes") == 1) close;
    donpcevent strnpcinfo(0)+"::OnMinute22";
    mes "[ Find The Plants ]";
    mes "   ";
    mes "^009900*Event Started*^000000";
    close;
	OnInit:
    set .Prize,21017;    // Reward item ID
    set .Amount,5;    // Reward item amount
    set .GM,80;    // GM level required to access NPC
    setarray .Maps$[0],"poring_c01"; // Possible maps
    end;
	OnMinute22:    // Start time (every hour)
if ( .plantstatus ) end;
announce "[Minor Event] : Find the Plant event is starting within 1 minute in the event area.",0,0x00FFFF;
sleep 30000;
announce "[Minor Event] : Find the Plant event is starting within 30 seconds in the event area.",0,0x00FFFF;
sleep 20000;
announce "[Minor Event] : Find the Plant event is starting within 10 seconds, Please hurry if you want to join.",0,0x00FFFF;
sleep 10000;
announce "[Minor Event] : Find the Plant event has started.",0,0x00FFFF;
    set .plantstatus,1;
    set .spawnplant,rand(2,3);    // How many Mushrooms should spawn?
    set .Map$,.Maps$[rand(getarraysize(.Maps$))];
    killmonster .Map$,"All";
    monster .Map$,0,0,"[Event] Plant",1083,.spawnplant,strnpcinfo(0)+"::OnMobKilled";
    announce "[Find the Plant] : "+.spawnplant+" plants have been spawned in the event area.",bc_map,0x00FFFF;
    sleep 5000;
    announce "[Find the Plant] : Every plants you kill will give you 5x "+getitemname(.Prize)+".",bc_map,0x00FFFF;
    end;
OnMobKilled:
    set .spawnplant, .spawnplant - 1;
    getitem .Prize, .Amount;
    if (.spawnplant) announce "[Find the Plants] : '"+strcharinfo(0)+"' has killed a plant, "+.spawnplant+" more to go.",bc_map,0x00FFFF;
    else {
        announce "[Minor Event] : Find the Plant event has ended, All the plants have been killed.",bc_map,0x00FFFF;
        set .plantstatus,0;
    }
    end;
}

Edited June 5, 2018 by caspa

[AnnieRuru]

announce "[Fast-Type Event] : Next round starts in 5 seconds.",bc_map,0x00FFFF;
	---- Change into ---->
announce "[Fast-Type Event] : Next round starts in 5 seconds.",bc_map|bc_npc,0x00FFFF;

almost all of it needs to add bc_npc flag for the 1st script

 

2nd script however need to use mapannounce, since the monster spawn in other maps

announce "[Find the Plant] : "+.spawnplant+" plants have been spawned in the event area.",bc_map,0x00FFFF;
	------ Change into ----->
mapannounce .Map$, "[Find the Plant] : "+.spawnplant+" plants have been spawned in the event area.", bc_map, 0x00FFFF;

 

Edited June 5, 2018 by AnnieRuru

[caspa]

8 minutes ago, AnnieRuru said:

announce "[Fast-Type Event] : Next round starts in 5 seconds.",bc_map,0x00FFFF;
	---- Change into ---->
announce "[Fast-Type Event] : Next round starts in 5 seconds.",bc_map|bc_npc,0x00FFFF;

almost all of it needs to add bc_npc flag for the 1st script

 

2nd script however need to use mapannounce, since the monster spawn in other maps

mapannounce .Map$, "[Find the Plant] : "+.spawnplant+" plants have been spawned in the event area.", bc_map, 0x00FFFF;

[SOLVED] thank you so much ms. annie  LOVE LOTS!!