NPC menu for equipped item

[Kawacito]

What I am looking to create is very basic but unfortunately I cannot solve the problem, what I need to create is an NPC that gives me a list of the items that I have equipped and a menu for each item that I have equipped to perform other functions. In my case through an npc that allows the battle teams to evolve with a specific item, when speaking to the npc I get the option of which equipped item I want to evolve, example:

[NPC] You have equipped:
*Devil Hat
*Devil Armor
Which do you want to evolve?

menu:
Devil's Hat
Devil Armor

basically it is that the npc gives me the name of the item that I have equipped and gives me the option to select which one I want to select for future actions

[Racaae]

Hi

Spoiler

prontera,150,150,4	script	Person	485,{
	disable_items;
	mes "[Person]";
	mes "I can evolve equipments.";
	mes "Do you want to evolve something?";
	next;

	setarray .@indices[1], EQI_HEAD_TOP, EQI_ARMOR, EQI_HAND_L, EQI_HAND_R, EQI_GARMENT, EQI_SHOES, EQI_ACC_L, EQI_ACC_R, EQI_HEAD_MID, EQI_HEAD_LOW;
	for(.@i = 1; .@i<getarraysize(.@indices); ++.@i) {
		if(getequipisequiped(.@indices[.@i])) {
			.@menu$ = .@menu$ + F_getpositionname(.@indices[.@i]) + "-[" + getequipname(.@indices[.@i]) + "]";
			.@equipped = 1;
		}
		.@menu$ = .@menu$ + ":";
	}
	if (.@equipped == 0) {
		mes "[Person]";
		mes "What?";
		close;
	}

	.@part = .@indices[select(.@menu$)];
	.@item = getequipid(.@part);
	//You can now use various commands with .@part and .@item

	//You can check more info about the item, like refine
	.@refine = getequiprefinerycnt(.@part);

	mes "[Person]";
	mes "That's a nice " + getitemname(.@item) + ".";
	mes "It's at refine " + .@refine + ".";

	//Command examples:
	//successremovecards .@part;
	//successrefitem .@part;
	//downrefitem .@part;
	//unequip .@part;
	//breakequip .@part;
	//delequip .@part;
	//getitem
	
	close;
}