R>goldroom with bot check

[RARM]

can i request gold room like this?

1.TALK to NPC but npc will have a bot check, if player gets it wrong the npc uses command @kick<player name>

2. Paid]-200k: Npc will warp the player in gold room. 

3. mob example: Gold Peco - if you kill a peco it will give you a points it will random 1-5 points per Gold Peco. 

4. disable @go/@warp commands or butterfly wing there will be a warper to return in the city.

5. PVP on if someone kill you your points will be gone.

6. if you warp and get back alive in the city you can exchange your points into Gold.

 

Hopefully someone can help me with this solution and thank you 

[fTakano]

prontera,155,180,4	script	Gold Room#tst	100,{
	mes "What do you want?";
	next;
	switch(select("Enter Gold Room.:Exchange Points:Cancel")) {
		case 1:
			@str$ = "";
			mes "Make sure to type the strings correctly.";
			mes "Fee: ^FF0000"+F_InsertComma(.zeny)+" Z^000000";
			for( .@i=0; .@i<.strLen; .@i++ )
				@str$ += charat(.charSet$, rand(0, getstrlen(.charSet$)));
			mes "Passcode : ^FF0000"+@str$+"^000000";
			next;
			input .@txt$;
			if( .@txt$ != @str$ ) {
				mes "You will be kicked.";
				close2;
				atcommand "@kick "+strcharinfo(0);
				end;
			} else {
				if( Zeny < .zeny ) {
					mes "Sorry, but you can't enter the room.";
					close;
				} else {
					@str$ = "";
					Zeny -= .zeny;
					warp "ordeal_1-1",0,0;
					end;
				}
			}
			break;
			
		case 2:
			if( !#goldPoint ) {
				mes "Don't have enough Gold Points to exchange.";
				close;
			}
			mes "You currently have "+F_InsertPlural(#goldPoint, "Gold Point")+".";
			mes "Do you want to exchange them all or decide on how many you will exchange?";
			next;
			switch(select("Exchange all of my Gold Points:Decide on how many will I exchange:Cancel")) {
				case 1:
					if(!checkweight(969,#goldPoint)) {
						mes "Sorry, you can't carry these gold bars.";
						close;
					} else {
						getitem 969,#goldPoint;
						#goldPoint = 0;
						mes "Here's your gold bars.";
						mes "You currently have "+F_InsertPlural(#goldPoint, "Gold Point")+".";
						close;
					}
					break;
					
				case 2:
					mes "Input how many gold points will you get.";
					next;
					input .@gpoint,0,30000;
					if( .@gpoint > #goldPoint ) {
						mes "Sorry, you don't have enough gold points to exchange.";
						close;
					} else {
						if(!checkweight(969,.@gpoint)) {
							mes "Sorry, you can't carry these gold bars.";
							close;
						} else {
							getitem 969, .@gpoint;
							#goldPoint -= .@gpoint;
							mes "Here's your gold bars.";
							mes "You currently have "+F_InsertPlural(#goldPoint, "Gold Point")+".";
							close;
						}
					}
					break;
					
				default:
					goto L_Quit;
					break;
			}
			close;
			break;
			
		default:
			goto L_Quit;
			break;
	}
	L_Quit:
		close;
		end;
	
	OnInit:
		.charSet$ = "0123456789abcdefghijkmnopqrstuvwxyzABCDEFGHJKLMNOPQRSTUVWXYZ";
		.strLen = 10;		// Sets how many characters for the generated confirmation code.
		.zeny = 200000;		// Entrance fee for the room
		end;
}

ordeal_1-1,150,150,4	script	Exit	100,{
	mes "Want to go out?";
	if( select("Yes:No") == 2 ) close;
	else {
		warp "SavePoint",0,0;
		end;
	}
}


-	script	gold_room	-1,{
	OnInit:
		.mob_id = 1002;		// Monster ID for the Gold Room mobs
		monster "ordeal_1-1",0,0,"Golden Peco",.mob_id,100,strnpcinfo(0)+"::OnKilled";
		end;
		
	OnKilled:
		.ppk = rand(1,5);		// Points per kill
		#goldPoint += .ppk;
		dispbottom "-- Gold Point Information --";
		dispbottom "You have acquired "+F_InsertPlural(.ppk,"Gold Point")+".";
		dispbottom "You have currently have "+F_InsertPlural(#goldPoint,"Gold Point")+".";
		monster "ordeal_1-1",0,0,"Golden Peco",.mob_id,1,strnpcinfo(0)+"::OnKilled";
		end;
		
	OnPCDieEvent:
		if( strcharinfo(3) == "ordeal_1-1" ) {
			#goldPoint = 0;
			dispbottom "Sorry, but all of the Gold Points you have earned has vanished.";
		}
		end;
}

ordeal_1-1	mapflag	pvp_noparty
ordeal_1-1	mapflag	pvp_noguild
ordeal_1-1	mapflag	nowarp
ordeal_1-1	mapflag	noreturn
ordeal_1-1	mapflag	noteleport

 

[RARM]

Thank you