Reset that makes you forget the quest skills

[Nana]

IS there any way to make a reset NPC that when you reset you skills yo don't get the quest skills?

Thanks in advance

[Capuche]

You mean... when you reset your skill, you lost your platinum skills ? >>

prontera,150,193,4    script    Reset Girl    124,{

   setarray .@Reset, 5000, 5000, 9000;    // Zeny for stat reset - skill reset - both together

   mes "[Reset Girl]";
   mes "I am the Reset Girl.";
   mes "Reset Stats: "+ .@Reset[0] +"z";
   mes "Reset Skills: "+ .@Reset[1] +"z";
   mes "Reset Both: "+ .@Reset[2] +"z";
   mes "Please select the service you want:";
   next;
   if( select("^FF3355Reset Stats:Reset Skills:Reset Both^000000:Cancel") == 4 ) close;

   mes "[Reset Girl]";
   if( Zeny < .@Reset[ @menu-1] ) {
       mes "Sorry, you don't have enough Zeny.";
       close;
   }
   set Zeny, Zeny - .@Reset[ @menu-1];
   if( @menu != 1 ) {
       sc_end SC_ALL;
       ResetSkill;
       callsub Get_Platinum;
   }
   if( @menu != 2 )
       ResetStatus;
   mes "There you go!";
   close;

Get_Platinum:
   skill 142,0,0;
   switch(BaseClass) {
       case 0: if (Class !=23) skill 143,0,0; break;
       case 1: skill 144,0,0; skill 145,0,0; skill 146,0,0; break;
       case 2: skill 157,0,0; break;
       case 3: skill 147,0,0; skill 148,0,0; break;
       case 4: skill 156,0,0; break;
       case 5: skill 153,0,0; skill 154,0,0; skill 155,0,0; break;
       case 6: skill 149,0,0; skill 150,0,0; skill 151,0,0; skill 152,0,0; break;
       default: break;
   }
   switch(BaseJob) {
       case 7: skill 1001,0,0; break;
       case 8: skill 1014,0,0; break;
       case 9: skill 1006,0,0; break;
       case 10: skill 1012,0,0; skill 1013,0,0; break;
       case 11: skill 1009,0,0; break;
       case 12: skill 1003,0,0; skill 1004,0,0; break;
       case 14: skill 1002,0,0; break;
       case 15: skill 1015,0,0; skill 1016,0,0; break;
       case 16: skill 1007,0,0; skill 1008,0,0; skill 1017,0,0; skill 1018,0,0; skill 1019,0,0; break;
       case 17: skill 1005,0,0; break;
       case 18: skill 238,0,0; break;
       case 19: skill 1010,0,0; break;
       case 20: skill 1011,0,0; break;
       default: break;
   }
   return;
}

[Nana]

yes!! thanks a lot!!

<3

[Capuche]