Need Help to modification this script

[crixxz]

-	script	login_reward	-1,{
OnPCLoginEvent:
	.@pow = 1 << 10;
	.@todays = gettime(8);
	if ( #login_reward % .@pow == .@todays ) end;
	.@count = .reward_day;
	#login_reward = ( #login_reward &~ ( #login_reward % .@pow ) ) + .@todays + .@pow;
	.@count_day = ( #login_reward >> 10 ) % .@pow;
	if ( .@count_day % 7  == 0 ) {
		.@count += .reward_week;
		.@weekly_message$ = ( .@cond_ofthemonth ? ", " : " and " ) + .reward_week +" golds for being online a week";
	}
	if ( .@count_day % 31 == 0 ) {
		.@count += .reward_month;
		.@montly_message$ = " and " + .reward_month +" golds for being online a month";
	}
	getitem 969, .@count;
	dispbottom "Here your daily reward ! You got "+ .reward_day +" golds"+ .@weekly_message$ + .@montly_message$ +".";
	end;
OnInit:
	.reward_day = 2;// reward of the day : amount of gold
	.reward_week = 10;// reward of the week : amount of gold
	.reward_month = 35;// reward of the month : amount of gold
	end;
}

i got this script from http://rathena.org/board/topic/88005-how-to-make-this-account-based/?p=225329

this script get directly reward after login.

how to add 1 hour after login, just got a daily reward..?

thanks advance

Edited December 22, 2013 by crixxz

[Capuche]

- script login_reward -1,{

OnPCLoginEvent:

addtimer 3600, strnpcinfo(3) + "::Onijnuionion";

end;

Onijnuionion:

.@pow = 1 << 10;

[crixxz]

-	script	login_reward	-1,{
OnPCLoginEvent:
	addtimer 3600, strnpcinfo(3) + "::Onijnuionion";
	end;
Onijnuionion:
	.@pow = 1 << 10;

thanks for the answer, i will try it

[Capuche]

I forgot addtimer need the timer in millisecs

addtimer 3600000, strnpcinfo(3) + "::Onijnuionion";// 1h

[crixxz]

 

I forgot addtimer need the timer in millisecs

addtimer 3600000, strnpcinfo(3) + "::Onijnuionion";// 1h

thanks Capuche, work perfectly