NpC Encantador de Hats +1 Stat Random

[iraciz]

Este es un NpC que nunca Falla en encantar el UPPER GEAR que se lleve equipado!

cobra ciertos items!  la cantidad o la id se modifica facilmente!

 

puede ser +1 de cualquier STAT y siempre va colocado en el 4 slot! 

 

Si el objeto en cuestion es un Dark Baccilium, o Una mascara que ocupe por lo menos el top, tambien sera encantada.

 

headchant.txt

new_4-2,161,185,5	script	Artesano Maestro	531,{

emotion e_hmm;
	mes .npc$;
	mes "Hola, bienvenido seas! soy ^0000FFIracundo^000000, el Artesano Maestro.";
	mes "A lo largo de mi vida, me dedique a estudiar como ampliar la capacidad de los Hats.";
	next;
	mes .npc$;
	mes "Y esta habilidad me permite brindarle un misterioso ^32cd32+1 Stat^000000 enchant a cualquier upper gear equipado, sin importa cuantos espacios ocupe.";
	
	next;
	mes .npc$;
	mes "Si quieres mi servicio, con garantia de no fallar nunca.";
	mes "Vas a tener que  pagarme:";
	mes "^cc00cc"+.price+" "+((.price-1)?getitemname(.item)+"s":getitemname(.item))+"^000000."; 
	next;
	if(!countitem(.item)){ 
	mes .npc$; 
	mes "Pero que rayos?! Tu nisiquiera traes ^cc00cc"+getitemname(.item)+"s^000000 en tu inventario."; 
	close;
	}
	
	if(select("^FF9900Encantar Upper Gear^000000:^FF0000No Gracias^000000")&2){ 
	mes .npc$; 
	mes "Entiendo, gracias de todos modos!.";
	close;
	}

	if(countitem(.item)<.price) { 
	mes .npc$; 
	mes "Cuanto lo siento! no tienes suficientes ^cc00cc"+getitemname(.item)+"s^000000 para que yo infunda un enchant en tu Upper Gear.";
	next;
	mes .npc$; 
	mes "Vuelve cuando tengas la cantidad exacta que cobro.";
	close;
	}
	
	mes .npc$;
	mes "Esta es la mejor desicion que haz tomado.";
	next;
	specialeffect 96;
	progressbar "ffff00",2;
	if(getequipid(1)+1) {
		delitem .item,.price;
		set .@id, getequipid(1);
		set .@ref, getequiprefinerycnt(1);
		set .@card1, getequipcardid(1,0);
		set .@card2, getequipcardid(1,1);
		set .@card3, getequipcardid(1,2);
		set .@card4, getequipcardid(1,3);
		delitem2 .@id, 1, 1, .@ref, 0, .@card1, .@card2, .@card3, .@card4;
		getitem2 .@id, 1, 1, .@ref, 0, .@card1, .@card2, .@card3,
			callfunc("F_Rand", 4700, 4710,	4720, 4730, 4740, 4750);
		equip .@id;
		specialeffect2 154;
		mes .npc$;
		mes "Felicidades, el enchant ha sido exitoso!.";
		close;
	}
	
	mes .npc$;
	emotion e_omg;
	mes "eh eh ehhh! Aguarda un Momento";
	mes "Estas loco? Quieres que te introduzca una gema en tu craneo a martillazos?.";
	mes "Necesitas tener al menos un Upper Gear equipado para realizar mi mejora.";
	close;

	// Objeto Requerido y Cantidad
    OnInit:
        set .npc$, "^660066Iracundo^000000";
        set .price, 300;
        set .item, 7539;
}