Quest Shop Preview Problem

[terrence]

Hi i try put costume to quest_shop.txt which is this https://github.com/rathena/rathena/blob/master//npc/custom/quests/quest_shop.txt and i use old item_db.txt my item_db.txt example code 50000,Devil_Wing,C Devil Wing,4,0,,10,,0,,0,0xFFFFFFFF,63,2,1024,,0,1,5000,{},{ bonus bMaxHP,300; bonus bMaxSP,50; },{} and when i click preview it show googles only

[terrence]

Quote

//===== rAthena Script =======================================
//= Euphy's Quest Shop
//===== By: ==================================================
//= Euphy
//===== Current Version: =====================================
//= 1.6b
//===== Compatible With: =====================================
//= rAthena SVN r16862+
//===== Description: =========================================
//= A dynamic quest shop based on Lunar's, with easier config.
//= Includes support for multiple shops & cashpoints.
//= Item Preview script by ToastOfDoom.
//===== Additional Comments: =================================
//= 1.0 Initial script.
//= 1.2 Added category support.
//= 1.3 More options and fixes.
//= 1.4 Added debug settings.
//= 1.5 Replaced categories with shop IDs.
//= 1.6 Added support for purchasing stackables.
//= 1.6a Added support for previewing costumes and robes.
//= 1.6b Added 'disable_items' command.
//============================================================

// Shop NPCs -- supplying no argument displays entire menu.
//    callfunc "qshop"{,<shop ID>{,<shop ID>{,...}}};
//============================================================
mall,100,120,4    script    Headgear Quest Shop#4    4_MAL_SOLDIER,{ 
    callfunc "oshop1";
OnInit:
//    waitingroom "Quest",0;
    end;
 }

