a modification for this script

[KCritz]

Hi i would like to request a modification for this script if its okay

http://pastebin.com/k3p7LR0H

its a stat reset i would like to add the skill and at the same process using the same item coz what im doin is im making another npc just for the skill reset.

the owner of the script is GM Taka*** sorry cant remember his name

Edited December 23, 2012 by KCritz

[Capuche]

For you, Merry Christmas !

prontera,146,304,5	script	Reseter	407,{
//-
setarray .@minrange[0], 1, 41, 71, 91, 111, 126, 141;
setarray .@maxrange[0], 40, 70, 90, 110, 125, 140, 150;
setarray .@stones[0], 1, 2, 3, 4, 5, 6, 7;
set .@stoneid, 6320;
set .@npcname$,"["+strnpcinfo(0)+"]";

//- Reset Skills Option 0/1 -- no/yes
set .@Sk, 1;
//-

mes .@npcname$;
mes "So are you satisfied with your";
mes "current stat allocation?";
mes "Of course not, if you want to make";
mes "a change then listen on.";
next;

mes .@npcname$;
mes "I use the power of the";
mes "^009900"+getitemname(.@stoneid)+"^000000 to help adventurers";
mes "reset their stat choices.";
mes "Of course the more powerful the";
mes "adventurer, the more ^009900"+getitemname(.@stoneid)+"s^000000";
mes "I need the perform the reset.";
next;

for(set .@i,0; .@i<getarraysize(.@minrange); set .@i,.@i+1)
	if(BaseLevel >= .@minrange[.@i] && BaseLevel <= .@maxrange[.@i])
		set .@stonesreq,.@stones[.@i];
mes .@npcname$;
mes "For instance you ["+strcharinfo(0)+"] would require.";
mes "["+.@stonesreq+"] "+getitemname(.@stoneid)+" to reset all your stats to 1 and get all your status points back.";
next;

switch( select("Tell me More!","Lets reset NOW",(Freebies?"":"First Time Free Reset"),(.@Sk?"Reset Skills":""),"Later") ) {
	case 1:
		mes .@npcname$;
		for(set .@i,0; .@i<getarraysize(.@minrange); set .@i,.@i+1)
			mes "Base Lvl ^000099"+.@minrange[.@i]+" - "+.@maxrange[.@i]+"^000000 ^009900["+.@stones[.@i]+" "+getitemname(.@stoneid)+"]^000000";
		break;
	case 2:
	case 4:
		mes .@npcname$;
		mes "Ok let's start checking.";
		next;
		mes .@npcname$;
		if( Weight > 0 ) {
			mes "Lower your weight to 0";
			break; }
		if(checkcart()) setcart 0;
		if(checkfalcon()) setfalcon 0;
		if(checkriding()) setriding 0;
		if( countitem(.@stoneid) >= .@stonesreq ) {
			delitem .@stoneid, .@stonesreq;
			mes "Done.";
			if( @menu & 2 )
				resetstatus;
			else
				resetskill; }
		else
			mes "You do not have enough ^009900"+getitemname(.@stoneid)+"s^000000";
		break;
	case 3:
		mes .@npcname$;
		mes "Welcome...this is your first character free reset...";
		resetstatus;
		set Freebies,1;
		break;
	case 5: }
close;
}

Edited December 25, 2012 by Capuche

[KCritz]

thank you sir Capuche and Happy New Year to you