Jump to content
  • 0

R> Mini-Game Last man standing

dukenukexd

Asked by dukenukexd,

 Share

Question

dukenukexd Drops

dukenukexd

Posted
  • Group:  Members
  • Topic Count:  4
  • Topics Per Day:  0.00
  • Content Count:  4
  • Reputation:   0
  • Joined:  04/12/14
  • Last Seen:  
Posted

Preciso de ajuda com um script de mini jogo

funciona assim: no mapa quiz_02 tem 2 espaços e cada jogador tera q escolher um dos espaços e depois de alguns segundos quem estiver no espaço errado está fora, e segue assim ate sobrar 1 jogador!

alguem pode me ajudar? ou se ja tiver algum script parecido me mande o link

obrigado e deus abençoe!

 

-- english

I need help with a mini game script

It works like this: on the quiz_02 map there are 2 spaces and each player will have to choose one of the spaces and after a few seconds whoever is in the wrong space is out, and it continues like this until there is 1 player left!

Can someone help me? or if you have a script similar to mine send the link

Thank you and God bless! 

 

Sem título.png

Link to comment
Share on other sites

2 answers to this question

Recommended Posts

  • 0
Racaae Metaling

Racaae

Posted
  • Group:  Members
  • Topic Count:  0
  • Topics Per Day:  0
  • Content Count:  132
  • Reputation:   53
  • Joined:  06/02/12
  • Last Seen:  
Posted

Hello 

//============================================================ 
//= Last Standing (try your luck guessing O or X) by Racaae
//============================================================ 
//= https://rathena.org/board/topic/141331-r-mini-game-last-man-standing/
//============================================================ 