// Script Core
//============================================================
-    script    offquest_shop    FAKE_NPC,{ 
function Add; function Chk; function Slot; function A_An;
OnInit:
    freeloop(1);
    

// -----------------------------------------------------------
//  Basic shop settings.
// -----------------------------------------------------------

    set .announce,0;    // Announce quest completion? (1: yes / 0: no)
    set .ShowSlot,1;    // Show item slots? (2: all equipment / 1: if slots > 0 / 0: never)
    set .ShowID,1;      // Show item IDs? (1: yes / 0: no)
    set .ShowZeny,0;    // Show Zeny cost, if any? (1: yes / 0: no)
    set .MaxStack,100;    // Max number of quest items purchased at one time.

// -----------------------------------------------------------
//  Points variable -- optional quest requirement.
//    setarray .Points$[0],"<variable name>","<display name>";
// -----------------------------------------------------------

    setarray .Points$[0],"#CASHPOINTS","Cash Points";

// -----------------------------------------------------------
//  Shop IDs -- to add shops, copy dummy data at bottom of file.
//    setarray .Shops$[1],"<Shop 1>","<Shop 2>"{,...};
// -----------------------------------------------------------

    setarray .Shops$[1],"Upper Gear","Middle Gear";

// -----------------------------------------------------------
//  Quest items -- do NOT use a reward item more than once!
//    Add(<shop ID>,<reward ID>,<reward amount>,
//        <Zeny cost>,<point cost>,
//        <required item ID>,<required item amount>{,...});
// -----------------------------------------------------------
//---------- Upper
    Add(1,2284,1,0,0,923,20);
    Add(1,5076,1,0,0,2227,1,7038,500);
    Add(1,5199,1,0,0,2227,1,978,1,1057,100);
    Add(1,5057,1,10000,0,2213,1,983,1,914,200);
    Add(1,5065,1,0,0,624,1,959,500,1023,1);
    Add(1,5016,1,0,0,1030,10,0,0,0,0,0,0);
    Add(1,2214,1,0,0,949,100,706,1,722,1,2213,1);
    Add(1,5026,1,0,0,1036,450,949,330,539,120,982,1);
    Add(1,5108,1,5000,0,7301,500,611,10);
    Add(1,5038,1,0,0,1038,600,7048,40);
    Add(1,5258,1,0,0,914,100,975,1,976,1,978,1);
    Add(1,5058,1,0,0,2233,1,983,1,7206,300,7030,1);
    Add(1,5205,1,0,0,610,100,706,25,7194,300);
//    Add(1,5427,1,0,0,5288,1,12078,1,7521,1,12183,1);
//    Add(1,5188,1,0,0,5027,1,7166,50,7064,1);
//    Add(1,5426,1,0,0,5027,1,976,5);
    Add(1,5001,1,0,0,999,40,984,1,970,1,1003,1);
    Add(1,5070,1,0,0,7216,300,7097,300,2211,1,982,1);
    Add(1,5069,1,0,0,1022,99);
    Add(1,5027,1,0,0,2252,1,1036,400,7001,50,4052,1);
    Add(1,2280,1,10000,0,1019,120);
    Add(1,5062,1,0,0,2280,1,7197,300,7150,300);
    Add(1,5121,1,0,0,7263,1,660,1,7099,30,7315,369);

//---------- Middle
    Add(2,5074,1,20000,0,2286,1,2254,1);
    Add(2,5068,1,20000,0,2255,1,2286,1);
    Add(2,2296,1,50000,0,999,100);
    Add(2,5040,1,0,0,7047,100);
    Add(2,5175,1,100000,0,7111,100,938,99,983,1);
    Add(2,2281,1,5000,0,998,20,707,1);
    Add(2,5043,1,0,0,2281,1,1048,50);
    Add(2,2202,1,0,0,7020,2,999,100);

// -----------------------------------------------------------

    freeloop(0);
    set .menu$,"";
    for(set .@i,1; .@i<=getarraysize(.Shops$); set .@i,.@i+1) {
        set .menu$, .menu$+.Shops$[.@i]+":";
        npcshopdelitem "oshop"+.@i,909;
    }
    end;

OnMenu:
    set .@size, getarraysize(@i);
    if (!.@size) set .@i, select(.menu$);
    else if (.@size == 1) set .@i, @i[0];
    else {
        for(set .@j,0; .@j<.@size; set .@j,.@j+1)
            set .@menu$, .@menu$+.Shops$[@i[.@j]]+":";
        set .@i, @i[select(.@menu$)-1];
    }
    deletearray @i[0],getarraysize(@i);
    if (.Shops$[.@i] == "") {
        message strcharinfo(0),"An error has occurred.";
        end;
    }
    dispbottom "Select one item at a time.";
    callshop "oshop"+.@i,1;
    npcshopattach "oshop"+.@i;
    end;

OnBuyItem:
    // .@q[] : RewardID, BoughtAmt, RewardAmt, BaseAmt, ReqZeny, ReqPts, { ReqItem, ReqAmt, ... }
    setarray .@q[0],@bought_nameid[0],((@bought_quantity[0] > .MaxStack)?.MaxStack:@bought_quantity[0]);
    copyarray .@q[3],getd(".q_"+.@q[0]+"[0]"),getarraysize(getd(".q_"+.@q[0]));
    set .@q[2],.@q[1]*.@q[3];
    if (!.@q[2] || .@q[2] > 30000) {
        message strcharinfo(0),"You can't purchase that many "+getitemname(.@q[0])+".";
        end;
    }
    mes "[Quest Shop]";
    mes "Reward: ^0055FF"+((.@q[2] > 1)?.@q[2]+"x ":"")+Slot(.@q[0])+"^000000";
    mes "Requirements:";
    disable_items;
    if (.@q[4]) mes " > "+Chk(Zeny,.@q[4]*.@q[1])+(.@q[4]*.@q[1])+" Zeny^000000";
    if (.@q[5]) mes " > "+Chk(getd(.Points$[0]),.@q[5]*.@q[1])+(.@q[5]*.@q[1])+" "+.Points$[1]+" ("+getd(.Points$[0])+"/"+(.@q[5]*.@q[1])+")^000000";
    if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
        mes " > "+Chk(countitem(.@q[.@i]),.@q[.@i+1]*.@q[1])+((.ShowID)?"{"+.@q[.@i]+"} ":"")+Slot(.@q[.@i])+" ("+countitem(.@q[.@i])+"/"+(.@q[.@i+1]*.@q[1])+")^000000";
    next;
    setarray @qe[1], getiteminfo(.@q[0],5), getiteminfo(.@q[0],11);
    if (@qe[2] > 0 && ((@qe[1] & 1) || (@qe[1] & 256) || (@qe[1] & 512) || (@qe[1] & 1024) || (@qe[1] & 2048) || (@qe[1] & 4096) || (@qe[1] & 4) || (@qe[1] & 8192)))
        set .@preview,1;
    addtimer 1000, strnpcinfo(0)+"::OnEnd";
    while(1) {
        switch(select(" ~ Purchase ^0055FF"+getitemname(.@q[0])+"^000000:"+((.@preview && !@qe[7])?" ~ Preview...":"")+": ~ ^777777Cancel^000000")) {
        case 1:
            if (@qe[0]) { 
                mes "[Quest Shop]";
                mes "You're missing one or more quest requirements.";
                close;
            }
            if (!checkweight(.@q[0],.@q[2])) {
                mes "[Quest Shop]";
                mes "^FF0000You need "+(((.@q[2]*getiteminfo(.@q[0],6))+Weight-MaxWeight)/10)+" additional weight capacity to complete this trade.^000000";
                close;
            }
            if (.@q[4]) set Zeny, Zeny-(.@q[4]*.@q[1]);
            if (.@q[5]) setd .Points$[0], getd(.Points$[0])-(.@q[5]*.@q[1]);
            if (.@q[6]) for(set .@i,6; .@i<getarraysize(.@q); set .@i,.@i+2)
                delitem .@q[.@i],.@q[.@i+1]*.@q[1];
            getitem .@q[0],.@q[2];
            if (.announce) announce strcharinfo(0)+" has created "+((.@q[2] > 1)?.@q[2]+"x "+getitemname(.@q[0]):A_An(getitemname(.@q[0])))+"!",0,0xFF6060; // f87e7b;
            specialeffect EF_FLOWERLEAF;
            close;
        case 2:
            setarray @qe[3], getlook(LOOK_HEAD_BOTTOM), getlook(LOOK_HEAD_TOP), getlook(LOOK_HEAD_MID), getlook(LOOK_ROBE), 1;
            if ((@qe[1] & 1) || (@qe[1] & 4096)) changelook LOOK_HEAD_BOTTOM, @qe[2];
            else if ((@qe[1] & 256) || (@qe[1] & 1024)) changelook LOOK_HEAD_TOP, @qe[2];
            else if ((@qe[1] & 512) || (@qe[1] & 2048)) changelook LOOK_HEAD_MID, @qe[2];
            else if ((@qe[1] & 4) || (@qe[1] & 8192)) changelook LOOK_ROBE, @qe[2];
            break;
        case 3:
            close;
        }
    }

OnEnd:
    if (@qe[7]) {
        changelook LOOK_HEAD_BOTTOM, @qe[3];
        changelook LOOK_HEAD_TOP, @qe[4];
        changelook LOOK_HEAD_MID, @qe[5];
        changelook LOOK_ROBE, @qe[6];
    }
    deletearray @qe[0],8;
    end;
    
function Add {
    if (getitemname(getarg(1)) == "null") {
        consolemes(CONSOLEMES_DEBUG, "Quest reward #"+getarg(1)+" invalid (skipped).");
        return;
    }
    setarray .@j[0],getarg(2),getarg(3),getarg(4);
    for(set .@i,5; .@i<getargcount(); set .@i,.@i+2) {
        if (getitemname(getarg(.@i)) == "null") {
            consolemes(CONSOLEMES_DEBUG, "Quest requirement #"+getarg(.@i)+" invalid (skipped).");
            return;
        } else
            setarray .@j[.@i-2],getarg(.@i),getarg(.@i+1);
    }
    copyarray getd(".q_"+getarg(1)+"[0]"),.@j[0],getarraysize(.@j);
    npcshopadditem "oshop"+getarg(0),getarg(1),((.ShowZeny)?getarg(3):0);
    return;
}

function Chk {
    if (getarg(0) < getarg(1)) {
        set @qe[0],1;
        return "^FF0000";
    } else
        return "^00FF00";
}

function Slot {
    set .@s$,getitemname(getarg(0));
    switch(.ShowSlot) {
        case 1: if (!getitemslots(getarg(0))) return .@s$;
        case 2: if (getiteminfo(getarg(0),2) == 4 || getiteminfo(getarg(0),2) == 5) return .@s$+" ["+getitemslots(getarg(0))+"]";
        default: return .@s$;
    }
}

function A_An {
    setarray .@A$[0],"a","e","i","o","u";
    set .@B$, "_"+getarg(0);
    for(set .@i,0; .@i<5; set .@i,.@i+1)
        if (compare(.@B$,"_"+.@A$[.@i])) return "an "+getarg(0);
    return "a "+getarg(0);
}
}

function    script    oshop1    {
    deletearray @i[0],getarraysize(@i);
    for(set .@i,0; .@i<getargcount(); set .@i,.@i+1)
        set @i[.@i],getarg(.@i);
    doevent "offquest_shop::OnMenu";
    end;
    
}

// Dummy shop data -- copy as needed.
//============================================================
-    shop    oshop1    FAKE_NPC,909:-1
-    shop    oshop2    FAKE_NPC,909:-1

try this code not work cant click it