Jump to content
  • 0

ALL IN ONE NPC had issues. Ori script from Euphy


crystalro

Question


  • Group:  Members
  • Topic Count:  18
  • Topics Per Day:  0.00
  • Content Count:  42
  • Reputation:   0
  • Joined:  03/10/12
  • Last Seen:  

8bc8ddef60ea34b78bea7e1c761810a3.png

//===== eAthena Script =======================================
//= All-in-One NPC
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.3
//===== Description: =========================================
//= A compilation of commonly-used NPC scripts.
//== Includes job changer, stylist, refiner, card remover,
//== coin exchanger, rentals, resetter, platinum skills,
//== sex changer, identifier, healer, buffer, and repairman.
//============================================================

prontera,164,174,4    script    ALL IN ONE    531,{
function Get_Platinum; function Equip_Menu;

    if (getarraysize(.OnClick)) {
        if (.OnClick[0]) { specialeffect2 313; percentheal 100,100; }
        if (.OnClick[1]) { specialeffect2 42; sc_start SC_BLESSING,600000,10; specialeffect2 37; sc_start SC_INCREASEAGI,600000,10; }
        if (.OnClick[2] && getbrokenid(1)) { specialeffect2 101; atcommand "@repairall"; } }
    set .@menu$,"";
    for (set .@i,0; .@i < getarraysize(.MainMenu$); set .@i,.@i+1) {
        if (.MenuOption & pow(2,.@i))
            set .@menu$, .@menu$+" ~ "+.MainMenu$[.@i];
        set .@menu$, .@menu$+":"; }
    switch(select(.@menu$)) {
        case 1:
            function Job_Menu; function A_An;
            if (checkfalcon() || checkcart() || checkriding()) {
                message strcharinfo(0),"Please remove your "+((checkfalcon())?"falcon":"")+((checkcart())?"cart":"")+((checkriding())?"Peco":"")+" before proceeding.";
                close; }
            if (.SkillPointCheck && SkillPoint) { message strcharinfo(0),"Please use all your skill points before proceeding."; close; }
            if (Class > 6 && Class < 22) {
                if (BaseLevel < .Rebirth[0] || JobLevel < .Rebirth[1]) {
                    set .@blvl, .Rebirth[0]-BaseLevel; set .@jlvl, .Rebirth[1]-JobLevel;
                    message strcharinfo(0),"You need "+((.@blvl>0)?.@blvl+" more base levels "+((.@jlvl>0)?"/ ":""):"")+((.@jlvl>0)?.@jlvl+" more job levels ":"")+"to rebirth.";
                    close; }
                message strcharinfo(0),"Change into a High Novice?";
                if(select(" ~ ^0055FFRebirth^000000: ~ ^777777Cancel^000000")==2) close;
                jobchange 4001; resetlvl(1); specialeffect2 432;
                close; }
            set .@eac, eaclass();
            set .@j1, roclass(.@eac|EAJL_2_1); set .@j2,roclass(.@eac|EAJL_2_2);
            if (.@eac&EAJL_2)
                if (.@eac&(EAJL_UPPER|EAJL_BABY) || roclass(.@eac|EAJL_UPPER) == -1) {
                    message strcharinfo(0),"No more jobs are available."; close; }
            if ((.@eac&EAJ_BASEMASK) == EAJ_NOVICE) {
                if( Class == 0 && JobLevel < .JobReq[0] ) Job_Menu(1,4023);
                else if (JobLevel < .JobReq[0]) message strcharinfo(0),"A job level of "+.JobReq[0]+" is required to change into the 1st Class.";
                else switch(Class) {
                    case 0: Job_Menu(11,1,2,3,4,5,6,23,4046,24,25,4023);
                    case 4001: Job_Menu(6,4002,4003,4004,4005,4006,4007);
                    case 4023: Job_Menu(7,4024,4025,4026,4027,4028,4029,4045);
                    default: message strcharinfo(0),"An error has occurred."; break; }
                close; }
            if (roclass(.@eac|EAJL_2_1) == -1 || roclass(.@eac|EAJL_2_2) == -1) {
                message strcharinfo(0),"No more jobs are available."; close; }
            if (!(.@eac&EAJL_2) && JobLevel < .JobReq[1]) { message strcharinfo(0),"A job level of "+.JobReq[1]+" is required to change into the 2nd Class."; close; }
            Job_Menu(2,.@j1,.@j2);
            end;
            function Job_Menu {
                set .@menu$,"";
                for(set .@i,1; .@i<=getarg(0); set .@i,.@i+1)
                    set .@menu$, .@menu$+" ~ "+jobname(getarg(.@i))+":";
                set .@menu$, .@menu$+" ~ ^777777Cancel^000000";
                while(1) {
                    set .@i, getarg(select(.@menu$),0);
                    if (!.@i) close;
                    if ((.@i == 23 || .@i == 4045) && BaseLevel < .SNovice) {
                        message strcharinfo(0),"A base level of "+.SNovice+" is required to turn into a Super "+((.@i==23)?"Novice":"Baby")+"."; }
                    else if (select(" ~ Change into ^0055FF"+jobname(.@i)+"^000000 class: ~ ^777777Go back^000000")==1) {
                        message strcharinfo(0),"Became "+A_An(jobname(.@i))+"!";
                        jobchange .@i; specialeffect2 338;
                        if (.Platinum) Get_Platinum;
                        close; }
                } end; }
            function Get_Platinum {
                skill 142,1,0;
                switch(BaseClass) {
                    case 0: if (Class !=23) skill 143,1,0; break;
                    case 1: skill 144,1,0; skill 145,1,0; skill 146,1,0; break;
                    case 2: skill 157,1,0; break;
                    case 3: skill 147,1,0; skill 148,1,0; break;
                    case 4: skill 156,1,0; break;
                    case 5: skill 153,1,0; skill 154,1,0; skill 155,1,0; break;
                    case 6: skill 149,1,0; skill 150,1,0; skill 151,1,0; skill 152,1,0; break;
                    default: break; }
                switch(roclass(eaclass()&EAJ_UPPERMASK)) {
                    case 7: skill 1001,1,0; break;
                    case 8: skill 1014,1,0; break;
                    case 9: skill 1006,1,0; break;
                    case 10: skill 1012,1,0; skill 1013,1,0; break;
                    case 11: skill 1009,1,0; break;
                    case 12: skill 1003,1,0; skill 1004,1,0; break;
                    case 14: skill 1002,1,0; break;
                    case 15: skill 1015,1,0; skill 1016,1,0; break;
                    case 16: skill 1007,1,0; skill 1008,1,0; skill 1017,1,0; skill 1018,1,0; skill 1019,1,0; break;
                    case 17: skill 1005,1,0; break;
                    case 18: skill 238,1,0; break;
                    case 19: skill 1010,1,0; break;
                    case 20: skill 1011,1,0; break;
                    default: break; }
                return; }
            function A_An {
                setarray .@A$[0],"a","e","i","o","u";
                set .@B$, "_"+getarg(0);
                for(set .@i,0; .@i<5; set .@i,.@i+1)
                    if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
                return "a "+getarg(0); }
        case 2:
            setarray .@Look[1],7,1,6;
            set .@s, select(" ~ Cloth color: ~ Hairstyle: ~ Hair color");
            set .@Revert, getlook(.@Look[.@s]); set .@Style,1;
            while(1) {
                setlook .@Look[.@s], .@Style;
                message strcharinfo(0),"This is style #"+.@Style+".";
                set .@menu$, " ~ Next (^0055FF"+((.@Style!=.Styles[.@s])?.@Style+1:1)+"^000000): ~ Previous (^0055FF"+((.@Style!=1)?.@Style-1:.Styles[.@s])+"^000000): ~ Jump to...: ~ Revert to original (^0055FF"+.@Revert+"^000000)";
                switch(select(.@menu$)) {
                    case 1: set .@Style, ((.@Style!=.Styles[.@s])?.@Style+1:1); break;
                    case 2: set .@Style, ((.@Style!=1)?.@Style-1:.Styles[.@s]); break;
                    case 3: message strcharinfo(0),"Choose a style between 1 - "+.Styles[.@s]+".";
                        input .@Style,0,.Styles[.@s];
                        if (!.@Style) set .@Style, rand(1,.Styles[.@s]);
                        break;
                    case 4: set .@Style, .@Revert; setlook .@Look[.@s], .@Revert; break; }
            } end;
        case 3:
            function Refine_Item;
            if (.EnrichedRefine)
                if (select(" ~ Normal Refiner: ~ Enriched Refiner")==2) {
                    Equip_Menu(1);
                    setarray .@Materials[0],7619,7620,7620,7620,7620;
                    setarray .@Safe[0],4,7,6,5,4;
                    set .@WLv, getequipweaponlv(@i);
                    message strcharinfo(0),"Item: +"+getequiprefinerycnt(@i)+" "+getequipname(@i);
                    if(select(" ~ Refine item (2 * ^0055FF"+getequippercentrefinery(@i)+"^000000% success): ~ ^777777Cancel^000000")==2) close;
                    Refine_Item(1, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv], 1);
                    close; }
            Equip_Menu(1);
            setarray .@Materials[0],985,1010,1011,984,984;
            setarray .@Safe[0],4,7,6,5,4;
            set .@WLv, getequipweaponlv(@i);
            set .@SafeCount, .@Safe[.@WLv]-getequiprefinerycnt(@i);
            message strcharinfo(0),"Item: +"+getequiprefinerycnt(@i)+" "+getequipname(@i);
            switch(select(" ~ Refine once (^0055FF"+getequippercentrefinery(@i)+"^000000% success): ~ Refine multiple times (up to "+(10-getequiprefinerycnt(@i))+"): ~ Refine to safe limit ("+((.@SafeCount>0)?.@SafeCount+" refines":"^777777disabled^000000")+"): ~ ^777777Cancel^000000")) {
                case 1: Refine_Item(1, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]); close;
                case 2:
                    input .@Refines;
                    if (.@Refines+getequiprefinerycnt(@i) > 10 || .@Refines < 1) message strcharinfo(0),"Invalid number ("+.@Refines+").";
                    else Refine_Item(.@Refines, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]);
                    close;
                case 3:
                    if (.@SafeCount < 1) message strcharinfo(0),"The item has already reached the safe limit.";
                    else Refine_Item(.@SafeCount, .@Materials[.@WLv], .RP[.@WLv], .@Safe[.@WLv]);
                    close;  
                case 4: close; }
            function Equip_Menu {
                setarray .@pos$[1],"Upper Headgear","Armor","Left hand","Right hand","Garment","Footgear","Left Accessory","Right Accessory","Mid Headgear","Lower Headgear";
                set .@menu$,"";
                for (set .@i,1; .@i <= 10; set .@i,.@i+1) {
                    if (getequipisequiped(.@i))
                        set .@menu$, .@menu$+.@pos$[.@i]+" [^0055FF"+getequipname(.@i)+"^000000]";
                    set .@menu$, .@menu$+":"; }
                set @i, select(.@menu$);
                if (!getequipisequiped(@i)) { message strcharinfo(0),"Nothing is equipped there!"; close; }
                if (getarg(0)) {
                    if (!getequipisenableref(@i)) { message strcharinfo(0),getequipname(@i)+" cannot be refined."; close; }
                    if (getequiprefinerycnt(@i) >= 10 ) { message strcharinfo(0),"+"+getequiprefinerycnt(@i)+" "+getequipname(@i)+" cannot be refined any further."; close; } }
                return; }
            function Refine_Item {
                message strcharinfo(0),"I'll need "+getarg(0)+"x "+getitemname(getarg(1))+" and "+getarg(0)*getarg(2)+" Zeny.";
                if (countitem(getarg(1)) < getarg(0) || Zeny < getarg(0)*getarg(2)) {
                    sleep2 500; message strcharinfo(0),"Come back when you have the required materials."; close; }
                if (getequiprefinerycnt(@i)+getarg(0) > getarg(3)) {
                    sleep2 500; message strcharinfo(0),"The item will be refined above the safe limit. It may break."; }
                sleep2 500;
                if(select(" ~ ^0055FFContinue^000000: ~ ^777777Cancel^000000")==2) close;
                set .@j, getarg(0);
                while(.@j) {
                    delitem getarg(1), 1;
                    set Zeny, Zeny-getarg(2);
                    if (getarg(4,0)) {
                        if (getequippercentrefinery(@i) <= rand(100) && getequippercentrefinery(@i) <= rand(100)) {
                            message strcharinfo(0),getequipname(@i)+" broke while refining."; failedrefitem @i; close; } }
                    else {
                        if (getequippercentrefinery(@i) <= rand(100)) {
                            message strcharinfo(0),getequipname(@i)+" broke while refining."; failedrefitem @i; close; } }
                    successrefitem @i;
                    set .@j, .@j-1; }
                message strcharinfo(0),"All done!";
                close; }
        case 4:
            if (.Prices[0]) message strcharinfo(0),"It costs "+.Prices[0]+" Zeny to remove cards.";
            Equip_Menu(0);
            if (Zeny < .Prices[0]) { message strcharinfo(0),"You don't have enough Zeny."; close; }
            set .@j,getequipcardcnt(@i);
            if (!.@j) { message strcharinfo(0),"There are no cards compounded to "+getequipname(@i)+"."; close; }
            if (!checkweight(4001,(.@j+1))) { message strcharinfo(0),"You're carrying too many items!"; close; }
            message strcharinfo(0),"Item: "+getequipname(@i);
            if (select(" ~ Remove "+.@j+" card(s): ~ ^777777Cancel^000000")==2) close;
            set Zeny, Zeny-.Prices[0];
            successremovecards @i;
            message strcharinfo(0),"Cards successfully removed!";
            close;
        case 5:
            message strcharinfo(0),"Coins are worth "+.Coin[1]+" Zeny each.";
            switch(select(" ~ Zeny to coins: ~ Coins to Zeny: ~ Close")) {
                case 1:
                    message strcharinfo(0),"How many coins do you want?";
                    input .@coins,0,(1000000000/.Coin[1]);
                    if (.@coins*.Coin[1] > Zeny) { message strcharinfo(0),"You don't have enough Zeny."; close; }
                    if (!checkweight(.Coin[0],.@coins)) { message strcharinfo(0),"You don't have enough inventory space."; close; }
                    set Zeny, Zeny-(.Coin[1]*.@coins);
                    getitem .Coin[0], .@coins;
                    message strcharinfo(0),"Purchased "+.@coins+" coins.";
                    close;
                case 2:
                    message strcharinfo(0),"How many coins do you want to trade in?";
                    input .@coins,0,(1000000000/.Coin[1]);
                    if (countitem(.Coin[0]) < .@coins) { message strcharinfo(0),"You don't have that many coins!"; close; }
                    if ((Zeny+(.Coin[1]*.@coins)) > 1000000000) { message strcharinfo(0),"You have too much Zeny!"; close; }
                    delitem .Coin[0], .@coins;
                    set Zeny, Zeny+(.Coin[1]*.@coins);
                    message strcharinfo(0),"Exchanged "+.@coins+" coins.";
                    close;
                case 3:
                    close; }
        case 6:
            if (.Prices[2]) message strcharinfo(0),"It costs "+.Prices[2]+" Zeny to rent.";
            set .@i, select(" ~ Cart: ~ Falcon: ~ Peco");
            if (Zeny < .Prices[2]) { message strcharinfo(0),"You don't have enough Zeny."; close; }
            if (.@i==1 && !checkcart() && getskilllv(39)) setcart;
            else if (.@i==2 && !checkfalcon() && getskilllv(127)) setfalcon;
            else if (.@i==3 && !checkriding() && getskilllv(63)) setriding;
            else { message strcharinfo(0),"You do not meet skill the requirements to rent."; close; }
            set Zeny, Zeny-.Prices[2];
            close;
        case 7:
            if (.Prices[1]) message strcharinfo(0),"It costs "+.Prices[1]+" Zeny to reset stats or skills.";
            set .@i, select(" ~ Stat reset: ~ Skill reset: ~ Cancel");
            if (.@i==3) close;
            if (Zeny < .Prices[1]) { message strcharinfo(0),"You don't have enough Zeny."; close; }
            set Zeny, Zeny-.Prices[1];
            if (.@i==1) ResetStatus;
            else ResetSkill;
            message strcharinfo(0),((.@i==1)?"Stats":"Skills")+" reset!";
            close;
        case 8:
            Get_Platinum;
            specialeffect2 441;
            message strcharinfo(0),"Platinum skills received!";
            close;
        case 9:
            set .@Var$, ".SexChange"+((Sex)?"F":"M");
            if (getarraysize(getd(.@Var$))) {
                message strcharinfo(0),"To turn into a "+((Sex)?"female":"male")+" you need the following items:";
                sleep2 1000;
                for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2) {
                    message strcharinfo(0),getd(.@Var$+"["+(.@i+1)+"]")+"x "+getitemname(getd(.@Var$+"["+.@i+"]"));
                    if (countitem(getd(.@Var$+"["+.@i+"]")) < getd(.@Var$+"["+(.@i+1)+"]")) set .@nreq,1;
                    sleep2 500; }
                if (.@nreq) close; }
            if(select(" ~ Change into a "+((Sex)?"female":"male")+": ~ Cancel")==2) close;
            if (getarraysize(getd(.@Var$)))
                for(set .@i,0; .@i<getarraysize(getd(.@Var$)); set .@i,.@i+2)
                    delitem getd(.@Var$+"["+.@i+"]"), getd(.@Var$+"["+(.@i+1)+"]");
            changesex;
            end;
        case 10:
            setarray .@Total[0],0,0;
            getinventorylist;
            for(set .@i,0; .@i<@inventorylist_count; set .@i,.@i+1) {
                if (@inventorylist_identify[.@i]) continue;
                if (Zeny < .Prices[3]) {
                    dispbottom "It costs "+.Prices[3]+" to identify an item."; break; }
                set Zeny, Zeny-.Prices[3];
                delitem2 @inventorylist_id[.@i],1,0,0,0,0,0,0,0;
                getitem @inventorylist_id[.@i],1;
                setarray .@Total[0], .@Total[0]+1, .@Total[1]+.Prices[3]; }
            if (!.@Total[0]) { message strcharinfo(0),"No items identified."; close; }
            specialeffect2 154;
            message strcharinfo(0),"Identified "+.@Total[0]+" items"+((.@Total[1])?" for "+.@Total[1]+" Zeny":"")+".";
            close;
    }
