Help for Guild Party and Online members checking

[friomixx]

Hi,

Can anyone help me check my error?
the goal of my script is to check if all members of the party are online and members of the same guild.
as you can see in the screenshot, I'm able to reload the script, but whenever i tried to click the NPC, it now gives the error message.

 

Edited October 14, 2023 by friomixx

[Winterfox]

if(getcharid(2,$@partymembername$[.@i] != getarg(0))) {

Has to be:

if(getcharid(2,$@partymembername$[.@i]) != getarg(0)) {

 

Edited October 13, 2023 by Winterfox

[Winterfox]

1 hour ago, friomixx said:

Hi,

Can anyone help me check my error?
the goal of my script is to check if all members of the party are online and members of the same guild.
as you can see in the screenshot, I'm able to reload the script, but whenever i tried to click the NPC, it now gives the error message.

 

prontera,194,181,5	script	Room Manager	415,{
	
	.@partyId = getcharid(1);
	.@guildId = getcharid(2);
	.@partyMember = 2;
	getpartymember(.@partyId,0);
	getpartymember(.@partyId,1);
	getpartymember(.@partyId,2);
	
	callsub S_GuildParty,.@guildId;
	
	dispbottom "You passed the checks.";
	end;

S_GuildParty:
	for(.@i = 0; .@i < $@partymembercount; .@i++) {
		if (isloggedin( $@partymemberaid[.@i], $@partymembercid[.@i] )) {
			.@partyMemberOnline++;
			if(getcharid(2,$@partymembername$[.@i] != getarg(0))) {
				dispbottom $@partymembername$[.@i] +" is not a member of your guild.";
				.@partyMemberNotInGuild++;
			}
		}
	}
	if (.@partyMemberNotInGuild || .@partyMemberOnline < $@partymembercount) {
		dispbottom "All party members should be online and member of same guild";
		end;
	}
return;
}

Another suggestion I have would be to improve readability by using continue, to jump to the next iteration of the loop to minimize nesting.

for(.@i = 0; .@i < $@partymembercount; .@i++) {
    if(!isloggedin($@partymemberaid[.@i], $@partymembercid[.@i])) continue;

    .@partyMemberOnline++;
                                      
    if(getcharid(2, $@partymembername$[.@i]) != getarg(0)) {
    	dispbottom $@partymembername$[.@i] + " is not a member of your guild.";
     	.@partyMemberNotInGuild++;
    }
}

 

Edited October 13, 2023 by Winterfox

[friomixx]

thank you Winterfox for your help, will consider your suggestion in my scripts.