MVP Party Script

[ValkRO]

Hello rAthena. Can you guys edit this script to make it all of the party members receive two rewards not randomly? its scripted by Annie thank you in advance

-	script	jfksdhfkjs	-1,{
OnNPCKillEvent:
if ( !getmonsterinfo( killedrid, MOB_MVPEXP ) ) end;
if ( getcharid(1) ) {
	getpartymember getcharid(1), 1;
	getpartymember getcharid(1), 2;
	for ( .@i = 0; .@i < $@partymembercount; .@i++ ) {
		if ( isloggedin( $@partymemberaid[.@i], $@partymembercid[.@i] ) ) { // what happens if someone in the party member is offline =/
			.@partymemberaid[.@c] = $@partymemberaid[.@i];
			.@c++;
		}
	}
	getitem 607, 3, .@partymemberaid[ rand( .@c ) ];
	announce "Party ["+ strcharinfo(1) +"] has killed "+ getmonsterinfo( killedrid, MOB_NAME ) +" at "+ strcharinfo(3), 0;
}
else {
	getitem 607, 3;
	announce "Player ["+ strcharinfo(0) +"] has killed "+ getmonsterinfo( killedrid, MOB_NAME ) +" at "+ strcharinfo(3), 0;
}
end;
}

[Sryx]

	for ( .@i = 0; .@i < $@partymembercount; .@i++ ) {
		if ( isloggedin( $@partymemberaid[.@i], $@partymembercid[.@i] ) ) { // what happens if someone in the party member is offline =/
			.@partymemberaid[.@c] = $@partymemberaid[.@i];
            		getitem 607, 3, $@partymemberaid[.@i];                                
			.@c++;
		}
	}
	

Try this.

[Technoken]

Try

-	script	jfksdhfkjs	-1,{
OnNPCKillEvent:
if ( !getmonsterinfo( killedrid, MOB_MVPEXP ) ) end;
if ( getcharid(1) ) {
	getpartymember getcharid(1), 1;
	getpartymember getcharid(1), 2;
	for ( .@i = 0; .@i < $@partymembercount; .@i++ ) {
		if ( !isloggedin( $@partymemberaid[.@i], $@partymembercid[.@i] ) ) // what happens if someone in the party member is offline =/
			continue;
		getitem 607, 3, $@partymemberaid[.@i];
	}
	announce "Party ["+ strcharinfo(1) +"] has killed "+ getmonsterinfo( killedrid, MOB_NAME ) +" at "+ strcharinfo(3), 0;
}
else {
	getitem 607, 3;
	announce "Player ["+ strcharinfo(0) +"] has killed "+ getmonsterinfo( killedrid, MOB_NAME ) +" at "+ strcharinfo(3), 0;
}
end;
}