Autobuffer (Soullink)

[CubeCat]

Buffer who can buff soullink after u stay in range for period of time. Cuz my English sucks... ill post example.

 

Like:

 

NPC wich every 20sec cast Soullink at all players who stayed 9x9 near it.

Edited March 27, 2013 by CubeCat

[Capuche]

prontera,157,181,5	script	Soul L	992,9,9,{
	deltimer strnpcinfo(0) +"::OnTwenty";
	addtimer 20000, strnpcinfo(0) +"::OnTwenty";
	end;
OnTwenty:
	getmapxy .@map$, .@x, .@y, 0;
	if( distance( .@x, .@y, .x_npc, .y_npc ) > 9 ) end;
	addtimer 20000, strnpcinfo(0) +"::OnTwenty";
	switch ( basejob ) {
		case Job_Alchemist:	set .@spirit, 445; break;
		case Job_Monk:	 set .@spirit, 447; break;
		case Job_Star_Gladiator:  set .@spirit, 448; break;
		case Job_Sage:	 set .@spirit, 449; break;
		case Job_Crusader:	set .@spirit, 450; break;
		case Job_SuperNovice:   set .@spirit, 451; break;
		case Job_Knight:	set .@spirit, 452; break;
		case Job_Wizard:	set .@spirit, 453; break;
		case Job_Priest:	set .@spirit, 454; break;
		case Job_Bard: case Job_Dancer: set .@spirit, 455; break;
		case Job_Rogue:	 set .@spirit, 456; break;
		case Job_Assassin:	set .@spirit, 457; break;
		case Job_Blacksmith:   set .@spirit, 458; break;
		case Job_Hunter:	set .@spirit, 460; break;
		case Job_Soul_Linker:   set .@spirit, 461; break;
		default:
			if ( upper == 1 && baselevel < 70 )
				set .@spirit, 494;
	}
	if ( .@spirit ) {
		sc_start4 sc_spirit, 360000, 5, .@spirit,0,0;
		skilleffect .@spirit, 5;
	}
	end;
OnInit:
	getmapxy .map_npc$, .x_npc, .y_npc, 1;
	end;
}

Credit to Emistry for the Soul link

Edited March 28, 2013 by Emistry
It's from AnnieRuru

[CubeCat]

Thank you! Really nice script, but have a lil issue when linked character sits he'll stuck, so i just modified this a lil.

 

 

if ( .@spirit ) {
        readparam(Sitting);
        if (readparam(Sitting)>=1) {
        stand;
        sc_start4 sc_spirit, 360000, 5, .@spirit,0,0;
        skilleffect .@spirit, 5; }
        else {
        sc_start4 sc_spirit, 360000, 5, .@spirit,0,0;
        skilleffect .@spirit, 5; }
    }    end;  
 

 

 

Edited March 28, 2013 by CubeCat

[Capuche]

Oo what a weird bug

 

btw Sitting is already a parameter, no need readparam command

	if ( .@spirit ) {
		if( Sitting ) stand;
		sc_start4 sc_spirit, 360000, 5, .@spirit,0,0;
		skilleffect .@spirit, 5;
	}