OnInit:
       waitingroom "All in 1 NPC",0;
// --------------------- Config ---------------------
    setarray .MainMenu$[0],    // Set menu options!
        "Change Jobs",        // [1]
        "Stylist",        // [2]
        "Refiner",        // [4]
        "Remove Cards",        // [8]
        "Exchange Coins",    // [16]
        "Rentals",        // [32]
        "Reset Stats/Skills",    // [64]
        "Platinum Skills",    // [128]
        "Change Sex",        // [256]
        "Identify All";        // [512]

    set .MenuOption,1|8|32|64|128|512;

    setarray .OnClick[0],0;        // When clicked: heal [0], buff [1], repair [2] (1: yes / 0: no)
    setarray .Styles[1],553,37,250;        // Maximum dye, hair style, and hair color
    setarray .Coin[0],674,100000000;        // Coin item ID, coin price
    setarray .Prices[0],50000,10000,0,100;    // Zeny to remove cards [0], reset [1], rent [2], identify [3]

    setarray .Rebirth[0],99,50;    // Minimum base level, job level to rebirth
    setarray .JobReq[0],10,40;    // Minimum job level to turn into 1st class, 2nd class
    set .SNovice,45;        // Minimum base level to turn into Super Novice
    set .SkillPointCheck,0;        // Force player to use up all skill points? (1: yes / 0: no)
    set .Platinum,1;        // Get platinum skills automatically? (1: yes / 0: no)

    set .EnrichedRefine,1;            // Allow enriched refiner option? (1: yes / 0: no)
    setarray .RP[0],2000,50,200,5000,20000;    // Zeny for armor, lv1, lv2, lv3, lv4 refines

    setarray .SexChangeF[0],7539,100;    // Items to turn into Female (ID,Count)
    setarray .SexChangeM[0],7539,100;    // Items to turn into Male (ID,Count)