prontera,147,150,0	script	Evento Last Standing	PORTAL,{
	emotion F_Rand(ET_O,ET_X), getnpcid(0);
	mes "[" + strnpcinfo(1) + "]";
	if ($@laststanding == 1) {
		mes "Quer participar do evento?";
		if (select("Sim", "Não") == 2) {
			clear;
			if (checkweight(1119,3) == 0) {
				mes "- Você tem muitos itens.";
				mes "Organize seu inventário e tente novamente. -";
				close;
			}
			mes "[" + strnpcinfo(1) + "]";
			mes "Até mais.";
			close;
		}
		warp "quiz_02",249,385;
		end;
	}
	mes "O evento começa sempre aos 45 minutos de cada hora.";
	mes "Por exemplo, 10:45 12:45 18:45";
	if (getgroupid() >= 99)
		mes " ", "^0000ffDigite @LastStanding para acessar o menu GM^000000";
	close;

OnMinute45:
	if ($@laststanding != 0) end;
OnOpen:
	cloakonnpc "O#luckyevent";
	cloakonnpc "X#luckyevent";
	cloakonnpc "O#luckyevent2";
	cloakonnpc "X#luckyevent2";
	waitingroom "Venha Participar!", 0;
	announce "Last Standing : O portal para o evento se abriu em Prontera!! 5 minutos até que ele se feche!",0;
	$@laststanding = 1;
	sleep 120000;
	if ($@laststanding != 1) end;
	announce "Last Standing : O portal para o evento fechará em 3 minutos!",0;
	sleep 60000;
	if ($@laststanding != 1) end;
	announce "Last Standing : O portal para o evento fechará em 1 minuto!",0;
	sleep 60000;
	if ($@laststanding != 1) end;
	announce "Last Standing : O portal para o evento se fechou!",0;
	donpcevent strnpcinfo(0) + "::OnStart";
	end;

OnStart:
	$@laststanding = 2;
	delwaitingroom;
	sleep 3000;	
	areaannounce "quiz_02",220,330,280,395,"Bem vindos ao evento Last Standing. O ou X será escolhido aleatoriamente.",bc_blue;
	sleep 4000;
	areaannounce "quiz_02",220,330,280,395,"Tudo que você precisa fazer é ir até a área que você acha que foi escolhida.",bc_blue;
	sleep 4000;
	areaannounce "quiz_02",220,330,280,395,"Exemplo, se eu escolher X, todos os aventureiros que estiverem em O perdem.",bc_blue;
	sleep 4000;
	areaannounce "quiz_02",220,330,280,395,"Faremos isso de novo e de novo até termos 1 aventureiro sobrevivente.",bc_blue;
	sleep 4000;
	areaannounce "quiz_02",220,330,280,395,"Antes que eu esqueça, você deve entrar em uma das áreas! Qualquer um do lado de fora será automaticamente desclassificado!",bc_blue;
	sleep 4000;
	areaannounce "quiz_02",220,330,280,395,"É isso... Agora vamos começar!",bc_blue;
	sleep 4000;
	.@num = getareaunits(BL_PC,"quiz_02",220,330,280,395,$@ls_players$[0]);
	if (.@num == 0) {
		$@laststanding = 0;
		end;
	}
	goto L_start;

L_start:
	if ($@laststanding != 2) end;
	cloakoffnpc "O#luckyevent";
	cloakoffnpc "X#luckyevent";
	cloakoffnpc "O#luckyevent2";
	cloakoffnpc "X#luckyevent2";
	areaannounce "quiz_02",220,330,280,395,"Por favor, vá até uma das áreas desejadas Vai! Vai! Vai!",bc_blue;
	sleep 10000;
	if ($@laststanding != 2) end;
	areaannounce "quiz_02",220,330,280,395,"5",bc_blue;
	sleep 1500;
	if ($@laststanding != 2) end;
	areaannounce "quiz_02",220,330,280,395,"4",bc_blue;
	sleep 1500;
	if ($@laststanding != 2) end;
	areaannounce "quiz_02",220,330,280,395,"3",bc_blue;
	sleep 1500;
	if ($@laststanding != 2) end;
	areaannounce "quiz_02",220,330,280,395,"2",bc_blue;
	sleep 1500;
	if ($@laststanding != 2) end;
	areaannounce "quiz_02",220,330,280,395,"1",bc_blue;
	sleep 1000;
	if ($@laststanding != 2) end;
	cloakonnpc "O#luckyevent";
	cloakonnpc "X#luckyevent";
	cloakonnpc "O#luckyevent2";
	cloakonnpc "X#luckyevent2";
	sleep 500;
	.@w = rand(2);
	areaannounce "quiz_02",220,330,280,395,"E o escolhido foi " + (.@w?"X":"O") + "!",bc_blue;
	.@num_e = getareaunits(BL_PC,"quiz_02",220,330,280,395,.@emote[0]);
	for (.@i = 0; .@i < .@num_e; .@i++)
		emotion (.@w?ET_X:ET_O), .@emote[.@i];
	sleep 1500;
	if ($@laststanding != 2) end;
	deletearray $@ls_players, getarraysize($@ls_players);
	if (.@w) { // X choosen
		areawarp "quiz_02",220,330,248,358,"quiz_02",241,364,258,375;
		.@num = getareaunits(BL_PC,"quiz_02",250,330,275,358,$@ls_players[0]);
	}
	else { // O choosen
		areawarp "quiz_02",250,330,275,358,"quiz_02",241,364,258,375;
		.@num = getareaunits(BL_PC,"quiz_02",220,330,248,358,$@ls_players[0]);
	}
	if (.@num == 0) {
		announce "Last Standing : Ninguém venceu o evento.",bc_all;
		sleep 3000;
		donpcevent strnpcinfo(0) + "::OnEnd";
	}
	if (.@num == 1) {
		donpcevent strnpcinfo(0) + "::OnWinner";
		end;
	}
	areaannounce "quiz_02",220,330,280,395,.@num + " aventureiros acertaram! Preparem-se para outra rodada.",bc_blue;
	sleep 4000;
	callsub L_start;

OnWinner:
	announce "Last Standing : " + convertpcinfo($@ls_players[0],CPC_NAME) + " ganhou o evento!",bc_all;
	getitem 607,10,$@ls_players[0];	// prêmio do vencedor
	specialeffect2 EF_MVP, AREA, convertpcinfo($@ls_players[0],CPC_NAME);
	sleep 3000;
	if ($@laststanding != 2) end;
	areaannounce "quiz_02",220,330,280,395,"Obrigado por psrticipar! Você será teleportado em 10 segundos.",bc_blue;
	sleep 10000;
	if ($@laststanding != 2) end;
	donpcevent strnpcinfo(0) + "::OnEnd";
	end;

OnEnd:
	if ($@laststanding == 1)
		announce "Last Standing : O evento foi cancelado.",0;
	delwaitingroom;
	$@laststanding = 0;
	areawarp "quiz_02",220,330,280,395,"prontera",150,150;
	end;

OnInit:
	bindatcmd "laststanding",strnpcinfo(3)+"::OnAtcommand",99,99;
	$@laststanding = 0;
	end;

OnAtcommand:
	message strcharinfo(0), "Controle GM do evento Last Standing";
	switch(select("Cancelar", "^0000FFComeçar evento^000000", "^0000FFTerminar evento^000000", "Ir para o mapa")) {
		case 1:
			end;
		case 2:
			if ($@laststanding == 0) {
				donpcevent strnpcinfo(0) + "::OnOpen";
				message strcharinfo(0), "Ação confirmada!";
				end;
			}
			if ($@laststanding == 1) {
				mes "O portal do evento já está aberto para jogadores irem entrando.";
				mes "Quer fechar o portal e iniciar o evento agora?";
				if (select("Manter portal aberto", "^0000FFFechar portal e iniciar^000000") == 1)
					close;
				if ($@laststanding == 1) {
					donpcevent strnpcinfo(0) + "::OnStart";
					message strcharinfo(0), "Ação confirmada!";
				}
				close;
			}
			message strcharinfo(0), "Evento já está em andamento";
			end;
		case 3:
			if ($@laststanding != 0) {
				donpcevent strnpcinfo(0) + "::OnEnd";
				message strcharinfo(0), "Ação confirmada!";
				end;
			}
			message strcharinfo(0), "Evento não foi iniciado.";
			end;
		case 4:
			warp "quiz_02",249,385;
			end;
	}
	end;
}

