R> NPC Full Buffs for VIP Groups

[Subzero]

hello this my current script for normal buffer how about if i want make VIP member group get a CP and Link?(VIP GROUP ID 5

prontera,150,181,4 script Healer#h1-1::Healer 533,{
emotion 21;

while( .@i < .sc_size ){
sc_end .sc_status[.@i];
set .@i,.@i + 1;
}

sc_start SC_BLESSING,.buff_duration,10;
sc_start SC_INCREASEAGI,.buff_duration,10;
sc_start SC_GLORIA,.buff_duration,5;
sc_start SC_ASPDPOTION2,.buff_duration,0;
sc_start SC_MAGNIFICAT,.buff_duration,10;
sc_start SC_SUFFRAGIUM,.buff_duration,10;
sc_start SC_ASSUMPTIO,.buff_duration,10;
percentheal 100,100;

dispbottom "Thanks.";

while( getbrokenid(1) )
// repair getbrokenid(1);
repairall;
// atcommand "@repairall";
end;


OnInit:
set .buff_duration,600000;

setarray .sc_status,
SC_STONE,SC_FREEZE,SC_STUN,SC_SLEEP,SC_POISON,SC_CURSE,SC_SILENCE,SC_CONFUSION,SC_BLIND,SC_BLEEDING,
SC_QUAGMIRE,SC_AETERNA,SC_HALLUCINATION,SC_SLOWDOWN,SC_BERSERK,SC_CHANGEUNDEAD,
SC_STRIPWEAPON,SC_STRIPSHIELD,SC_STRIPARMOR,SC_STRIPHELM;
set .sc_size,getarraysize( .sc_status );


waitingroom " H e a l e r",0;
end;
}

bump

Edited July 30, 2016 by Emistry
use codebox

[Hijirikawa]

if(getgroupid() >= 5 ){

set(.@min, 5); // duration in minutes

sc_start(SC_CP_HELM, (.@min * 1000 * 60), 1);

sc_start(SC_CP_ARMOR, (.@min * 1000 * 60), 1);

sc_start(SC_CP_SHIELD, (.@min * 1000 * 60), 1);

sc_start(SC_CP_WEAPON, (.@min * 1000 * 60), 1);

switch ( basejob ) {

case Job_Alchemist: set .@spirit, 445; break;

case Job_Monk: set .@spirit, 447; break;

case Job_Star_Gladiator: set .@spirit, 448; break;

case Job_Sage: set .@spirit, 449; break;

case Job_Crusader: set .@spirit, 450; break;

case Job_SuperNovice: set .@spirit, 451; break;

case Job_Knight: set .@spirit, 452; break;

case Job_Wizard: set .@spirit, 453; break;

case Job_Priest: set .@spirit, 454; break;

case Job_Bard: case Job_Dancer: set .@spirit, 455; break;

case Job_Rogue: set .@spirit, 456; break;

case Job_Assassin: set .@spirit, 457; break;

case Job_Blacksmith: set .@spirit, 458; break;

case Job_Hunter: set .@spirit, 460; break;

case Job_Soul_Linker: set .@spirit, 461; break;

default:

if ( upper == 1 && baselevel < 70 )

set .@spirit, 494;

}

if ( .@spirit ) {

sc_start4 sc_spirit, 360000, 5, .@spirit,0,0;

skilleffect .@spirit, 5;

}

}

[nitrous]

If we put it all together:

prontera,150,181,4 script Healer#h1-1::Healer 533,{
	emotion 21;

	while( .@i < .sc_size ){
		sc_end .sc_status[.@i];
		set .@i,.@i + 1;
	}

	sc_start SC_BLESSING,.buff_duration,10;
	sc_start SC_INCREASEAGI,.buff_duration,10;
	sc_start SC_GLORIA,.buff_duration,5;
	sc_start SC_ASPDPOTION2,.buff_duration,0;
	sc_start SC_MAGNIFICAT,.buff_duration,10;
	sc_start SC_SUFFRAGIUM,.buff_duration,10;
	sc_start SC_ASSUMPTIO,.buff_duration,10;
	percentheal 100,100;
	if(getgroupid() >= 5 ){
		sc_start(SC_CP_HELM, (.buff_duration), 1);
		sc_start(SC_CP_ARMOR, (.buff_duration), 1);
		sc_start(SC_CP_SHIELD, (.buff_duration), 1);
		sc_start(SC_CP_WEAPON, (.buff_duration), 1);
		switch ( basejob ) {
			case Job_Alchemist:	set .@spirit, 445; break;
			case Job_Monk:	 set .@spirit, 447; break;
			case Job_Star_Gladiator:  set .@spirit, 448; break;
			case Job_Sage:	 set .@spirit, 449; break;
			case Job_Crusader:	set .@spirit, 450; break;
			case Job_SuperNovice:   set .@spirit, 451; break;
			case Job_Knight:	set .@spirit, 452; break;
			case Job_Wizard:	set .@spirit, 453; break;
			case Job_Priest:	set .@spirit, 454; break;
			case Job_Bard: case Job_Dancer: set .@spirit, 455; break;
			case Job_Rogue:	 set .@spirit, 456; break;
			case Job_Assassin:	set .@spirit, 457; break;
			case Job_Blacksmith:   set .@spirit, 458; break;
			case Job_Hunter:	set .@spirit, 460; break;
			case Job_Soul_Linker:   set .@spirit, 461; break;
			default:
				if ( upper == 1 && baselevel < 70 )
					set .@spirit, 494;
		}
		if ( .@spirit ) {
			sc_start4 sc_spirit, .buff_duration, 5, .@spirit,0,0;
			skilleffect .@spirit, 5;
		}
	}

	dispbottom "Thanks.";

	while( getbrokenid(1) )
		// repair getbrokenid(1);
		repairall;
	        // atcommand "@repairall";
	end;


OnInit:
	set .buff_duration,600000;

	setarray .sc_status,
	SC_STONE,SC_FREEZE,SC_STUN,SC_SLEEP,SC_POISON,SC_CURSE,SC_SILENCE,SC_CONFUSION,SC_BLIND,SC_BLEEDING,
	SC_QUAGMIRE,SC_AETERNA,SC_HALLUCINATION,SC_SLOWDOWN,SC_BERSERK,SC_CHANGEUNDEAD,
	SC_STRIPWEAPON,SC_STRIPSHIELD,SC_STRIPARMOR,SC_STRIPHELM;
	set .sc_size,getarraysize( .sc_status );


	waitingroom " H e a l e r",0;
	end;
}