// --------------------------------------------------
    end;
}

 

Edited by Emistry
Please use CODEBOX.
Link to comment
Share on other sites

9 answers to this question

Recommended Posts

  • 0

  • Group:  Members
  • Topic Count:  6
  • Topics Per Day:  0.00
  • Content Count:  261
  • Reputation:   53
  • Joined:  11/11/16
  • Last Seen:  

First off you need to put that in a codebox, second off whats the issue?

Edited by srhmike
Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  18
  • Topics Per Day:  0.00
  • Content Count:  42
  • Reputation:   0
  • Joined:  03/10/12
  • Last Seen:  

@srhmike It's ori script from Euphy...... And you look at the picture, There's wrong parts to remove card.... Upper Headgear part is the Diablo RING...

This script no problem at my friend server... But when i load this script to my server i happened these issues.

His client 2010, Mine 2015 client ........ Can you help me check?

Edited by crystalro
Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  6
  • Topics Per Day:  0.00
  • Content Count:  261
  • Reputation:   53
  • Joined:  11/11/16
  • Last Seen:  

I didnt see the picture before.  And to confirm, mine does the same thing.  I'm using new client also. Haven't fixed it either.

Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  18
  • Topics Per Day:  0.00
  • Content Count:  42
  • Reputation:   0
  • Joined:  03/10/12
  • Last Seen:  