quiz_02,255,384,3	script	SAÍDA#laststanding	PORTAL,{
	npctalk "Quer sair do evento?", strnpcinfo(0), bc_self;
	if (select("Ficar aqui", "^FF0000Sair do evento^000000") == 2)
		warp "prontera",150,150;
	end;
}

quiz_02,237,365,0	script	O#luckyevent	1_SHADOW_NPC,14,7,{
	if ($@ls_players[0] && inarray($@ls_players, getcharid(3)) == -1)
		npctalk "Você não está mais participando.", strnpcinfo(0), bc_self;
	else
		warp "quiz_02",237,345;
	end;

OnTouch:
	npctalk "Clique aqui se escolhe O", strnpcinfo(0), bc_self;
	emotion ET_O, getnpcid(0);
	end;
}

quiz_02,262,365,0	script	X#luckyevent	1_SHADOW_NPC,14,7,{
	if ($@ls_players[0] && inarray($@ls_players, getcharid(3)) == -1)
		npctalk "Você não está mais participando.", strnpcinfo(0), bc_self;
	else
		warp "quiz_02",262,345;
	end;

OnTouch:
	npctalk "Clique aqui se escolhe X", strnpcinfo(0), bc_self;
	emotion ET_X, getnpcid(0);
	end;
}

quiz_02,237,357,0	warp	O#luckyevent2	1,1,quiz_02,250,366
quiz_02,262,357,0	warp	X#luckyevent2	1,1,quiz_02,249,366

quiz_02	mapflag	nowarp
quiz_02	mapflag	nowarpto
quiz_02	mapflag	noskill
quiz_02	mapflag	noteleport
quiz_02	mapflag	nomemo
quiz_02	mapflag	nosave	SavePoint
quiz_02	mapflag	noicewall
quiz_02	mapflag	noloot

 

Link to comment
Share on other sites
  • 0
CharliBedori174 Poring

CharliBedori174

Posted
  • Group:  Members
  • Topic Count:  0
  • Topics Per Day:  0
  • Content Count:  1
  • Reputation:   0
  • Joined:  04/04/24
  • Last Seen:  
Posted (edited)

Os jogos sem conquistas oferecem uma experiência única e refrescante. Livres das tradicionais listas de tarefas e objetivos a alcançar, eles proporcionam uma oportunidade para os jogadores se perderem em mundos ricos e explorarem histórias profundas no seu próprio ritmo. Esta abordagem estimula a imaginação e promove uma apreciação mais profunda dos detalhes artísticos e narrativos. Para aqueles que buscam uma experiência de jogo ainda mais enriquecedora, explorar opções como as disponíveis em 1winscasinos-brazil.com.br pode ser um excelente ponto de partida. É uma verdadeira celebração da liberdade no universo dos jogos, abrindo portas para aventuras sem limites.

Edited by CharliBedori174
rw
Link to comment
Share on other sites

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.

Guest
Answer this question...

×   Pasted as rich text.   Paste as plain text instead

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 Share
Go to question listing
×
×
  • Create New...