@srhmike Or bro can you share me your script? Thanks !!!

Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  6
  • Topics Per Day:  0.00
  • Content Count:  261
  • Reputation:   53
  • Joined:  11/11/16
  • Last Seen:  

I use the same one, and I have not fixed it.  

The error is somewhere in here:

function Equip_Menu {
			setarray .@pos$[1],"Upper Headgear","Armor","Left hand","Right hand","Garment","Footgear","Left Accessory","Right Accessory","Mid Headgear","Lower Headgear";
			set .@menu$,"";
			for (set .@i,1; .@i <= 10; set .@i,.@i+1) {
				if (getequipisequiped(.@i))
					set .@menu$, .@menu$+.@pos$[.@i]+" [^0055FF"+getequipname(.@i)+"^000000]";
				set .@menu$, .@menu$+":";
			}

 

Edited by srhmike
Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  1
  • Topics Per Day:  0.00
  • Content Count:  13
  • Reputation:   7
  • Joined:  11/23/11
  • Last Seen:  

in "function Equip_Menu"
 

                setarray .@pos$[1],"Upper Headgear","Armor","Left hand","Right hand","Garment","Footgear","Left Accessory","Right Accessory","Mid Headgear","Lower Headgear";
                set .@menu$,"";
                for (set .@i,1; .@i <= 10; set .@i,.@i+1) {
                    if (getequipisequiped(.@i))
                        set .@menu$, .@menu$+.@pos$[.@i]+" [^0055FF"+getequipname(.@i)+"^000000]";
                    set .@menu$, .@menu$+":"; }
                set @i, select(.@menu$);


Replace to :

				setarray .@pos$[1],"Upper Headgear","Armor","Left hand","Right hand","Garment","Footgear","Left Accessory","Right Accessory","Mid Headgear","Lower Headgear";
				setarray .@eq_pos[1], EQI_HEAD_TOP, EQI_ARMOR, EQI_HAND_L, EQI_HAND_R, EQI_GARMENT, EQI_SHOES, EQI_ACC_L, EQI_ACC_R, EQI_HEAD_MID, EQI_HEAD_LOW;
				set .@menu$,"";
				for (set .@i,1; .@i <= 10; set .@i,.@i+1) {
					if (getequipisequiped(.@eq_pos[.@i]))
						set .@menu$, .@menu$+.@pos$[.@i]+" [^0055FF"+getequipname(.@eq_pos[.@i])+"^000000]";
					set .@menu$, .@menu$+":";
				}
                set @i, .@eq_pos[select(.@menu$)];

 

  • Upvote 1
Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  18
  • Topics Per Day:  0.00
  • Content Count:  42
  • Reputation:   0
  • Joined:  03/10/12
  • Last Seen:  

@gugusjungs Thanks so muchhhhhhhhhhhhhhhhhhhhhhhhhhhhhhh!!!!!!!!!!!!!!

Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  18
  • Topics Per Day:  0.00
  • Content Count:  42
  • Reputation:   0
  • Joined:  03/10/12
  • Last Seen:  

@gugusjungs Please help me this script too bro. Thank you! I wonder why other server works and load on my server become other thing....
this script refiner is refine 1by1 style.... But i wear full eq ady.... It only appear Shoes , Upper and Garment..  Disabled accessory & mid low 
f5081145c314b7de4cc2951e6782ae9a.png

// function    script    ValueConvert    {
    // set .@num, atoi(""+getarg(0));
    // if ( .@num == 0 || .@num >= 2147483647 ) return getarg(0);
    // set .@l, getstrlen(""+.@num);
    // for ( set .@i,0; .@i < .@l; set .@i, .@i + 1 ) {
        // set .@num$, .@num % pow(10,.@i+1) / pow(10,.@i) + .@num$;
            // if ( (.@i+1) % 3 == 0 && .@i+1 != .@l ) set .@num$, ","+ .@num$;
    // }
    // return .@num$;
// }


quiz_02,334,78,5    script    Refiner    63,{

for( set .@i,1; .@i <= 6; set .@i,.@i + 1 )
    if( getequipisequiped( .@i ) ){
        if( getequipisenableref( .@i ) && getequiprefinerycnt( .@i ) <= .max_refine ){
            set .@eq_count,.@eq_count + 1;
            set .@menu$,.@menu$ + " +"+getequiprefinerycnt( .@i )+" "+getequipname( .@i ) +":";
        }else{
            set .@menu$,.@menu$ +":";
        }
    }else{
        set .@menu$,.@menu$ +":";
    }
if( !.@eq_count ){
    mes "You dont have any equipment available for refine.";
    close;
}

set .@equipment,select( .@menu$ );
set .@temp_equip,getequipid( .@equipment );

do{
    if( getequipid( .@equipment ) != .@temp_equip ){
        mes "Dont change to other equipments.";
        close;
    }
    
    set .@eq_level,getequipweaponlv( .@equipment );
    if( .@eq_level == 1 ) set .@free_refine,7;
    else if( .@eq_level == 2 ) set .@free_refine,6;
    else if( .@eq_level == 3 ) set .@free_refine,5;
    else set .@free_refine,4;
    
    set .@refine_count,getequiprefinerycnt( .@equipment );
    
    if( .zeny_cost ){
        mes "Every Refine : ^0055FF"+callfunc( "ValueConvert",.zeny_cost )+" Zeny^000000";
        mes "De-refine : ^FF0000Free^000000";
        mes " ";
        mes "If current refine below +^FF0000"+.@free_refine+" : ^FF0000Free^000000";
        next;
    }

    set .@refine,select(( .@refine_count >= .max_refine )?"":"Refine to ^0055FF+"+( .@refine_count + 1 )+" "+getequipname( .@equipment )+"^000000",
                        ( .@refine_count < 1 )?"":"De-refine -1" );  // temporary disabled de-refine
    
    if( Zeny < .zeny_cost && .@refine == 1 ){
        message strcharinfo(0),"Dont have enough zeny.";
        break;
    }
    
    if( .@refine_count < 1 && .@refine == 2 ){
        mes "You cant de-refine this anymore.";
        break;
    }else if( .@refine_count >= .max_refine && .@refine == 1 ){
        mes "You cant refine this anymore.";
    }else{
        if( .@refine == 1 && .@refine_count >= .@free_refine )
            set Zeny,Zeny - .zeny_cost;
        switch( .@refine ){
            Case 1: successrefitem .@equipment; break;
            Case 2: downrefitem .@equipment; break;
            default: break;
        }
    }
    
    if( getequiprefinerycnt( .@equipment ) >= .max_refine ){
        mes "Max Refine Reach...";
        break;
    }
}while( 1 );
close;

OnInit:
OnWhisperGlobal:
set .zeny_cost,0;
set .max_refine,10;

waitingroom "  Refiner",0;
end;
}

 

Edited by Emistry
Link to comment
Share on other sites

  • 0

  • Group:  Members
  • Topic Count:  18
  • Topics Per Day:  0.00
  • Content Count:  42
  • Reputation:   0
  • Joined:  03/10/12
  • Last Seen:  

@gugusjungs Errrrrrr... You solved me that all in one npc.... Putty appear
4c0734d9dcec2e9e2cfbe7d578174525.png

Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
×
  • Create New...